user-tools/paths2indent

   1 #!/usr/bin/env perl
   2
   3 use Getopt::Long;
   4 use Pod::Usage;
   5 use Data::Dumper;
   6
   7 my $do_sort = 0;
   8 my $stop_pattern = undef;
   9 my $DIRSEP = '/';
  10
  11 GetOptions(
  12         's|sort!' => \$do_sort,
  13         'd|separator|dir-separator=s' => \$DIRSEP,
  14         't|stop=s' => \$stop_pattern,
  15 ) or pod2usage(-exitval=>2, -verbose=>99);
  16
  17 my %parsed;
  18
  19 while(my $line = <STDIN>)
  20 {
  21         chomp $line;
  22         my $ref = \%parsed;
  23         my ($path, $sep, $suffix);
  24
  25         if(defined $stop_pattern)
  26         {
  27                 ($path, $sep, $suffix) = split /($stop_pattern)/, $line, 2;
  28         }
  29         else
  30         {
  31                 $path = $line;
  32                 $sep = $suffix = '';
  33         }
  34
  35         my @elements = split /\Q$DIRSEP\E/, $path;
  36         $elements[$#elements] .= $sep . $suffix if @elements;
  37
  38         for my $element (@elements)
  39         {
  40                 next if $element eq '';
  41                 $ref->{'children'}->{$element} = {
  42                         'index' => (scalar keys %{$ref->{'children'}}),
  43                         'name' => $element,
  44                         'children' => {},
  45                 } if not exists $ref->{'children'}->{$element};
  46                 $ref = $ref->{'children'}->{$element};
  47         }
  48 }
  49
  50 sub output
  51 {
  52         my $indent = shift;
  53         my $ref = shift;
  54         for my $child (sort {$do_sort ? ($a->{'name'} cmp $b->{'name'}) : ($a->{'index'} <=> $b->{'index'})} values %{$ref->{'children'}})
  55         {
  56                 printf "%s%s\n", "\t"x$indent, $child->{'name'};
  57                 output($indent+1, $child);
  58         }
  59 }
  60
  61 output(0, \%parsed);
  62
  63
  64 __END__
  65
  66 =pod
  67
  68 =head1 NAME
  69
  70 paths2indent - Transform list of filesystem paths to an indented list of the leaf elements
  71
  72 =head1 SYNOPSIS
  73
  74 paths2indent [I<OPTIONS>]
  75
  76 =head1 DESCRIPTION
  77
  78 Input: list of file paths line-by-line
  79
  80 Output: leaf file names indented by as many tabs as deep the file is on the tree
  81
  82 =head1 OPTIONS
  83
  84 =over 4
  85
  86 =item -d, --separator I<CHAR>
  87
  88 =item -t, --stop I<PATTERN>
  89
  90 =item -s, --sort
  91
  92 =back
  93
  94 =head1 LIMITATIONS
  95
  96 Can not have empty path elements (ie. consecutive slashes).
  97
  98 =head1 SEE ALSO
  99
 100 =over 4
 101
 102 =item https://github.com/jez/as-tree
 103
 104 =back
 105
 106 =cut