configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  22 dnl configure script to emit at least warnings when it comes across unknown
  23 dnl command line options. These versions also have the macro
  24 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  25 dnl We want to have this turned off here since our configure calls can
  26 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  27 dnl So avoid confusing the user by turning this off. See also PR 45221.
  28 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  29
  30 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  31 dnl by configure until it is too late.  Is that how it should be or not?
  32 dnl Something seems broken here.
  33 AC_PREFIX_DEFAULT(/usr/local/apache2)
  34
  35 dnl Get the layout here, so we can pass the required variables to apr
  36 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  37
  38 dnl reparse the configure arguments.
  39 APR_PARSE_ARGUMENTS
  40
  41 dnl export expanded and relative configure argument variables
  42 APACHE_EXPORT_ARGUMENTS
  43
  44 dnl Save user-defined environment settings for later restoration
  45 dnl
  46 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  47 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  48 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  49 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  50 APR_SAVE_THE_ENVIRONMENT(LIBS)
  51 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  52
  53 dnl Generate ./config.nice for reproducing runs of configure
  54 dnl
  55 APR_CONFIG_NICE(config.nice)
  56
  57 nl='
  58 '
  59 dnl Check that mkdir -p works
  60 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  61
  62 dnl ## Run configure for packages Apache uses
  63
  64 dnl shared library support for these packages doesn't currently
  65 dnl work on some platforms
  66
  67 AC_CANONICAL_SYSTEM
  68
  69 orig_prefix="$prefix"
  70
  71 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  72
  73 AC_ARG_WITH(included-apr,
  74 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  75
  76 if test "x$with_included_apr" = "xyes"; then
  77    apr_found=reconfig
  78 else
  79    APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, "1 2")
  80 fi
  81
  82 if test "$apr_found" = "no"; then
  83   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  84 fi
  85
  86 if test "$apr_found" = "reconfig"; then
  87   APR_SUBDIR_CONFIG(srclib/apr,
  88                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  89                     [--enable-layout=*|\'--enable-layout=*])
  90   dnl We must be the first to build and the last to be cleaned
  91   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  92   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  93
  94   dnl We have to find apr-N-config when we reconfigure APR.
  95   for majorver in 1 2; do
  96     test_apr_config="$srcdir/srclib/apr/apr-${majorver}-config"
  97     if test -f $test_apr_config; then
  98       apr_config=$test_apr_config
  99     fi
 100   done
 101 fi
 102
 103 APR_SETIFNULL(CC, `$apr_config --cc`)
 104 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 105 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 106 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 107 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 108 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 109 APR_BINDIR=`$apr_config --bindir`
 110 APR_INCLUDEDIR=`$apr_config --includedir`
 111 APR_INCLUDES=`$apr_config --includes`
 112 APR_VERSION=`$apr_config --version`
 113 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 114 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 115
 116 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
 117
 118 if test "x$with_included_apr" = "xyes"; then
 119    apu_found=reconfig
 120 else
 121    APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util", 1, ${apr_major_version})
 122 fi
 123
 124 if test "$apu_found" = "no"; then
 125   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
 126 fi
 127
 128 # Catch some misconfigurations:
 129 case ${apr_found}.${apu_found} in
 130 reconfig.yes)
 131   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 132   ;;
 133 yes.reconfig)
 134   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 135   ;;
 136 esac
 137
 138 if test "$apu_found" = "reconfig"; then
 139   APR_SUBDIR_CONFIG(srclib/apr-util,
 140                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 141                     [--enable-layout=*|\'--enable-layout=*])
 142   dnl We must be the last to build and the first to be cleaned
 143   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 144   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 145   dnl APR and APR-Util major versions must match
 146   apu_config="${srcdir}/srclib/apr-util/apu-${apr_major_version}-config"
 147 fi
 148
 149 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 150 APU_BINDIR=`$apu_config --bindir`
 151 APU_INCLUDEDIR=`$apu_config --includedir`
 152 APU_INCLUDES=`$apu_config --includes`
 153 APU_VERSION=`$apu_config --version`
 154 APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 155
 156 dnl In case we picked up CC and CPP from APR, get that info into the
 157 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 158 dnl PCRE and for our config tests will be whatever PCRE determines.
 159 AC_PROG_CC
 160 AC_PROG_CPP
 161
 162 if test "x${cache_file}" = "x/dev/null"; then
 163   # Likewise, ensure that CC and CPP are passed through to the pcre
 164   # configure script iff caching is disabled (the autoconf 2.5x default).
 165   export CC; export CPP
 166 fi
 167
 168 dnl Absolute source/build directory
 169 abs_srcdir=`(cd $srcdir && pwd)`
 170 abs_builddir=`pwd`
 171
 172 AC_ARG_WITH(pcre,
 173 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 174
 175 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 176 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 177    PCRE_CONFIG=$with_pcre/bin/pcre-config
 178 elif test -x "$with_pcre"; then
 179    PCRE_CONFIG=$with_pcre
 180 fi
 181
 182 if test "$PCRE_CONFIG" != "false"; then
 183   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 184     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 185   fi
 186   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 187   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 188   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 189 else
 190   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 191 fi
 192 APACHE_SUBST(PCRE_LIBS)
 193
 194 dnl Add PCRE_LIBS to HTTPD_LDFLAGS
 195 APR_ADDTO(HTTPD_LDFLAGS, [\$(PCRE_LIBS)])
 196
 197 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 198
 199 dnl If the source dir is not equal to the build dir,
 200 dnl then we are running in VPATH mode.
 201
 202 APR_ADDTO(INCLUDES, [-I.])
 203
 204 if test "$abs_builddir" != "$abs_srcdir"; then
 205   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 206 fi
 207
 208 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/aaa -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/modules/session -I\$(top_srcdir)/include -I\$(top_srcdir)/modules/generators -I\$(top_srcdir)/modules/mappers -I\$(top_srcdir)/modules/database])
 209
 210 # apr/apr-util --includes may pick up system paths for dependent
 211 # libraries, so ensure these are later in INCLUDES than local source
 212 # directories.
 213 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 214 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 215
 216 dnl Add in path to PCRE includes
 217 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 218
 219 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 220
 221 case $host in
 222   *os2*)
 223       # Use a custom made libtool replacement
 224       echo "using aplibtool"
 225       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 226       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 227       SH_LIBS="\$(ALL_LIBS)"
 228       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 229       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 230       MK_IMPLIB="emximp"
 231       other_targets="$other_targets os2core"
 232       INSTALL_PROG_FLAGS="-e .exe"
 233       SHLTCFLAGS=""
 234       LTCFLAGS=""
 235       ;;
 236   *)
 237       if test "x$LTFLAGS" = "x"; then
 238           LTFLAGS='--silent'
 239       fi
 240       my_libtool=`$apr_config --apr-libtool`
 241       LIBTOOL="$my_libtool \$(LTFLAGS)"
 242       libtoolversion=`$my_libtool --version`
 243       case $libtoolversion in
 244           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 245               SH_LIBTOOL='$(LIBTOOL)'
 246               SHLTCFLAGS="-prefer-pic"
 247               LTCFLAGS="-prefer-non-pic -static"
 248               ;;
 249           *)
 250               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 251               SHLTCFLAGS=""
 252               LTCFLAGS=""
 253               ;;
 254       esac
 255       ;;
 256 esac
 257 APACHE_SUBST(SHLTCFLAGS)
 258 APACHE_SUBST(LTCFLAGS)
 259
 260 case $host in
 261   *-apple-aux3*)
 262       APR_SETVAR(APACHE_MPM, [prefork])
 263       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 264       ;;
 265   *-beos*)
 266       APR_SETVAR(APACHE_MPM, [beos])
 267       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 268       ;;
 269   *os2-emx*)
 270       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 271       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 272       ;;
 273   *-linux-*)
 274       case `uname -r` in
 275         2.[[2-9]]* )
 276             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 277             ;;
 278         * )
 279             ;;
 280       esac
 281       ;;
 282   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 283       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 284       ;;
 285   *-solaris2*)
 286       dnl This is a hack -- we should be using AC_TRY_RUN instead
 287       ap_platform_runtime_link_flag="-R"
 288       dnl solaris 8 and above don't have a thundering herd
 289       dnl not sure about rev's before this one.
 290       case `uname -r` in
 291         5.[567]*)
 292             ;;
 293         * )
 294             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 295             ;;
 296       esac
 297       ;;
 298   *cygwin*)
 299       APR_SETVAR(APACHE_MPM, [prefork])
 300       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 301       ;;
 302   *mingw32*)
 303       APR_SETVAR(APACHE_MPM, [winnt])
 304       APR_ADDTO(CPPFLAGS, [-DAP_DECLARE_EXPORT])
 305       APR_SETIFNULL(ac_cv_func_times, [no])
 306       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 307       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 308       ;;
 309   *aix*)
 310       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 311       if test $aixver -ge 4320; then
 312         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 313       fi
 314       ;;
 315   *os390*)
 316       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 317       ;;
 318 esac
 319
 320 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 321
 322 dnl
 323 dnl Process command line arguments. This is done early in the process so the
 324 dnl user can get feedback quickly in case of an error.
 325 dnl
 326 dnl ### need to move some of the arguments "up here"
 327
 328 dnl ## Check for programs
 329
 330 AC_PATH_PROG(RM, rm)
 331 AC_PATH_PROG(PKGCONFIG, pkg-config)
 332 AC_PATH_PROG(RSYNC, rsync)
 333 AC_PROG_AWK
 334 AC_PROG_LN_S
 335 AC_CHECK_TOOL(RANLIB, ranlib, true)
 336 dnl AC_PATH_PROG(PERL_PATH, perl)
 337 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 338
 339 # Hard-coded install programs
 340 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 341 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 342 APACHE_SUBST(MKINSTALLDIRS)
 343 APACHE_SUBST(INSTALL)
 344
 345 dnl Various OS checks that apparently set required flags
 346 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 347 AC_USE_SYSTEM_EXTENSIONS
 348 ], [
 349 AC_AIX
 350 AC_MINIX
 351 ])
 352
 353 AC_ISC_POSIX
 354
 355 # Ensure that satisfactory versions of apr and apr-util are
 356 # found if external copies are configured.
 357 if test "${apr_found}" = "yes"; then
 358   # Require at least APR 1.3.x otherwise fail
 359   APACHE_CHECK_APxVER([apr], 1, 3)
 360 fi
 361
 362 if test "${apu_found}" = "yes"; then
 363   # Require at least APR-util 1.3.x otherwise fail
 364   APACHE_CHECK_APxVER([apu], 1, 3)
 365 fi
 366
 367 dnl Check for what we can generate dependency files with
 368 APR_CHECK_DEPEND
 369
 370 dnl ## Check for libraries
 371
 372 dnl ## Check for header files
 373
 374 dnl I think these are just used all over the place, so just check for
 375 dnl them at the base of the tree. If some are specific to a single
 376 dnl directory, they should be moved (Comment #Spoon)
 377
 378 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 379 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 380 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 381
 382 AC_HEADER_STDC
 383 AC_CHECK_HEADERS( \
 384 string.h \
 385 limits.h \
 386 unistd.h \
 387 sys/socket.h \
 388 pwd.h \
 389 grp.h \
 390 strings.h \
 391 sys/prctl.h \
 392 sys/processor.h \
 393 sys/sem.h \
 394 sys/sdt.h
 395 )
 396 AC_HEADER_SYS_WAIT
 397
 398 dnl ## Check for typedefs, structures, and compiler characteristics.
 399
 400 AC_C_CONST
 401
 402 dnl ## Check for library functions
 403 dnl ## sqrt() only needed in support/ab.c
 404 saved_LIBS="$LIBS"
 405 LIBS=""
 406 AC_SEARCH_LIBS(sqrt, m)
 407 MATH_LIBS="$LIBS"
 408 APACHE_SUBST(MATH_LIBS)
 409 LIBS="$saved_LIBS"
 410
 411 dnl See Comment #Spoon
 412
 413 AC_CHECK_FUNCS( \
 414 getpwnam \
 415 getgrnam \
 416 initgroups \
 417 bindprocessor \
 418 prctl \
 419 timegm \
 420 getpgid
 421 )
 422
 423 dnl confirm that a void pointer is large enough to store a long integer
 424 APACHE_CHECK_VOID_PTR_LEN
 425
 426 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 427 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 428 [AC_TRY_COMPILE([#include <sys/types.h>
 429 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 430   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 431 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 432     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 433 fi
 434
 435 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 436
 437 case $host in
 438     *aix*)
 439         # for 32-bit builds, increase MAXDATA to allow lots of threads
 440         if test x$OBJECT_MODE != x64; then
 441             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 442         fi
 443         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 444         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 445         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 446         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 447         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 448         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 449         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 450         ;;
 451     *os390*)
 452         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 453         ;;
 454     *)
 455         OS_SPECIFIC_VARS=""
 456 esac
 457
 458 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 459         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 460         [PORT=80])
 461
 462 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 463         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 464         [SSLPORT=443])
 465
 466 DTRACE=true
 467 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 468 [
 469   enable_dtrace=$enableval
 470   APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 471   AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 472 ],
 473 [
 474   enable_dtrace=no
 475 ])
 476
 477 dnl Disabled dtrace build for now.
 478 enable_dtrace=no
 479
 480 case $host in
 481   *-solaris2*)
 482     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 483         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 484                   [Enable DTrace probes])
 485         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 486         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 487     fi
 488     ;;
 489 esac
 490
 491 APACHE_SUBST(DTRACE)
 492
 493 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 494
 495 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 496 [
 497   v4mapped=$enableval
 498 ],
 499 [
 500     case $host in
 501     *freebsd5*|*netbsd*|*openbsd*)
 502         v4mapped=no
 503         ;;
 504     *)
 505         v4mapped=yes
 506         ;;
 507 esac
 508 ])
 509
 510 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 511     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 512               [Allow IPv4 connections on IPv6 listening sockets])
 513 fi
 514
 515 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 516 [
 517     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 518               [Allow modules to run hook after a fatal exception])
 519 ])dnl
 520
 521 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 522 [
 523   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 524 ])dnl
 525
 526 dnl Conditionally enable PIE support for GNU toolchains.
 527 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 528 if test "$enable_pie" = "yes"; then
 529    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 530      save_CFLAGS=$CFLAGS
 531      save_LDFLAGS=$LDFLAGS
 532      CFLAGS="$CFLAGS -fPIE"
 533      LDFLAGS="$LDFLAGS -pie"
 534      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 535       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 536      CFLAGS=$save_CFLAGS
 537      LDFLAGS=$save_LDFLAGS
 538    ])
 539    if test "$ap_cv_cc_pie" = "yes"; then
 540      PICFLAGS="-fPIE"
 541      PILDFLAGS="-pie"
 542    else
 543      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 544    fi
 545 fi
 546 AC_SUBST(PICFLAGS)
 547 AC_SUBST(PILDFLAGS)
 548
 549 prefix="$orig_prefix"
 550 APACHE_ENABLE_MODULES
 551
 552 dnl reading config stubs
 553 esyscmd(./build/config-stubs .)
 554
 555 APACHE_SUBST(progname)
 556 APACHE_SUBST(MPM_LIB)
 557 APACHE_SUBST(OS)
 558 APACHE_SUBST(OS_DIR)
 559 APACHE_SUBST(BUILTIN_LIBS)
 560 APACHE_SUBST(SHLIBPATH_VAR)
 561 APACHE_SUBST(OS_SPECIFIC_VARS)
 562
 563 PRE_SHARED_CMDS='echo ""'
 564 POST_SHARED_CMDS='echo ""'
 565
 566 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 567
 568 if test "$apache_need_shared" = "yes"; then
 569   if test -f $ac_aux_dir/ltconfig; then
 570     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 571   fi
 572   shared_build="shared-build"
 573 fi
 574
 575 dnl enable_so tells us if *any* modules can be built as DSOs
 576
 577 if test "$enable_so" = "yes"; then
 578   case $host in
 579     *-ibm-aix*)
 580       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 581       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 582       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 583       ;;
 584     *beos)
 585       SH_LDFLAGS='$(top_builddir)/_APP_'
 586       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 587       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 588       ;;
 589     *os390)
 590       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 591       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 592   esac
 593   MOD_SO_ENABLED=yes
 594 fi
 595 AC_SUBST(MOD_SO_ENABLED)
 596
 597 APACHE_SUBST(PRE_SHARED_CMDS)
 598 APACHE_SUBST(POST_SHARED_CMDS)
 599 APACHE_SUBST(shared_build)
 600
 601 AC_ARG_WITH(program-name,
 602 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 603   progname="$withval" ], [
 604   progname="httpd"] )
 605
 606 # SuExec parameters
 607 AC_ARG_WITH(suexec-bin,
 608 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 609   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 610 ] )
 611
 612 AC_ARG_WITH(suexec-caller,
 613 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 614   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 615
 616 AC_ARG_WITH(suexec-userdir,
 617 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 618   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 619
 620 AC_ARG_WITH(suexec-docroot,
 621 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 622   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 623
 624 AC_ARG_WITH(suexec-uidmin,
 625 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 626   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 627
 628 AC_ARG_WITH(suexec-gidmin,
 629 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 630   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 631
 632 AC_ARG_WITH(suexec-logfile,
 633 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 634   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 635
 636 AC_ARG_WITH(suexec-safepath,
 637 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 638   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 639
 640 AC_ARG_WITH(suexec-umask,
 641 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 642   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 643
 644 dnl APR should go after the other libs, so the right symbols can be picked up
 645 AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 646 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 647 APACHE_SUBST(AP_LIBS)
 648 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 649 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 650
 651 AC_DEFINE(AP_USING_AUTOCONF, 1,
 652                 [Using autoconf to configure Apache])
 653
 654 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 655     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 656               [This platform doesn't suffer from the thundering herd problem])
 657 fi
 658
 659 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 660     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 661               [Listening sockets are non-blocking when there are more than 1])
 662 fi
 663
 664
 665 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 666 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 667 APACHE_FAST_OUTPUT(support/Makefile)
 668
 669 if test -d ./test; then
 670     APACHE_FAST_OUTPUT(test/Makefile)
 671 fi
 672
 673 dnl ## Finalize the variables
 674 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 675
 676 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 677 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 678 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 679 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 680 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 681 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 682
 683 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 684
 685 APACHE_GEN_CONFIG_VARS
 686
 687 dnl ## Build modules.c
 688 rm -f modules.c
 689 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 690
 691 APR_EXPAND_VAR(ap_prefix, $prefix)
 692 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 693         [Root directory of the Apache install area])
 694 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 695         [Location of the config file, relative to the Apache root directory])
 696 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 697         [Location of the MIME types config file, relative to the Apache root directory])
 698 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 699         [Location of the source for the current MPM])
 700
 701 perlbin=`$ac_aux_dir/PrintPath perl`
 702 if test "x$perlbin" = "x"; then
 703     perlbin="/replace/with/path/to/perl/interpreter"
 704 fi
 705 AC_SUBST(perlbin)
 706
 707 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 708
 709 BSD_MAKEFILE=no
 710 ap_make_include=include
 711 ap_make_delimiter=' '
 712 case $host in
 713 *bsdi*)
 714     # Check whether they've installed GNU make
 715     if make --version > /dev/null 2>&1; then
 716         true
 717     else
 718         BSD_MAKEFILE=yes
 719         ap_make_include=.include
 720         ap_make_delimiter='"'
 721     fi
 722     ;;
 723 esac
 724 AC_SUBST(ap_make_include)
 725 AC_SUBST(ap_make_delimiter)
 726
 727 dnl Ensure that docs/conf is created.
 728 test -d docs/conf||$mkdir_p docs/conf
 729
 730 dnl Ensure that the httpd version is included
 731 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
 732 AC_SUBST(HTTPD_VERSION)
 733
 734 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 735   APACHE_GEN_MAKEFILES
 736 ])
 737
 738 case $MPM_SUBDIR_NAME in
 739 *experimental*)
 740     echo ""
 741     echo ""
 742     echo "============================================================"
 743     echo "    WARNING: THE '${APACHE_MPM}' MPM IS EXPERIMENTAL"
 744     echo "============================================================"
 745     echo " The selected MPM might not be fully functional!"
 746     echo ""
 747     echo " Development of this MPM is not complete. Do not use this"
 748     echo " MPM unless you are a programmer willing to help fix it."
 749     echo ""
 750     echo " If you are looking for a stable server, you should not use"
 751     echo " the '${APACHE_MPM}' MPM until it is moved out of experimental."
 752     echo "============================================================"
 753     echo ""
 754     echo ""
 755     ;;
 756 esac