cp/nucleus/int.s

   1 /*
   2  * (C) Copyright 2007-2010  Josef 'Jeff' Sipek <jeffpc@josefsipek.net>
   3  *
   4  * This file is released under the GPLv2.  See the COPYING file for more
   5  * details.
   6  */
   7
   8 .text
   9
  10 #include <interrupt.h>
  11
  12 #
  13 # IO Interrupt
  14 #
  15         .align  4
  16 .globl IO_INT
  17         .type   IO_INT, @function
  18 IO_INT:
  19         # save regs
  20         STMG    %r0,%r15,0x200(%r0)
  21
  22         # set up stack
  23         LARL    %r15, int_stack_ptr
  24         LG      %r15, 0(%r15)
  25         AGHI    %r15,-160
  26
  27         LARL    %r14, __io_int_handler
  28         BALR    %r14, %r14              # call the real handler
  29
  30         # restore regs
  31         LMG     %r0,%r15,0x200(%r0)
  32
  33         LPSWE   0x170                   # go back to what we interrupted
  34
  35
  36 #
  37 # External Interrupt
  38 #
  39         .align 4
  40 .globl EXT_INT
  41         .type   EXT_INT, @function
  42 EXT_INT:
  43         # save regs
  44         STMG    %r0,%r15,0x200(%r0)
  45
  46         # set up stack
  47         LARL    %r15, int_stack_ptr
  48         LG      %r15, 0(%r15)
  49         AGHI    %r15,-160
  50
  51         LARL    %r14, __ext_int_handler
  52         BALR    %r14, %r14              # call the real handler
  53
  54         #
  55         # NOTE: we may never return from the C-interrupt handler if the
  56         # interrupt was caused by the timer clock, in which case the
  57         # scheduler kicks in, and gives control to someone else
  58         #
  59
  60         # restore regs
  61         LMG     %r0,%r15,0x200(%r0)
  62
  63         LPSWE   0x130                   # go back to what we interrupted
  64
  65
  66 #
  67 # Supervisor-Call Interrupt
  68 #
  69         .align 4
  70 .globl SVC_INT
  71         .type   SVC_INT, @function
  72 SVC_INT:
  73         # save regs
  74         STMG    %r0,%r15,0x200(%r0)
  75
  76         # set up stack
  77         LARL    %r15, int_stack_ptr
  78         LG      %r15, 0(%r15)
  79         AGHI    %r15,-160
  80
  81         # find the right handler
  82         LARL    %r14, svc_table         # table address
  83         LGH     %r2, 0x8a               # interruption code
  84         SLL     %r2, 3
  85                                         # byte offset into table
  86         LG      %r14, 0(%r2,%r14)       # load value from table
  87
  88         BALR    %r14, %r14              # call the real handler
  89
  90         # restore regs
  91         LMG     %r0,%r15,0x200(%r0)
  92
  93         LPSWE   0x140                   # go back to what we interrupted
  94
  95
  96 #
  97 # Program Interrupt
  98 #
  99         .align 4
 100 .globl PGM_INT
 101         .type   PGM_INT, @function
 102 PGM_INT:
 103         # save regs
 104         STMG    %r0,%r15,0x200(%r0)
 105
 106         # set up stack
 107         LARL    %r15, int_stack_ptr
 108         LG      %r15, 0(%r15)
 109         AGHI    %r15,-160
 110
 111         LARL    %r14, __pgm_int_handler
 112         BALR    %r14, %r14              # call the real handler
 113
 114         #
 115         # NOTE: we may never return from the C-interrupt handler
 116         #
 117
 118         # restore regs
 119         LMG     %r0,%r15,0x200(%r0)
 120
 121         LPSWE   0x150                   # go back to what we interrupted
 122
 123
 124 #
 125 # Machine Check Interrupt
 126 #
 127         .align 4
 128 .globl MCH_INT
 129         .type   MCH_INT, @function
 130 MCH_INT:
 131         # save regs
 132         STMG    %r0,%r15,0x200(%r0)
 133
 134         # set up stack
 135         LARL    %r15, int_stack_ptr
 136         LG      %r15, 0(%r15)
 137         AGHI    %r15,-160
 138
 139         LARL    %r14, __mch_int_handler
 140         BALR    %r14, %r14              # call the real handler
 141
 142         #
 143         # NOTE: we may never return from the C-interrupt handler
 144         #
 145
 146         # restore regs
 147         LMG     %r0,%r15,0x200(%r0)
 148
 149         LPSWE   0x160                   # go back to what we interrupted