src/system/ldscripts/ppc/boot_loader_cfe.ld

   1 OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc", "elf32-powerpc")
   2 OUTPUT_ARCH(powerpc)
   3
   4 ENTRY(_start)
   5
   6 SECTIONS
   7 {
   8         . = 0x200000 + SIZEOF_HEADERS;
   9
  10         __text_begin = .;
  11
  12         /* text/read-only data */
  13         .text : { *(.text .text.* .gnu.linkonce.t.*) }
  14
  15         .rodata : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  16         .sdata2 : { *(.sdata2) }
  17
  18         /* writable data  */
  19         /* align to the same offset in the next page (for performance reasons
  20            (not that it really matters in the boot loader)) */
  21         . = ALIGN(0x1000) + 0x1000 + (. & (0x1000 - 1));
  22
  23         __ctor_list = .;
  24         .ctors : { *(.ctors) }
  25         __ctor_end = .;
  26
  27         __data_start = .;
  28         .data : { *(.data .gnu.linkonce.d.*) }
  29         .data.rel.ro : { *(.data.rel.ro.local .data.rel.ro*) }
  30         .got : { *(.got .got2) }
  31         .sdata : { *(.sdata .sdata.* .gnu.linkonce.s.*) }
  32
  33         /* uninitialized data (in same segment as writable data) */
  34         __bss_start = .;
  35         .sbss : { *(.sbss .sbss.* .gnu.linkonce.sb.*) }
  36         .bss : {
  37                 *(.bss .bss.* .gnu.linkonce.b.*)
  38                 . = ALIGN(0x1000);
  39         }
  40
  41         _end = . ;
  42
  43         /* Strip unnecessary stuff */
  44         /DISCARD/ : { *(.comment .note .eh_frame .dtors .debug_*) }
  45 }