configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[7.99.1],[https://github.com/heimdal/heimdal/issues])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.11])
  11 AM_MAINTAINER_MODE
  12
  13 LT_PREREQ([2.2])
  14 LT_INIT([shared static win32-dll])
  15
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC
  19 AM_PROG_CC_C_O
  20 AC_PROG_CPP
  21 AM_PATH_PYTHON
  22 AC_CHECK_PROG(CLANG_FORMAT, clang-format, [clang-format], [no])
  23 test "$CLANG_FORMAT" = no && CLANG_FORMAT=true
  24
  25 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  26
  27 AC_PREFIX_DEFAULT(/usr/heimdal)
  28
  29 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  30 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  31
  32 AC_CANONICAL_HOST
  33 CANONICAL_HOST=$host
  34 AC_SUBST(CANONICAL_HOST)
  35
  36 rk_SYS_LARGEFILE
  37
  38 rk_AIX
  39 rk_IRIX
  40 rk_SUNOS
  41
  42 dnl
  43 dnl this is needed to run the configure tests against glibc
  44 dnl
  45 AC_DEFINE([_GNU_SOURCE], 1,
  46         [Define to enable extensions on glibc-based systems such as Linux.])
  47
  48 AC_OBJEXT
  49 AC_EXEEXT
  50
  51 dnl
  52 dnl this is needed when der-protos.h or der-private.h has to be generated
  53 dnl
  54 if ! test -f "$srcdir/lib/asn1/der-protos.h" ||
  55    ! test -f "$srcdir/lib/asn1/der-private.h"; then
  56     AC_KRB_PROG_PERL
  57     AC_KRB_PERL_MOD(Getopt::Std)
  58     AC_KRB_PERL_MOD(File::Compare)
  59 fi
  60
  61 AC_KRB_PROG_YACC
  62 dnl AC_PROG_YACC
  63 AM_PROG_LEX
  64 AS_IF([$LEX --nounput -V > /dev/null 2>&1 && test $? -eq 0],
  65       [AC_SUBST([FLEXNOUNPUTARGS], ["--nounput"])],
  66       [AC_SUBST([FLEXNOUNPUTARGS], [""])])
  67 dnl AC_PROG_RANLIB
  68 AC_PROG_AWK
  69 AC_KRB_PROG_LN_S
  70
  71 AC_MIPS_ABI
  72 CC="$CC $abi"
  73 libdir="$libdir$abilibdirext"
  74
  75 AC_C___ATTRIBUTE__
  76
  77 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  78 rk_VERSIONSCRIPT
  79
  80 dnl Code coverage
  81 AC_ARG_ENABLE([gcov],
  82         AC_HELP_STRING([--enable-gcov], [enable gcov code coverage tool]))
  83 AM_CONDITIONAL([ENABLE_GCOV], [test "x$enable_gcov" = xyes])
  84
  85
  86 dnl
  87 dnl Helper bits for cross compiling
  88 dnl
  89
  90 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  91
  92 AC_ARG_WITH(cross-tools,
  93         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  94         [if test "$withval" = "yes"; then
  95                 AC_MSG_ERROR([Need path to cross tools])
  96         fi
  97         with_cross_tools="${with_cross_tools}/"
  98         ])
  99
 100 if test "${cross_compiling}" != yes ; then
 101
 102    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
 103    SLC="\$(top_builddir)/lib/sl/slc"
 104
 105    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
 106    SLC_DEP="\$(SLC)"
 107 else
 108    ASN1_COMPILE="${with_cross_tools}asn1_compile"
 109    SLC="${with_cross_tools}slc"
 110
 111    ASN1_COMPILE_DEP=
 112    SLC_DEP=
 113
 114    ac_cv_prog_COMPILE_ET=${with_cross_tools}compile_et
 115
 116 fi
 117
 118 AX_CHECK_COMPILE_FLAG([-Wno-error=enum-conversion],
 119                       [WFLAGS_ENUM_CONV=-Wno-error=enum-conversion],
 120                       [WFLAGS_ENUM_CONV=], [-Werror])
 121 AX_CHECK_COMPILE_FLAG([-Wno-unused-but-set-variable],
 122                       [WFLAGS_UNUSED_BUT_SET_VAR=-Wno-unused-but-set-variable],
 123                       [WFLAGS_UNUSED_BUT_SET_VAR=], [-Werror])
 124
 125 AC_SUBST([WFLAGS_ENUM_CONV])
 126 AC_SUBST([ASN1_COMPILE])
 127 AC_SUBST([ASN1_COMPILE_DEP])
 128 AC_SUBST([SLC])
 129 AC_SUBST([SLC_DEP])
 130
 131 dnl ---
 132
 133 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 134
 135 rk_TEST_PACKAGE(openldap,
 136 [#include <lber.h>
 137 #include <ldap.h>],
 138 [-lldap -llber],,,OPENLDAP)
 139 AM_CONDITIONAL(OPENLDAP, test "$with_openldap" != "no")
 140
 141 AC_ARG_ENABLE(hdb-openldap-module,
 142         AS_HELP_STRING([--enable-hdb-openldap-module],
 143                 [if you want support to build openldap hdb as shared object]))
 144 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 145     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 146 fi
 147 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 148
 149 AC_ARG_ENABLE(asn1-templating,
 150         AS_HELP_STRING([--disable-asn1-templating],
 151                 [if you want disable to use of the ASN.1 templating compiler]))
 152 AM_CONDITIONAL(ASN1_TEMPLATING, test "x$enable_asn1_templating" != xno)
 153
 154 dnl
 155 dnl Optional modules, pk-init, digest, kx509
 156 dnl
 157
 158 AC_ARG_ENABLE(pk-init,
 159         AS_HELP_STRING([--disable-pk-init],
 160                 [if you want disable to PK-INIT support]))
 161 if test "$enable_pk_init" != no ;then
 162         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 163 fi
 164 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 165
 166 AC_ARG_ENABLE(digest,
 167         AS_HELP_STRING([--disable-digest],
 168                 [if you want disable to DIGEST support]))
 169 if test "$enable_digest" != no ;then
 170         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 171 fi
 172
 173 AC_ARG_ENABLE(kx509,
 174         AS_HELP_STRING([--disable-kx509],
 175                 [if you want disable to kx509 support]))
 176 if test "$enable_kx509" != no ;then
 177         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 178 fi
 179
 180 dnl Need to test if pkg-config exists
 181 PKG_PROG_PKG_CONFIG
 182
 183 dnl libcap-ng
 184 AC_ARG_WITH([capng],
 185   AC_HELP_STRING([--with-capng], [use libcap-ng to drop KDC privileges @<:@default=check@:>@]),
 186   [],
 187   [with_capng=check])
 188 if test "$with_capng" != "no"; then
 189   PKG_CHECK_MODULES([CAPNG], [libcap-ng >= 0.4.0],
 190                     [with_capng=yes],[with_capng=no])
 191 fi
 192 if test "$with_capng" = "yes"; then
 193   AC_DEFINE_UNQUOTED([HAVE_CAPNG], 1, [whether capng is available for privilege reduction])
 194 fi
 195 AM_CONDITIONAL([HAVE_CAPNG], [test "$with_capng" != "no"])
 196 AC_SUBST([CAPNG_CFLAGS])
 197 AC_SUBST([CAPNG_LIBS])
 198
 199 dnl mitdb
 200 AC_ARG_WITH([mitdb],
 201   AC_HELP_STRING([--with-mitdb], [Path to MIT Kerberos DB include header and shared object]),
 202   [],
 203   [with_mitdb=no])
 204 if test -n "$with_mitdb" -a -d "$with_mitdb"; then
 205   AC_DEFINE_UNQUOTED([HAVE_MITDB], 1, [Define if building with MIT Kerberos DB driver])
 206   AC_DEFINE(HAVE_DB1, 1, [define if you have a berkeley db1/2 library])
 207   mitdb=$with_mitdb
 208 elif test "$with_mitdb" = no; then
 209   with_mitdb=
 210   mitdb=
 211 elif test "$with_mitdb" = yes; then
 212   AC_MSG_ERROR([Need path to MIT Kerberos DB include header and shared object])
 213 fi
 214 AM_CONDITIONAL([HAVE_MITDB], [test -n "$with_mitdb"])
 215 AC_SUBST([MITDB], ["$with_mitdb"])
 216
 217 dnl libmicrohttpd
 218 AC_ARG_WITH([microhttpd],
 219   AC_HELP_STRING([--with-microhttpd], [use microhttpd to serve KDC REST API @<:@default=check@:>@]),
 220   [],
 221   [with_microhttpd=check])
 222 if test "$with_microhttpd" != "no"; then
 223   PKG_CHECK_MODULES([MICROHTTPD], [libmicrohttpd >= 0.9.37],
 224                     [with_microhttpd=yes],[with_microhttpd=no])
 225 fi
 226 if test "$with_microhttpd" = "yes"; then
 227   AC_DEFINE_UNQUOTED([HAVE_MICROHTTPD], 1, [whether libmicrohttpd is available for KDC REST API])
 228 fi
 229 AM_CONDITIONAL([HAVE_MICROHTTPD], [test "$with_microhttpd" != "no"])
 230 AC_SUBST([MICROHTTPD_CFLAGS])
 231 AC_SUBST([MICROHTTPD_LIBS])
 232
 233 dnl libcjwt
 234 AC_ARG_WITH([cjwt],
 235   AC_HELP_STRING([--with-cjwt], [(Experimental) use cjwt to validate JWT tokens @<:@default=check@:>@]),
 236   [],
 237   [with_cjwt=check])
 238 if test "$with_cjwt" != "no"; then
 239   PKG_CHECK_MODULES([CJWT], [libcjwt >= 1.0.0],
 240                     [with_cjwt=yes],[with_cjwt=no])
 241 fi
 242 if test "$with_cjwt" = "yes"; then
 243   AC_DEFINE_UNQUOTED([HAVE_CJWT], 1, [whether libcjwt is available for KDC REST API])
 244 fi
 245 AM_CONDITIONAL([HAVE_CJWT], [test "$with_cjwt" != "no"])
 246 AC_SUBST([CJWT_CFLAGS])
 247 AC_SUBST([CJWT_LIBS])
 248
 249 dnl libcjson
 250 AC_ARG_WITH([cjson],
 251   AC_HELP_STRING([--with-cjson], [(Experimental) use cJSON to extract private claims from JWT tokens @<:@default=check@:>@]),
 252   [],
 253   [with_cjson=check])
 254 if test "$with_cjson" != "no"; then
 255   PKG_CHECK_MODULES([CJSON], [libcjson >= 1.0.0],
 256                     [with_cjson=yes],[with_cjson=no])
 257 fi
 258 if test "$with_cjson" = "yes"; then
 259   AC_DEFINE_UNQUOTED([HAVE_CJSON], 1, [whether libcjson is available for KDC REST API])
 260 fi
 261 AM_CONDITIONAL([HAVE_CJSON], [test "$with_cjson" != "no"])
 262 AC_SUBST([CJSON_CFLAGS])
 263 AC_SUBST([CJSON_LIBS])
 264
 265 dnl mitkrb5
 266 AC_ARG_WITH([mitkrb5],
 267   AC_HELP_STRING([--with-mitkrb5], [Path to MIT Kerberos for interop testing @<:@default=check@:>@]),
 268   [],
 269   [with_mikrb5=check])
 270 AM_CONDITIONAL([MITKRB5], [test "$with_mitkrb5" != "no"])
 271
 272 dnl Check for sqlite
 273 rk_TEST_PACKAGE(sqlite3,
 274 [#include <sqlite3.h>
 275 #ifndef SQLITE_OPEN_CREATE
 276 #error "old version"
 277 #endif],
 278 [-lsqlite3],,,SQLITE3)
 279
 280 if test "X$with_sqlite3" != Xyes ; then
 281    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 282    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 283 fi
 284 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 285
 286 AC_DEFINE(HAVE_SQLITE3, 1, [Define if you want support for sqlite in Heimdal.])
 287
 288 AC_ARG_ENABLE(sqlite-cache,
 289         AS_HELP_STRING([--disable-sqlite-cache],[if you want support for cache in sqlite]))
 290 if test "$enable_sqlite_cache" != no; then
 291     AC_DEFINE(HAVE_SCC, 1, [Define if you want support for cache in sqlite.])
 292 fi
 293 AM_CONDITIONAL(have_scc, test "$enable_sqlite_cache" != no)
 294
 295
 296 dnl check for libintl
 297 rk_TEST_PACKAGE(libintl,
 298 [#include <libintl.h>],
 299 [-lintl],,,LIBINTL)
 300
 301 dnl path where the hdb directory is stored
 302 AC_ARG_WITH([hdbdir],
 303         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 304         [],
 305         [with_hdbdir=/var/heimdal])
 306 DIR_hdbdir="$with_hdbdir"
 307 AC_SUBST([DIR_hdbdir])
 308
 309
 310 AM_CONDITIONAL(KRB5, true)
 311 AM_CONDITIONAL(do_roken_rename, true)
 312
 313 AC_DEFINE(SUPPORT_INETD, 1, [Enable use of inetd style startup.])dnl
 314
 315
 316 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 317 AC_SUBST(LIB_kdb)dnl
 318
 319 KRB_CRYPTO
 320
 321 KRB_PTHREADS
 322
 323 AC_ARG_ENABLE(dce,
 324         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 325 if test "$enable_dce" = yes; then
 326     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 327 fi
 328 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 329
 330 ## XXX quite horrible:
 331 if test -f /etc/ibmcxx.cfg; then
 332         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 333         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 334         dpagaix_ldflags=
 335 else
 336         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 337         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 338         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 339 fi
 340 AC_SUBST(dpagaix_cflags)
 341 AC_SUBST(dpagaix_ldadd)
 342 AC_SUBST(dpagaix_ldflags)
 343
 344 AC_ARG_ENABLE([afs-support],
 345         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 346 if test "$enable_afs_support" = no; then
 347         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 348         NO_AFS="1"
 349 fi
 350 AC_SUBST(NO_AFS)dnl
 351 AM_CONDITIONAL(NO_AFS, test "$enable_afs_support" = no)
 352
 353 rk_DB
 354
 355 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 356
 357 rk_ROKEN(lib/roken)
 358 LIBADD_roken="$LIB_roken"
 359 AC_SUBST(LIBADD_roken)dnl
 360 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 361
 362 rk_OTP
 363
 364 rk_LIBDISPATCH
 365
 366 AC_CHECK_OSFC2
 367
 368 AC_ARG_ENABLE(mmap,
 369         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 370 if test "$enable_mmap" = "no"; then
 371         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 372 fi
 373
 374 AC_ARG_ENABLE(afs-string-to-key,
 375         AS_HELP_STRING([--disable-afs-string-to-key],
 376         [disable use of weak AFS string-to-key functions]),
 377         [], [enable_afs_string_to_key=yes])
 378
 379 if test "$enable_afs_string_to_key" = "yes"; then
 380         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 381         ENABLE_AFS_STRING_TO_KEY=1
 382 fi
 383 AC_SUBST(ENABLE_AFS_STRING_TO_KEY)dnl
 384
 385
 386 rk_CHECK_MAN
 387
 388 rk_TEST_PACKAGE(readline,
 389 [#include <stdio.h>
 390 #if defined(HAVE_READLINE_READLINE_H)
 391 #include <readline/readline.h>
 392 #elif defined(HAVE_READLINE_H)
 393 #include <readline.h>
 394 #endif
 395 ],-lreadline,,, READLINE,, [readline.h readline/readline.h])
 396
 397 rk_TEST_PACKAGE(libedit,
 398 [#include <stdio.h>
 399 #if defined(HAVE_READLINE_READLINE_H)
 400 #include <readline/readline.h>
 401 #elif defined(HAVE_READLINE_H)
 402 #include <readline.h>
 403 #elif defined(HAVE_EDITLINE_READLINE_H)
 404 #include <editline/readline.h>
 405 #endif
 406 ],-ledit,,, READLINE,, [readline.h readline/readline.h editline/readline.h])
 407
 408 AC_CONFIG_SUBDIRS([lib/libedit])
 409
 410 KRB_C_BIGENDIAN
 411 AC_C_INLINE
 412
 413 dnl AM_C_PROTOTYPES
 414
 415 dnl Checks for typedefs, structures, and compiler characteristics.
 416 AC_C_CONST
 417 AC_TYPE_OFF_T
 418 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 419 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 420 AC_HAVE_TYPE([long long])
 421 AC_HEADER_TIME
 422 AC_STRUCT_TM
 423
 424 dnl Checks for header files.
 425 AC_HEADER_STDC
 426
 427 AC_CHECK_HEADERS([\
 428         CommonCrypto/CommonDigest.h             \
 429         CommonCrypto/CommonCryptor.h            \
 430         arpa/telnet.h                           \
 431         bind/bitypes.h                          \
 432         bsdsetjmp.h                             \
 433         curses.h                                \
 434         dlfcn.h                                 \
 435         execinfo.h                              \
 436         fnmatch.h                               \
 437         inttypes.h                              \
 438         io.h                                    \
 439         keyutils.h                              \
 440         libutil.h                               \
 441         limits.h                                \
 442         maillock.h                              \
 443         netgroup.h                              \
 444         netinet/in6_machtypes.h                 \
 445         netinet/tcp.h                           \
 446         pthread.h                               \
 447         pty.h                                   \
 448         sac.h                                   \
 449         sgtty.h                                 \
 450         siad.h                                  \
 451         signal.h                                \
 452         strings.h                               \
 453         stropts.h                               \
 454         sys/bitypes.h                           \
 455         sys/category.h                          \
 456         sys/file.h                              \
 457         sys/filio.h                             \
 458         sys/ioccom.h                            \
 459         sys/mman.h                              \
 460         sys/param.h                             \
 461         sys/pty.h                               \
 462         sys/ptyio.h                             \
 463         sys/select.h                            \
 464         sys/socket.h                            \
 465         sys/str_tty.h                           \
 466         sys/stream.h                            \
 467         sys/stropts.h                           \
 468         sys/syscall.h                           \
 469         sys/termio.h                            \
 470         sys/timeb.h                             \
 471         sys/times.h                             \
 472         sys/types.h                             \
 473         sys/un.h                                \
 474         locale.h                                \
 475         termcap.h                               \
 476         termio.h                                \
 477         termios.h                               \
 478         time.h                                  \
 479         tmpdir.h                                \
 480         udb.h                                   \
 481         util.h                                  \
 482 ])
 483
 484 AC_CHECK_HEADERS([stdatomic.h],
 485     [AC_MSG_CHECKING([whether libatomic is required])
 486     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdatomic.h>]], [[_Atomic(long long) i; atomic_init(&i, (long long) 0);]])],
 487         [AC_MSG_RESULT([no])],
 488         [AC_MSG_RESULT([yes])
 489         AC_MSG_CHECKING([whether libatomic works])
 490         save_LIBS="$LIBS"
 491         LIBS="$LIBS -latomic"
 492         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdatomic.h>]], [[_Atomic(long long) i; atomic_init(&i, (long long) 0);]])],
 493             [AC_MSG_RESULT([yes])],
 494             [AC_MSG_RESULT([no, using fallback])
 495              LIBS="$save_LIBS"
 496              AC_DEFINE([HEIM_BASE_ATOMICS_FALLBACK], [], [Define if you want fallbacks for atomic operations])]
 497         )]
 498     )],
 499     []
 500 )
 501
 502 dnl On Solaris 8 there's a compilation warning for term.h because
 503 dnl it doesn't define `bool'.
 504 AC_CHECK_HEADERS(term.h, , , -)
 505
 506 dnl aix have asl.h (A/IX screen library) that we don't want
 507 AC_CHECK_HEADERS(asl.h, , , [
 508 #include <asl.h>
 509 #ifndef ASL_STRING_EMERG
 510 #error ASL_STRING_EMERG missing
 511 #endif])
 512
 513 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 514 #if HAVE_SYS_SOCKET_H
 515 #include <sys/socket.h>
 516 #endif])
 517
 518 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 519 #if HAVE_SYS_TTY_H
 520 #include <sys/tty.h>
 521 #endif])
 522
 523 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 524 #if HAVE_TERMIOS_H
 525 #include <termios.h>
 526 #endif
 527 #if HAVE_SYS_STREAM_H
 528 #include <sys/stream.h>
 529 #endif])
 530
 531 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 532 #if HAVE_SYS_TYPES_H
 533 #include <sys/types.h>
 534 #endif
 535 #if HAVE_SYS_PARAM_H
 536 #include <sys/param.h>
 537 #endif])
 538
 539 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 540 #include <security/pam_appl.h>
 541 ])
 542
 543 dnl export symbols
 544 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 545 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 546 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 547 rk_WIN32_EXPORT(BUILD_KDC_LIB, KDC_LIB)
 548
 549 dnl Deal with switch fallthrough warnings
 550 AH_TOP([
 551 #if defined(DISPATCH_FALLTHROUGH)
 552 # define HEIM_FALLTHROUGH DISPATCH_FALLTHROUGH
 553 #else
 554 # if defined(__GNUC__)
 555 #  if __GNUC__ >= 7
 556 #   define HEIM_FALLTHROUGH __attribute__((fallthrough))
 557 #  else
 558 #   define HEIM_FALLTHROUGH do {} while (0) /* fallthrough */
 559 #  endif
 560 # else
 561 #  define HEIM_FALLTHROUGH do {} while (0) /* fallthrough */
 562 # endif
 563 #endif
 564 ])
 565
 566 dnl Checks for libraries.
 567
 568 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 569 #ifdef HAVE_UTIL_H
 570 #include <util.h>
 571 #endif
 572 ],[0,0,0,0,0])
 573
 574 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses tinfo,[
 575 #ifdef HAVE_TERMCAP_H
 576 #include <termcap.h>
 577 #endif
 578 #ifdef HAVE_CURSES_H
 579 #include <curses.h>
 580 #endif
 581 ],[0,0])
 582
 583 dnl Checks for library functions.
 584
 585 AC_CHECK_FUNCS([                                \
 586         _scrsize                                \
 587         arc4random                              \
 588         backtrace                               \
 589         fcntl                                   \
 590         fork                                    \
 591         fseeko                                  \
 592         ftello                                  \
 593         getpeereid                              \
 594         getpeerucred                            \
 595         getresgid                               \
 596         getresuid                               \
 597         grantpt                                 \
 598         ptsname_r                               \
 599         rand                                    \
 600         setitimer                               \
 601         setregid                                \
 602         setresgid                               \
 603         setresuid                               \
 604         setreuid                                \
 605         setsid                                  \
 606         sigaction                               \
 607         unlockpt                                \
 608         waitpid                                 \
 609 ])
 610
 611 AC_MSG_CHECKING([checking for __sync_add_and_fetch])
 612 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>]],
 613         [[unsigned int foo, bar; bar = __sync_add_and_fetch(&foo, 1);]])],
 614         [ac_rk_have___sync_add_and_fetch=yes], [ac_rk_have___sync_add_and_fetch=no])
 615 if test "$ac_rk_have___sync_add_and_fetch" = "yes" ; then
 616         AC_DEFINE_UNQUOTED(HAVE___SYNC_ADD_AND_FETCH, 1, [have __sync_add_and_fetch])
 617 fi
 618 AC_MSG_RESULT($ac_rk_have___sync_add_and_fetch)
 619
 620 AC_FUNC_MMAP
 621
 622 rk_DLADDR
 623
 624 AC_CHECK_GETPWNAM_R_POSIX
 625 AC_CHECK_GETPWUID_R_POSIX
 626
 627 dnl detect doors on solaris
 628 if test "$enable_pthread_support" != no; then
 629    saved_LIBS="$LIBS"
 630    LIBS="$LIBS $PTHREADS_LIBS"
 631    AC_FIND_FUNC_NO_LIBS(door_create, door)
 632    LIBS="$saved_LIBS"
 633 fi
 634
 635 AC_ARG_ENABLE(kcm,
 636         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 637 ,[enable_kcm=yes])
 638
 639 if test "$enable_kcm" = yes ; then
 640    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 641         enable_kcm=no
 642    fi
 643 fi
 644 if test "$enable_kcm" = yes; then
 645        AC_DEFINE(HAVE_KCM, 1,
 646                [Define if you want to use the Kerberos Credentials Manager.])
 647 fi
 648 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 649
 650 dnl detect keyring on Linux
 651 if test "$ac_cv_header_keyutils_h" = yes; then
 652     AC_CHECK_SIZEOF([key_serial_t],,[
 653         #ifdef HAVE_INTTYPES_H
 654         #include <inttypes.h>
 655         #endif
 656         #ifdef HAVE_SYS_TYPES_H
 657         #include <sys/types.h>
 658         #endif
 659         #include <keyutils.h>
 660     ])
 661 fi
 662
 663 AC_FIND_FUNC_NO_LIBS(add_key, keyutils)
 664 if test -n "$LIB_add_key"; then
 665     saved_LIBS="$LIBS"
 666     LIBS="$LIBS $LIB_add_key"
 667     AC_CHECK_FUNCS(keyctl_get_persistent)
 668     LIBS="$saved_LIBS"
 669 fi
 670 AM_CONDITIONAL(HAVE_KEYUTILS, test "$ac_cv_func_keyctl_get_persistent" = yes)
 671
 672 AC_CHECK_SIZEOF([time_t])
 673
 674 AX_CHECK_SIGN([time_t],
 675   [ AC_DEFINE(TIME_T_SIGNED, 1, [Define if time_t is signed]) ],
 676   [ AC_DEFINE(TIME_T_UNSIGNED, 1, [Define if time_t is unsigned]) ], [
 677 #ifdef HAVE_TIME_H
 678 #include <time.h>
 679 #endif
 680 ])
 681
 682
 683 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 684         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 685         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 686 #ifdef HAVE_INTTYPES_H
 687 #include <inttypes.h>
 688 #endif
 689 #ifdef HAVE_SYS_TYPES_H
 690 #include <sys/types.h>
 691 #endif
 692 #ifdef HAVE_SYS_BITYPES_H
 693 #include <sys/bitypes.h>
 694 #endif
 695 #ifdef HAVE_BIND_BITYPES_H
 696 #include <bind/bitypes.h>
 697 #endif
 698 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 699 #include <netinet/in6_machtypes.h>
 700 #endif
 701 ])
 702
 703 rk_FRAMEWORK_SECURITY
 704 rk_FRAMEWORK_COREFOUNDATION
 705
 706 KRB_READLINE
 707
 708 rk_TELNET
 709
 710 dnl Some operating systems already have com_err and compile_et
 711 CHECK_COMPILE_ET
 712
 713 rk_AUTH_MODULES([sia afskauthlib])
 714
 715 rk_DESTDIRS
 716
 717 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 718
 719
 720 AH_BOTTOM([#ifdef __APPLE__
 721 #include <AvailabilityMacros.h>
 722 #endif])
 723
 724 AH_BOTTOM([#ifdef ROKEN_RENAME
 725 #include "roken_rename.h"
 726 #endif])
 727
 728 AC_ARG_ENABLE(heimdal-documentation,
 729         AS_HELP_STRING([--disable-heimdal-documentation],
 730                 [if you want disable to heimdal documentation]))
 731 AM_CONDITIONAL(HEIMDAL_DOCUMENTATION, test "$enable_heimdal_documentation" != no)
 732
 733 AC_CONFIG_FILES(Makefile                \
 734         etc/Makefile                    \
 735         include/Makefile                \
 736         include/gssapi/Makefile         \
 737         include/hcrypto/Makefile        \
 738         include/kadm5/Makefile          \
 739         lib/Makefile                    \
 740         lib/base/Makefile                       \
 741         lib/asn1/Makefile               \
 742         lib/com_err/Makefile            \
 743         lib/hcrypto/Makefile            \
 744         lib/hx509/Makefile              \
 745         lib/gssapi/Makefile             \
 746         lib/ntlm/Makefile               \
 747         lib/hdb/Makefile                \
 748         lib/ipc/Makefile                \
 749         lib/kadm5/Makefile              \
 750         lib/kafs/Makefile               \
 751         lib/kdfs/Makefile               \
 752         lib/krb5/Makefile               \
 753         lib/otp/Makefile                \
 754         lib/roken/Makefile              \
 755         lib/sl/Makefile                 \
 756         lib/sqlite/Makefile             \
 757         lib/vers/Makefile               \
 758         lib/wind/Makefile               \
 759         lib/gss_preauth/Makefile        \
 760         po/Makefile                     \
 761         kuser/Makefile                  \
 762         kpasswd/Makefile                \
 763         kadmin/Makefile                 \
 764         admin/Makefile                  \
 765         kcm/Makefile                    \
 766         kdc/Makefile                    \
 767         appl/Makefile                   \
 768         appl/afsutil/Makefile           \
 769         appl/dbutils/Makefile           \
 770         appl/gssmask/Makefile           \
 771         appl/otp/Makefile               \
 772         appl/test/Makefile              \
 773         appl/kf/Makefile                \
 774         appl/dceutils/Makefile          \
 775         tests/Makefile                  \
 776         tests/bin/Makefile              \
 777         tests/can/Makefile              \
 778         tests/db/Makefile               \
 779         tests/kdc/Makefile              \
 780         tests/ldap/Makefile             \
 781         tests/gss/Makefile              \
 782         tests/java/Makefile             \
 783         tests/plugin/Makefile           \
 784         packages/Makefile               \
 785         packages/mac/Makefile           \
 786         doc/Makefile                    \
 787         tools/Makefile                  \
 788 )
 789
 790 AC_OUTPUT
 791
 792 dnl
 793 dnl This is the release version name-number[beta]
 794 dnl
 795
 796 if test -d "$srcdir/.git"; then
 797     cat > include/newversion.h.in <<EOF
 798 #ifndef VERSION_HIDDEN
 799 #define VERSION_HIDDEN
 800 #endif
 801 VERSION_HIDDEN const char *const heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ @BRANCH@ @TAG@ ($host) @COMMIT@ @DATE@ \$";
 802 VERSION_HIDDEN const char *const heimdal_version = "AC_PACKAGE_STRING";
 803 EOF
 804 else
 805     cat > include/newversion.h.in <<EOF
 806 #ifndef VERSION_HIDDEN
 807 #define VERSION_HIDDEN
 808 #endif
 809 VERSION_HIDDEN const char *const heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 810 VERSION_HIDDEN const char *const heimdal_version = "AC_PACKAGE_STRING";
 811 EOF
 812 fi
 813
 814 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 815         echo "include/version.h is unchanged"
 816         rm -f include/newversion.h.in
 817 else
 818         echo "creating include/version.h"
 819         if test -n "$SOURCE_DATE_EPOCH"; then
 820             Date=`
 821                   # BSD, OS X
 822                   date -u -r "$SOURCE_DATE_EPOCH" "+%Y-%m-%dT%H:%M:%SZ" 2>/dev/null ||
 823                   # Linux
 824                   date -u -d "@${SOURCE_DATE_EPOCH}" 2>/dev/null ||
 825                   # Illumos -- sorry, no -r/-d here
 826                   date -u ||
 827                   date`
 828         else
 829             Date=`date -u "+%Y-%m-%dT%H:%M:%SZ"`
 830         fi
 831         if test -n "$SOURCE_HOST"; then
 832             Host=$SOURCE_HOST
 833         else
 834             Host=`uname -n`
 835         fi
 836         if test -n "$SOURCE_USER"; then
 837             User=$SOURCE_USER
 838         else
 839             User=${USER:-${LOGNAME:-`id -nu`}}
 840         fi
 841         if test -d "$srcdir/.git"; then
 842             GitCommit=`cd $srcdir && git rev-parse HEAD`
 843             GitBranch=`cd $srcdir && git rev-parse --abbrev-ref HEAD`
 844             if test "x$GitBranch" = master; then
 845                 GitDesc=`cd $srcdir && git describe --all --dirty`
 846             else
 847                 GitDesc=`cd $srcdir && \
 848                          git describe --tags --match 'heimdal-*' --dirty`
 849             fi
 850         else
 851             GitCommit='<commit-unknown>'
 852             GitBranch='<branch-unknown>'
 853             GitDesc='<tag-unknown>'
 854         fi
 855         mv -f include/newversion.h.in include/version.h.in
 856         sed -e "s/@HOST@/$Host/" \
 857             -e "s;@USER@;$User;" \
 858             -e "s;@DATE@;$Date;" \
 859             -e "s;@BRANCH@;$GitBranch;" \
 860             -e "s;@TAG@;$GitDesc;" \
 861             -e "s;@COMMIT@;$GitCommit;" \
 862             include/version.h.in > include/version.h
 863 fi