src/system/ldscripts/m68k/runtime_loader.ld

   1 OUTPUT_FORMAT("elf32-m68k", "elf32-m68k", "elf32-m68k")
   2 OUTPUT_ARCH(m68k)
   3
   4 ENTRY(runtime_loader)
   5 SEARCH_DIR("libgcc");
   6 SECTIONS
   7 {
   8         . = 0x00100000 + SIZEOF_HEADERS;
   9
  10         .interp : { *(.interp) }
  11         .hash : { *(.hash) }
  12         .dynsym : { *(.dynsym) }
  13         .dynstr : { *(.dynstr) }
  14         .rel.text : { *(.rel.text) *(.rel.gnu.linkonce.t*) }
  15         .rela.text : { *(.rela.text) *(.rela.gnu.linkonce.t*) }
  16         .rel.data : { *(.rel.data) *(.rel.gnu.linkonce.d*) }
  17         .rela.data : { *(.rela.data) *(.rela.gnu.linkonce.d*) }
  18         .rel.rodata : { *(.rel.rodata) *(.rel.gnu.linkonce.r*) }
  19         .rela.rodata : { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
  20         .rel.got : { *(.rel.got) }
  21         .rela.got : { *(.rela.got) }
  22         .rel.ctors : { *(.rel.ctors) }
  23         .rela.ctors : { *(.rela.ctors) }
  24         .rel.dtors : { *(.rel.dtors) }
  25         .rela.dtors : { *(.rela.dtors) }
  26         .rel.init : { *(.rel.init) }
  27         .rela.init : { *(.rela.init) }
  28         .rel.fini : { *(.rel.fini) }
  29         .rela.fini : { *(.rela.fini) }
  30         .rel.bss : { *(.rel.bss) }
  31         .rela.bss : { *(.rela.bss) }
  32         .rel.plt : { *(.rel.plt) }
  33         .rela.plt : { *(.rela.plt) }
  34         .init : { *(.init) } =0x9090
  35         .plt : { *(.plt) }
  36
  37         /* text/read-only data */
  38         .text : { *(.text .gnu.linkonce.t.*) }
  39
  40         .rodata : { *(.rodata) }
  41
  42         /* writable data  */
  43         . = ALIGN(0x1000) + (. & (0x1000 - 1));
  44         __data_start = .;
  45         PROVIDE(_data_start = .);
  46         .data : { *(.data .gnu.linkonce.d.*) }
  47
  48         __ctor_list = .;
  49         PROVIDE (_ctor_list = .);
  50         .ctors : { *(.ctors) }
  51         PROVIDE (__ctor_end = .);
  52
  53
  54         /* uninitialized data (in same segment as writable data) */
  55         PROVIDE (__bss_start = .);
  56         .bss : { *(.bss) }
  57
  58         . = ALIGN(0x1000);
  59         PROVIDE (_end = .);
  60
  61         /* Strip unnecessary stuff */
  62         /DISCARD/ : { *(.comment .note .dtors) }
  63 }