arch/arm/boot/compressed/head-sa1100.S

   1 /*
   2  * linux/arch/arm/boot/compressed/head-sa1100.S
   3  *
   4  * Copyright (C) 1999 Nicolas Pitre <nico@cam.org>
   5  *
   6  * SA1100 specific tweaks.  This is merged into head.S by the linker.
   7  *
   8  */
   9
  10 #include <linux/linkage.h>
  11 #include <asm/mach-types.h>
  12
  13                 .section        ".start", "ax"
  14
  15 __SA1100_start:
  16
  17 #ifdef CONFIG_LAB       // if this is a LAB kernel, we're going to want to have bootloader code in it.
  18                 b       HiReset
  19 #               include "bootldr-sa1100.S"
  20 bootldr_main:
  21 #endif
  22                 @ Preserve r8/r7 i.e. kernel entry values
  23 #ifdef CONFIG_SA1100_COLLIE
  24                 mov     r7, #MACH_TYPE_COLLIE
  25 #endif
  26 #ifdef CONFIG_SA1100_SIMPAD
  27                 @ UNTIL we've something like an open bootldr
  28                 mov     r7, #MACH_TYPE_SIMPAD   @should be 87
  29 #endif
  30                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
  31                 ands    r0, r0, #0x0d
  32                 beq     99f
  33
  34                 @ Data cache might be active.
  35                 @ Be sure to flush kernel binary out of the cache,
  36                 @ whatever state it is, before it is turned off.
  37                 @ This is done by fetching through currently executed
  38                 @ memory to be sure we hit the same cache.
  39                 bic     r2, pc, #0x1f
  40                 add     r3, r2, #0x4000         @ 16 kb is quite enough...
  41 1:              ldr     r0, [r2], #32
  42                 teq     r2, r3
  43                 bne     1b
  44                 mcr     p15, 0, r0, c7, c10, 4  @ drain WB
  45                 mcr     p15, 0, r0, c7, c7, 0   @ flush I & D caches
  46
  47                 @ disabling MMU and caches
  48                 mrc     p15, 0, r0, c1, c0, 0   @ read control reg
  49                 bic     r0, r0, #0x0d           @ clear WB, DC, MMU
  50                 bic     r0, r0, #0x1000         @ clear Icache
  51                 mcr     p15, 0, r0, c1, c0, 0
  52 99: