IkiWiki/Plugin/comments.pm

   1 #!/usr/bin/perl
   2 # Copyright © 2006-2008 Joey Hess <joey@ikiwiki.info>
   3 # Copyright © 2008 Simon McVittie <http://smcv.pseudorandom.co.uk/>
   4 # Licensed under the GNU GPL, version 2, or any later version published by the
   5 # Free Software Foundation
   6 package IkiWiki::Plugin::comments;
   7
   8 use warnings;
   9 use strict;
  10 use IkiWiki 3.00;
  11 use Encode;
  12 use POSIX qw(strftime);
  13
  14 use constant PREVIEW => "Preview";
  15 use constant POST_COMMENT => "Post comment";
  16 use constant CANCEL => "Cancel";
  17
  18 my $postcomment;
  19 my %commentstate;
  20
  21 sub import {
  22         hook(type => "checkconfig", id => 'comments',  call => \&checkconfig);
  23         hook(type => "getsetup", id => 'comments',  call => \&getsetup);
  24         hook(type => "preprocess", id => 'comment', call => \&preprocess);
  25         hook(type => "preprocess", id => 'commentmoderation', call => \&preprocess_moderation);
  26         # here for backwards compatability with old comments
  27         hook(type => "preprocess", id => '_comment', call => \&preprocess);
  28         hook(type => "sessioncgi", id => 'comment', call => \&sessioncgi);
  29         hook(type => "htmlize", id => "_comment", call => \&htmlize);
  30         hook(type => "htmlize", id => "_comment_pending",
  31                 call => \&htmlize_pending);
  32         hook(type => "pagetemplate", id => "comments", call => \&pagetemplate);
  33         hook(type => "formbuilder_setup", id => "comments",
  34                 call => \&formbuilder_setup);
  35         # Load goto to fix up user page links for logged-in commenters
  36         IkiWiki::loadplugin("goto");
  37         IkiWiki::loadplugin("inline");
  38 }
  39
  40 sub getsetup () {
  41         return
  42                 plugin => {
  43                         safe => 1,
  44                         rebuild => 1,
  45                         section => "web",
  46                 },
  47                 comments_pagespec => {
  48                         type => 'pagespec',
  49                         example => 'blog/* and !*/Discussion',
  50                         description => 'PageSpec of pages where comments are allowed',
  51                         link => 'ikiwiki/PageSpec',
  52                         safe => 1,
  53                         rebuild => 1,
  54                 },
  55                 comments_closed_pagespec => {
  56                         type => 'pagespec',
  57                         example => 'blog/controversial or blog/flamewar',
  58                         description => 'PageSpec of pages where posting new comments is not allowed',
  59                         link => 'ikiwiki/PageSpec',
  60                         safe => 1,
  61                         rebuild => 1,
  62                 },
  63                 comments_pagename => {
  64                         type => 'string',
  65                         default => 'comment_',
  66                         description => 'Base name for comments, e.g. "comment_" for pages like "sandbox/comment_12"',
  67                         safe => 0, # manual page moving required
  68                         rebuild => undef,
  69                 },
  70                 comments_allowdirectives => {
  71                         type => 'boolean',
  72                         example => 0,
  73                         description => 'Interpret directives in comments?',
  74                         safe => 1,
  75                         rebuild => 0,
  76                 },
  77                 comments_allowauthor => {
  78                         type => 'boolean',
  79                         example => 0,
  80                         description => 'Allow anonymous commenters to set an author name?',
  81                         safe => 1,
  82                         rebuild => 0,
  83                 },
  84                 comments_commit => {
  85                         type => 'boolean',
  86                         example => 1,
  87                         description => 'commit comments to the VCS',
  88                         # old uncommitted comments are likely to cause
  89                         # confusion if this is changed
  90                         safe => 0,
  91                         rebuild => 0,
  92                 },
  93 }
  94
  95 sub checkconfig () {
  96         $config{comments_commit} = 1
  97                 unless defined $config{comments_commit};
  98         $config{comments_pagespec} = ''
  99                 unless defined $config{comments_pagespec};
 100         $config{comments_closed_pagespec} = ''
 101                 unless defined $config{comments_closed_pagespec};
 102         $config{comments_pagename} = 'comment_'
 103                 unless defined $config{comments_pagename};
 104 }
 105
 106 sub htmlize {
 107         my %params = @_;
 108         return $params{content};
 109 }
 110
 111 sub htmlize_pending {
 112         my %params = @_;
 113         return sprintf(gettext("this comment needs %s"),
 114                 '<a href="'.
 115                 IkiWiki::cgiurl(do => "commentmoderation").'">'.
 116                 gettext("moderation").'</a>');
 117 }
 118
 119 # FIXME: copied verbatim from meta
 120 sub safeurl ($) {
 121         my $url=shift;
 122         if (exists $IkiWiki::Plugin::htmlscrubber::{safe_url_regexp} &&
 123             defined $IkiWiki::Plugin::htmlscrubber::safe_url_regexp) {
 124                 return $url=~/$IkiWiki::Plugin::htmlscrubber::safe_url_regexp/;
 125         }
 126         else {
 127                 return 1;
 128         }
 129 }
 130
 131 sub preprocess {
 132         my %params = @_;
 133         my $page = $params{page};
 134
 135         my $format = $params{format};
 136         if (defined $format && ! exists $IkiWiki::hooks{htmlize}{$format}) {
 137                 error(sprintf(gettext("unsupported page format %s"), $format));
 138         }
 139
 140         my $content = $params{content};
 141         if (! defined $content) {
 142                 error(gettext("comment must have content"));
 143         }
 144         $content =~ s/\\"/"/g;
 145
 146         if ($config{comments_allowdirectives}) {
 147                 $content = IkiWiki::preprocess($page, $params{destpage},
 148                         $content);
 149         }
 150
 151         # no need to bother with htmlize if it's just HTML
 152         $content = IkiWiki::htmlize($page, $params{destpage}, $format, $content)
 153                 if defined $format;
 154
 155         IkiWiki::run_hooks(sanitize => sub {
 156                 $content = shift->(
 157                         page => $page,
 158                         destpage => $params{destpage},
 159                         content => $content,
 160                 );
 161         });
 162
 163         # set metadata, possibly overriding [[!meta]] directives from the
 164         # comment itself
 165
 166         my $commentuser;
 167         my $commentip;
 168         my $commentauthor;
 169         my $commentauthorurl;
 170         my $commentopenid;
 171         if (defined $params{username}) {
 172                 $commentuser = $params{username};
 173
 174                 my $oiduser = eval { IkiWiki::openiduser($commentuser) };
 175
 176                 if (defined $oiduser) {
 177                         # looks like an OpenID
 178                         $commentauthorurl = $commentuser;
 179                         $commentauthor = (defined $params{nickname} && length $params{nickname}) ? $params{nickname} : $oiduser;
 180                         $commentopenid = $commentuser;
 181                 }
 182                 else {
 183                         $commentauthorurl = IkiWiki::cgiurl(
 184                                 do => 'goto',
 185                                 page => IkiWiki::userpage($commentuser)
 186                         );
 187
 188                         $commentauthor = $commentuser;
 189                 }
 190         }
 191         else {
 192                 if (defined $params{ip}) {
 193                         $commentip = $params{ip};
 194                 }
 195                 $commentauthor = gettext("Anonymous");
 196         }
 197
 198         $commentstate{$page}{commentuser} = $commentuser;
 199         $commentstate{$page}{commentopenid} = $commentopenid;
 200         $commentstate{$page}{commentip} = $commentip;
 201         $commentstate{$page}{commentauthor} = $commentauthor;
 202         $commentstate{$page}{commentauthorurl} = $commentauthorurl;
 203         if (! defined $pagestate{$page}{meta}{author}) {
 204                 $pagestate{$page}{meta}{author} = $commentauthor;
 205         }
 206         if (! defined $pagestate{$page}{meta}{authorurl}) {
 207                 $pagestate{$page}{meta}{authorurl} = $commentauthorurl;
 208         }
 209
 210         if ($config{comments_allowauthor}) {
 211                 if (defined $params{claimedauthor}) {
 212                         $pagestate{$page}{meta}{author} = $params{claimedauthor};
 213                 }
 214
 215                 if (defined $params{url}) {
 216                         my $url=$params{url};
 217
 218                         eval q{use URI::Heuristic};
 219                         if (! $@) {
 220                                 $url=URI::Heuristic::uf_uristr($url);
 221                         }
 222
 223                         if (safeurl($url)) {
 224                                 $pagestate{$page}{meta}{authorurl} = $url;
 225                         }
 226                 }
 227         }
 228         else {
 229                 $pagestate{$page}{meta}{author} = $commentauthor;
 230                 $pagestate{$page}{meta}{authorurl} = $commentauthorurl;
 231         }
 232
 233         if (defined $params{subject}) {
 234                 # decode title the same way meta does
 235                 eval q{use HTML::Entities};
 236                 $pagestate{$page}{meta}{title} = decode_entities($params{subject});
 237         }
 238
 239         if ($params{page} =~ m/\/\Q$config{comments_pagename}\E\d+_/) {
 240                 $pagestate{$page}{meta}{permalink} = urlto(IkiWiki::dirname($params{page})).
 241                         "#".page_to_id($params{page});
 242         }
 243
 244         eval q{use Date::Parse};
 245         if (! $@) {
 246                 my $time = str2time($params{date});
 247                 $IkiWiki::pagectime{$page} = $time if defined $time;
 248         }
 249
 250         return $content;
 251 }
 252
 253 sub preprocess_moderation {
 254         my %params = @_;
 255
 256         $params{desc}=gettext("Comment Moderation")
 257                 unless defined $params{desc};
 258
 259         if (length $config{cgiurl}) {
 260                 return '<a href="'.
 261                         IkiWiki::cgiurl(do => 'commentmoderation').
 262                         '">'.$params{desc}.'</a>';
 263         }
 264         else {
 265                 return $params{desc};
 266         }
 267 }
 268
 269 sub sessioncgi ($$) {
 270         my $cgi=shift;
 271         my $session=shift;
 272
 273         my $do = $cgi->param('do');
 274         if ($do eq 'comment') {
 275                 editcomment($cgi, $session);
 276         }
 277         elsif ($do eq 'commentmoderation') {
 278                 commentmoderation($cgi, $session);
 279         }
 280         elsif ($do eq 'commentsignin') {
 281                 IkiWiki::cgi_signin($cgi, $session);
 282                 exit;
 283         }
 284 }
 285
 286 # Mostly cargo-culted from IkiWiki::plugin::editpage
 287 sub editcomment ($$) {
 288         my $cgi=shift;
 289         my $session=shift;
 290
 291         IkiWiki::decode_cgi_utf8($cgi);
 292
 293         eval q{use CGI::FormBuilder};
 294         error($@) if $@;
 295
 296         my @buttons = (POST_COMMENT, PREVIEW, CANCEL);
 297         my $form = CGI::FormBuilder->new(
 298                 fields => [qw{do sid page subject editcontent type author url}],
 299                 charset => 'utf-8',
 300                 method => 'POST',
 301                 required => [qw{editcontent}],
 302                 javascript => 0,
 303                 params => $cgi,
 304                 action => IkiWiki::cgiurl(),
 305                 header => 0,
 306                 table => 0,
 307                 template => { template('editcomment.tmpl') },
 308         );
 309
 310         IkiWiki::decode_form_utf8($form);
 311         IkiWiki::run_hooks(formbuilder_setup => sub {
 312                         shift->(title => "comment", form => $form, cgi => $cgi,
 313                                 session => $session, buttons => \@buttons);
 314                 });
 315         IkiWiki::decode_form_utf8($form);
 316
 317         my $type = $form->param('type');
 318         if (defined $type && length $type && $IkiWiki::hooks{htmlize}{$type}) {
 319                 $type = IkiWiki::possibly_foolish_untaint($type);
 320         }
 321         else {
 322                 $type = $config{default_pageext};
 323         }
 324
 325
 326         my @page_types;
 327         if (exists $IkiWiki::hooks{htmlize}) {
 328                 foreach my $key (grep { !/^_/ } keys %{$IkiWiki::hooks{htmlize}}) {
 329                         push @page_types, [$key, $IkiWiki::hooks{htmlize}{$key}{longname} || $key];
 330                 }
 331         }
 332         @page_types=sort @page_types;
 333
 334         $form->field(name => 'do', type => 'hidden');
 335         $form->field(name => 'sid', type => 'hidden', value => $session->id,
 336                 force => 1);
 337         $form->field(name => 'page', type => 'hidden');
 338         $form->field(name => 'subject', type => 'text', size => 72);
 339         $form->field(name => 'editcontent', type => 'textarea', rows => 10);
 340         $form->field(name => "type", value => $type, force => 1,
 341                 type => 'select', options => \@page_types);
 342
 343         $form->tmpl_param(username => $session->param('name'));
 344
 345         if ($config{comments_allowauthor} and
 346             ! defined $session->param('name')) {
 347                 $form->tmpl_param(allowauthor => 1);
 348                 $form->field(name => 'author', type => 'text', size => '40');
 349                 $form->field(name => 'url', type => 'text', size => '40');
 350         }
 351         else {
 352                 $form->tmpl_param(allowauthor => 0);
 353                 $form->field(name => 'author', type => 'hidden', value => '',
 354                         force => 1);
 355                 $form->field(name => 'url', type => 'hidden', value => '',
 356                         force => 1);
 357         }
 358
 359         if (! defined $session->param('name')) {
 360                 # Make signinurl work and return here.
 361                 $form->tmpl_param(signinurl => IkiWiki::cgiurl(do => 'commentsignin'));
 362                 $session->param(postsignin => $ENV{QUERY_STRING});
 363                 IkiWiki::cgi_savesession($session);
 364         }
 365
 366         # The untaint is OK (as in editpage) because we're about to pass
 367         # it to file_pruned and wiki_file_regexp anyway.
 368         my ($page) = $form->field('page')=~/$config{wiki_file_regexp}/;
 369         $page = IkiWiki::possibly_foolish_untaint($page);
 370         if (! defined $page || ! length $page ||
 371                 IkiWiki::file_pruned($page)) {
 372                 error(gettext("bad page name"));
 373         }
 374
 375         $form->title(sprintf(gettext("commenting on %s"),
 376                         IkiWiki::pagetitle(IkiWiki::basename($page))));
 377
 378         $form->tmpl_param('helponformattinglink',
 379                 htmllink($page, $page, 'ikiwiki/formatting',
 380                         noimageinline => 1,
 381                         linktext => 'FormattingHelp'),
 382                         allowdirectives => $config{allow_directives});
 383
 384         if ($form->submitted eq CANCEL) {
 385                 # bounce back to the page they wanted to comment on, and exit.
 386                 IkiWiki::redirect($cgi, urlto($page));
 387                 exit;
 388         }
 389
 390         if (not exists $pagesources{$page}) {
 391                 error(sprintf(gettext(
 392                         "page '%s' doesn't exist, so you can't comment"),
 393                         $page));
 394         }
 395
 396         if (pagespec_match($page, $config{comments_closed_pagespec},
 397                 location => $page)) {
 398                 error(sprintf(gettext(
 399                         "comments on page '%s' are closed"),
 400                         $page));
 401         }
 402
 403         # Set a flag to indicate that we're posting a comment,
 404         # so that postcomment() can tell it should match.
 405         $postcomment=1;
 406         IkiWiki::check_canedit($page, $cgi, $session);
 407         $postcomment=0;
 408
 409         my $content = "[[!comment format=$type\n";
 410
 411         if (defined $session->param('name')) {
 412                 my $username = $session->param('name');
 413                 $username =~ s/"/&quot;/g;
 414                 $content .= " username=\"$username\"\n";
 415         }
 416         if (defined $session->param('nickname')) {
 417                 my $nickname = $session->param('nickname');
 418                 $nickname =~ s/"/&quot;/g;
 419                 $content .= " nickname=\"$nickname\"\n";
 420         }
 421         elsif (defined $session->remote_addr()) {
 422                 my $ip = $session->remote_addr();
 423                 if ($ip =~ m/^([.0-9]+)$/) {
 424                         $content .= " ip=\"$1\"\n";
 425                 }
 426         }
 427
 428         if ($config{comments_allowauthor}) {
 429                 my $author = $form->field('author');
 430                 if (defined $author && length $author) {
 431                         $author =~ s/"/&quot;/g;
 432                         $content .= " claimedauthor=\"$author\"\n";
 433                 }
 434                 my $url = $form->field('url');
 435                 if (defined $url && length $url) {
 436                         $url =~ s/"/&quot;/g;
 437                         $content .= " url=\"$url\"\n";
 438                 }
 439         }
 440
 441         my $subject = $form->field('subject');
 442         if (defined $subject && length $subject) {
 443                 $subject =~ s/"/&quot;/g;
 444         }
 445         else {
 446                 $subject = "comment ".(num_comments($page, $config{srcdir}) + 1);
 447         }
 448         $content .= " subject=\"$subject\"\n";
 449
 450         $content .= " date=\"" . decode_utf8(strftime('%Y-%m-%dT%H:%M:%SZ', gmtime)) . "\"\n";
 451
 452         my $editcontent = $form->field('editcontent');
 453         $editcontent="" if ! defined $editcontent;
 454         $editcontent =~ s/\r\n/\n/g;
 455         $editcontent =~ s/\r/\n/g;
 456         $editcontent =~ s/"/\\"/g;
 457         $content .= " content=\"\"\"\n$editcontent\n\"\"\"]]\n";
 458
 459         my $location=unique_comment_location($page, $content, $config{srcdir});
 460
 461         # This is essentially a simplified version of editpage:
 462         # - the user does not control the page that's created, only the parent
 463         # - it's always a create operation, never an edit
 464         # - this means that conflicts should never happen
 465         # - this means that if they do, rocks fall and everyone dies
 466
 467         if ($form->submitted eq PREVIEW) {
 468                 my $preview=previewcomment($content, $location, $page, time);
 469                 IkiWiki::run_hooks(format => sub {
 470                         $preview = shift->(page => $page,
 471                                 content => $preview);
 472                 });
 473                 $form->tmpl_param(page_preview => $preview);
 474         }
 475         else {
 476                 $form->tmpl_param(page_preview => "");
 477         }
 478
 479         if ($form->submitted eq POST_COMMENT && $form->validate) {
 480                 IkiWiki::checksessionexpiry($cgi, $session);
 481
 482                 $postcomment=1;
 483                 my $ok=IkiWiki::check_content(content => $form->field('editcontent'),
 484                         subject => $form->field('subject'),
 485                         $config{comments_allowauthor} ? (
 486                                 author => $form->field('author'),
 487                                 url => $form->field('url'),
 488                         ) : (),
 489                         page => $location,
 490                         cgi => $cgi,
 491                         session => $session,
 492                         nonfatal => 1,
 493                 );
 494                 $postcomment=0;
 495
 496                 if (! $ok) {
 497                         $location=unique_comment_location($page, $content, $config{srcdir}, "._comment_pending");
 498                         writefile("$location._comment_pending", $config{srcdir}, $content);
 499
 500                         # Refresh so anything that deals with pending
 501                         # comments can be updated.
 502                         require IkiWiki::Render;
 503                         IkiWiki::refresh();
 504                         IkiWiki::saveindex();
 505
 506                         IkiWiki::printheader($session);
 507                         print IkiWiki::cgitemplate($cgi, gettext(gettext("comment stored for moderation")),
 508                                 "<p>".
 509                                 gettext("Your comment will be posted after moderator review").
 510                                 "</p>");
 511                         exit;
 512                 }
 513
 514                 # FIXME: could probably do some sort of graceful retry
 515                 # on error? Would require significant unwinding though
 516                 my $file = "$location._comment";
 517                 writefile($file, $config{srcdir}, $content);
 518
 519                 my $conflict;
 520
 521                 if ($config{rcs} and $config{comments_commit}) {
 522                         my $message = gettext("Added a comment");
 523                         if (defined $form->field('subject') &&
 524                                 length $form->field('subject')) {
 525                                 $message = sprintf(
 526                                         gettext("Added a comment: %s"),
 527                                         $form->field('subject'));
 528                         }
 529
 530                         IkiWiki::rcs_add($file);
 531                         IkiWiki::disable_commit_hook();
 532                         $conflict = IkiWiki::rcs_commit_staged(
 533                                 message => $message,
 534                                 session => $session,
 535                         );
 536                         IkiWiki::enable_commit_hook();
 537                         IkiWiki::rcs_update();
 538                 }
 539
 540                 # Now we need a refresh
 541                 require IkiWiki::Render;
 542                 IkiWiki::refresh();
 543                 IkiWiki::saveindex();
 544
 545                 # this should never happen, unless a committer deliberately
 546                 # breaks it or something
 547                 error($conflict) if defined $conflict;
 548
 549                 # Jump to the new comment on the page.
 550                 # The trailing question mark tries to avoid broken
 551                 # caches and get the most recent version of the page.
 552                 IkiWiki::redirect($cgi, urlto($page).
 553                         "?updated#".page_to_id($location));
 554
 555         }
 556         else {
 557                 IkiWiki::showform($form, \@buttons, $session, $cgi,
 558                         page => $page);
 559         }
 560
 561         exit;
 562 }
 563
 564 sub commentmoderation ($$) {
 565         my $cgi=shift;
 566         my $session=shift;
 567
 568         IkiWiki::needsignin($cgi, $session);
 569         if (! IkiWiki::is_admin($session->param("name"))) {
 570                 error(gettext("you are not logged in as an admin"));
 571         }
 572
 573         IkiWiki::decode_cgi_utf8($cgi);
 574
 575         if (defined $cgi->param('sid')) {
 576                 IkiWiki::checksessionexpiry($cgi, $session);
 577
 578                 my $rejectalldefer=$cgi->param('rejectalldefer');
 579
 580                 my %vars=$cgi->Vars;
 581                 my $added=0;
 582                 foreach my $id (keys %vars) {
 583                         if ($id =~ /(.*)\._comment(?:_pending)?$/) {
 584                                 $id=decode_utf8($id);
 585                                 my $action=$cgi->param($id);
 586                                 next if $action eq 'Defer' && ! $rejectalldefer;
 587
 588                                 # Make sure that the id is of a legal
 589                                 # pending comment.
 590                                 my ($f) = $id =~ /$config{wiki_file_regexp}/;
 591                                 if (! defined $f || ! length $f ||
 592                                     IkiWiki::file_pruned($f)) {
 593                                         error("illegal file");
 594                                 }
 595
 596                                 my $page=IkiWiki::dirname($f);
 597                                 my $file="$config{srcdir}/$f";
 598                                 if (! -e $file) {
 599                                         # old location
 600                                         $file="$config{wikistatedir}/comments_pending/".$f;
 601                                 }
 602
 603                                 if ($action eq 'Accept') {
 604                                         my $content=eval { readfile($file) };
 605                                         next if $@; # file vanished since form was displayed
 606                                         my $dest=unique_comment_location($page, $content, $config{srcdir})."._comment";
 607                                         writefile($dest, $config{srcdir}, $content);
 608                                         if ($config{rcs} and $config{comments_commit}) {
 609                                                 IkiWiki::rcs_add($dest);
 610                                         }
 611                                         $added++;
 612                                 }
 613
 614                                 require IkiWiki::Render;
 615                                 IkiWiki::prune($file);
 616                         }
 617                 }
 618
 619                 if ($added) {
 620                         my $conflict;
 621                         if ($config{rcs} and $config{comments_commit}) {
 622                                 my $message = gettext("Comment moderation");
 623                                 IkiWiki::disable_commit_hook();
 624                                 $conflict=IkiWiki::rcs_commit_staged(
 625                                         message => $message,
 626                                         session => $session,
 627                                 );
 628                                 IkiWiki::enable_commit_hook();
 629                                 IkiWiki::rcs_update();
 630                         }
 631
 632                         # Now we need a refresh
 633                         require IkiWiki::Render;
 634                         IkiWiki::refresh();
 635                         IkiWiki::saveindex();
 636
 637                         error($conflict) if defined $conflict;
 638                 }
 639         }
 640
 641         my @comments=map {
 642                 my ($id, $dir, $ctime)=@{$_};
 643                 my $content=readfile("$dir/$id");
 644                 my $preview=previewcomment($content, $id,
 645                         $id, $ctime);
 646                 {
 647                         id => $id,
 648                         view => $preview,
 649                 }
 650         } sort { $b->[2] <=> $a->[2] } comments_pending();
 651
 652         my $template=template("commentmoderation.tmpl");
 653         $template->param(
 654                 sid => $session->id,
 655                 comments => \@comments,
 656                 cgiurl => IkiWiki::cgiurl(),
 657         );
 658         IkiWiki::printheader($session);
 659         my $out=$template->output;
 660         IkiWiki::run_hooks(format => sub {
 661                 $out = shift->(page => "", content => $out);
 662         });
 663         print IkiWiki::cgitemplate($cgi, gettext("comment moderation"), $out);
 664         exit;
 665 }
 666
 667 sub formbuilder_setup (@) {
 668         my %params=@_;
 669
 670         my $form=$params{form};
 671         if ($form->title eq "preferences" &&
 672             IkiWiki::is_admin($params{session}->param("name"))) {
 673                 push @{$params{buttons}}, "Comment Moderation";
 674                 if ($form->submitted && $form->submitted eq "Comment Moderation") {
 675                         commentmoderation($params{cgi}, $params{session});
 676                 }
 677         }
 678 }
 679
 680 sub comments_pending () {
 681         my @ret;
 682
 683         eval q{use File::Find};
 684         error($@) if $@;
 685         eval q{use Cwd};
 686         error($@) if $@;
 687         my $origdir=getcwd();
 688
 689         my $find_comments=sub {
 690                 my $dir=shift;
 691                 my $extension=shift;
 692                 return unless -d $dir;
 693
 694                 chdir($dir) || die "chdir $dir: $!";
 695
 696                 find({
 697                         no_chdir => 1,
 698                         wanted => sub {
 699                                 my $file=decode_utf8($_);
 700                                 $file=~s/^\.\///;
 701                                 return if ! length $file || IkiWiki::file_pruned($file)
 702                                         || -l $_ || -d _ || $file !~ /\Q$extension\E$/;
 703                                 my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 704                                 if (defined $f) {
 705                                         my $ctime=(stat($_))[10];
 706                                         push @ret, [$f, $dir, $ctime];
 707                                 }
 708                         }
 709                 }, ".");
 710
 711                 chdir($origdir) || die "chdir $origdir: $!";
 712         };
 713
 714         $find_comments->($config{srcdir}, "._comment_pending");
 715         # old location
 716         $find_comments->("$config{wikistatedir}/comments_pending/",
 717                 "._comment");
 718
 719         return @ret;
 720 }
 721
 722 sub previewcomment ($$$) {
 723         my $content=shift;
 724         my $location=shift;
 725         my $page=shift;
 726         my $time=shift;
 727
 728         # Previewing a comment should implicitly enable comment posting mode.
 729         my $oldpostcomment=$postcomment;
 730         $postcomment=1;
 731
 732         my $preview = IkiWiki::htmlize($location, $page, '_comment',
 733                         IkiWiki::linkify($location, $page,
 734                         IkiWiki::preprocess($location, $page,
 735                         IkiWiki::filter($location, $page, $content), 0, 1)));
 736
 737         my $template = template("comment.tmpl");
 738         $template->param(content => $preview);
 739         $template->param(ctime => displaytime($time, undef, 1));
 740         $template->param(html5 => $config{html5});
 741
 742         IkiWiki::run_hooks(pagetemplate => sub {
 743                 shift->(page => $location,
 744                         destpage => $page,
 745                         template => $template);
 746         });
 747
 748         $template->param(have_actions => 0);
 749
 750         $postcomment=$oldpostcomment;
 751
 752         return $template->output;
 753 }
 754
 755 sub commentsshown ($) {
 756         my $page=shift;
 757
 758         return ! pagespec_match($page, "comment(*)",
 759                                 location => $page) &&
 760                pagespec_match($page, $config{comments_pagespec},
 761                               location => $page);
 762 }
 763
 764 sub commentsopen ($) {
 765         my $page = shift;
 766
 767         return length $config{cgiurl} > 0 &&
 768                (! length $config{comments_closed_pagespec} ||
 769                 ! pagespec_match($page, $config{comments_closed_pagespec},
 770                                  location => $page));
 771 }
 772
 773 sub pagetemplate (@) {
 774         my %params = @_;
 775
 776         my $page = $params{page};
 777         my $template = $params{template};
 778         my $shown = ($template->query(name => 'commentslink') ||
 779                      $template->query(name => 'commentsurl') ||
 780                      $template->query(name => 'atomcommentsurl') ||
 781                      $template->query(name => 'comments')) &&
 782                     commentsshown($page);
 783
 784         if ($template->query(name => 'comments')) {
 785                 my $comments = undef;
 786                 if ($shown) {
 787                         $comments = IkiWiki::preprocess_inline(
 788                                 pages => "comment($page)",
 789                                 template => 'comment',
 790                                 show => 0,
 791                                 reverse => 'yes',
 792                                 page => $page,
 793                                 destpage => $params{destpage},
 794                                 feedfile => 'comments',
 795                                 emptyfeeds => 'no',
 796                         );
 797                 }
 798
 799                 if (defined $comments && length $comments) {
 800                         $template->param(comments => $comments);
 801                 }
 802
 803                 if ($shown && commentsopen($page)) {
 804                         $template->param(addcommenturl => addcommenturl($page));
 805                 }
 806         }
 807
 808         if ($shown) {
 809                 if ($template->query(name => 'commentsurl')) {
 810                         $template->param(commentsurl =>
 811                                 urlto($page).'#comments');
 812                 }
 813
 814                 if ($template->query(name => 'atomcommentsurl') && $config{usedirs}) {
 815                         # This will 404 until there are some comments, but I
 816                         # think that's probably OK...
 817                         $template->param(atomcommentsurl =>
 818                                 urlto($page).'comments.atom');
 819                 }
 820
 821                 if ($template->query(name => 'commentslink')) {
 822                         my $num=num_comments($page, $config{srcdir});
 823                         my $link;
 824                         if ($num > 0) {
 825                                 $link = htmllink($page, $params{destpage}, $page,
 826                                         linktext => sprintf(ngettext("%i comment", "%i comments", $num), $num),
 827                                         anchor => "comments",
 828                                         noimageinline => 1
 829                                 );
 830                         }
 831                         elsif (commentsopen($page)) {
 832                                 $link = "<a href=\"".addcommenturl($page)."\">".
 833                                         #translators: Here "Comment" is a verb;
 834                                         #translators: the user clicks on it to
 835                                         #translators: post a comment.
 836                                         gettext("Comment").
 837                                         "</a>";
 838                         }
 839                         $template->param(commentslink => $link)
 840                                 if defined $link;
 841                 }
 842         }
 843
 844         # everything below this point is only relevant to the comments
 845         # themselves
 846         if (!exists $commentstate{$page}) {
 847                 return;
 848         }
 849
 850         if ($template->query(name => 'commentid')) {
 851                 $template->param(commentid => page_to_id($page));
 852         }
 853
 854         if ($template->query(name => 'commentuser')) {
 855                 $template->param(commentuser =>
 856                         $commentstate{$page}{commentuser});
 857         }
 858
 859         if ($template->query(name => 'commentopenid')) {
 860                 $template->param(commentopenid =>
 861                         $commentstate{$page}{commentopenid});
 862         }
 863
 864         if ($template->query(name => 'commentip')) {
 865                 $template->param(commentip =>
 866                         $commentstate{$page}{commentip});
 867         }
 868
 869         if ($template->query(name => 'commentauthor')) {
 870                 $template->param(commentauthor =>
 871                         $commentstate{$page}{commentauthor});
 872         }
 873
 874         if ($template->query(name => 'commentauthorurl')) {
 875                 $template->param(commentauthorurl =>
 876                         $commentstate{$page}{commentauthorurl});
 877         }
 878
 879         if ($template->query(name => 'removeurl') &&
 880             IkiWiki::Plugin::remove->can("check_canremove") &&
 881             length $config{cgiurl}) {
 882                 $template->param(removeurl => IkiWiki::cgiurl(do => 'remove',
 883                         page => $page));
 884                 $template->param(have_actions => 1);
 885         }
 886 }
 887
 888 sub addcommenturl ($) {
 889         my $page=shift;
 890
 891         return IkiWiki::cgiurl(do => 'comment', page => $page);
 892 }
 893
 894 sub num_comments ($$) {
 895         my $page=shift;
 896         my $dir=shift;
 897
 898         my @comments=glob("$dir/$page/$config{comments_pagename}*._comment");
 899         return int @comments;
 900 }
 901
 902 sub unique_comment_location ($$$$) {
 903         my $page=shift;
 904         eval q{use Digest::MD5 'md5_hex'};
 905         error($@) if $@;
 906         my $content_md5=md5_hex(Encode::encode_utf8(shift));
 907         my $dir=shift;
 908         my $ext=shift || "._comment";
 909
 910         my $location;
 911         my $i = num_comments($page, $dir);
 912         do {
 913                 $i++;
 914                 $location = "$page/$config{comments_pagename}${i}_${content_md5}";
 915         } while (-e "$dir/$location$ext");
 916
 917         return $location;
 918 }
 919
 920 sub page_to_id ($) {
 921         # Converts a comment page name into a unique, legal html id
 922         # attribute value, that can be used as an anchor to link to the
 923         # comment.
 924         my $page=shift;
 925
 926         eval q{use Digest::MD5 'md5_hex'};
 927         error($@) if $@;
 928
 929         return "comment-".md5_hex(Encode::encode_utf8(($page)));
 930 }
 931
 932 package IkiWiki::PageSpec;
 933
 934 sub match_postcomment ($$;@) {
 935         my $page = shift;
 936         my $glob = shift;
 937
 938         if (! $postcomment) {
 939                 return IkiWiki::FailReason->new("not posting a comment");
 940         }
 941         return match_glob($page, $glob, @_);
 942 }
 943
 944 sub match_comment ($$;@) {
 945         my $page = shift;
 946         my $glob = shift;
 947
 948         if (! $postcomment) {
 949                 # To see if it's a comment, check the source file type.
 950                 # Deal with comments that were just deleted.
 951                 my $source=exists $IkiWiki::pagesources{$page} ?
 952                         $IkiWiki::pagesources{$page} :
 953                         $IkiWiki::delpagesources{$page};
 954                 my $type=defined $source ? IkiWiki::pagetype($source) : undef;
 955                 if (! defined $type || $type ne "_comment") {
 956                         return IkiWiki::FailReason->new("$page is not a comment");
 957                 }
 958         }
 959
 960         return match_glob($page, "$glob/*", internal => 1, @_);
 961 }
 962
 963 sub match_comment_pending ($$;@) {
 964         my $page = shift;
 965         my $glob = shift;
 966
 967         my $source=exists $IkiWiki::pagesources{$page} ?
 968                 $IkiWiki::pagesources{$page} :
 969                 $IkiWiki::delpagesources{$page};
 970         my $type=defined $source ? IkiWiki::pagetype($source) : undef;
 971         if (! defined $type || $type ne "_comment_pending") {
 972                 return IkiWiki::FailReason->new("$page is not a pending comment");
 973         }
 974
 975         return match_glob($page, "$glob/*", internal => 1, @_);
 976 }
 977
 978 1