CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.13...3.18)
   2
   3 list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
   4
   5 set(MAIN_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
   6 set(MAIN_LIB_DIR "${CMAKE_CURRENT_SOURCE_DIR}/lib")
   7 set(MAIN_UTILS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/src/utils")
   8 set(MAIN_SRC_DIR "${CMAKE_CURRENT_SOURCE_DIR}/src/main")
   9 set(SVD_DIR "${CMAKE_CURRENT_SOURCE_DIR}/dev/svd")
  10 set(DOWNLOADS_DIR "${MAIN_DIR}/downloads")
  11 set(TOOLS_DIR "${MAIN_DIR}/tools")
  12
  13 option(SITL "SITL build for host system" OFF)
  14
  15 set(TOOLCHAIN_OPTIONS none arm-none-eabi host)
  16 if (SITL)
  17     if (CMAKE_HOST_APPLE)
  18         set(MACOSX TRUE)
  19     endif()
  20     set(TOOLCHAIN "host" CACHE STRING "Toolchain to use. Available: ${TOOLCHAIN_OPTIONS}")
  21 else()
  22     set(TOOLCHAIN "arm-none-eabi" CACHE STRING "Toolchain to use. Available: ${TOOLCHAIN_OPTIONS}")
  23 endif()
  24
  25 set_property(CACHE TOOLCHAIN PROPERTY STRINGS ${TOOLCHAIN_OPTIONS})
  26 if("" STREQUAL TOOLCHAIN)
  27     set(TOOLCHAIN none)
  28 endif()
  29 if (NOT ${TOOLCHAIN} IN_LIST TOOLCHAIN_OPTIONS)
  30     message(FATAL_ERROR "Invalid toolchain ${TOOLCHAIN}. Valid options are: ${TOOLCHAIN_OPTIONS}")
  31 endif()
  32
  33 option(COMPILER_VERSION_CHECK "Ensure the compiler matches the expected version" ON)
  34
  35 include(GetGitRevisionDescription)
  36 get_git_head_revision(GIT_REFSPEC GIT_SHA1)
  37 string(SUBSTRING ${GIT_SHA1} 0 8 GIT_REV)
  38
  39 # Load settings related functions, so the tests can use them
  40 include(main)
  41 include(settings)
  42
  43 if(TOOLCHAIN STREQUAL none)
  44     add_subdirectory(src/test)
  45 else()
  46     if (SITL)
  47         include("${CMAKE_CURRENT_SOURCE_DIR}/cmake/${TOOLCHAIN}.cmake")
  48     else()
  49         set(CMAKE_TOOLCHAIN_FILE "${CMAKE_CURRENT_SOURCE_DIR}/cmake/${TOOLCHAIN}.cmake")
  50         include("${CMAKE_CURRENT_SOURCE_DIR}/cmake/${TOOLCHAIN}-checks.cmake")
  51     endif()
  52 endif()
  53
  54
  55 project(INAV VERSION 9.0.0)
  56
  57 enable_language(ASM)
  58
  59 if(MACOSX AND SITL)
  60     set(CMAKE_C_STANDARD 11)
  61 else()
  62     set(CMAKE_C_STANDARD 99)
  63 endif()
  64 set(CMAKE_C_EXTENSIONS ON)
  65 set(CMAKE_C_STANDARD_REQUIRED ON)
  66 set(CMAKE_CXX_STANDARD 11)
  67 set(CMAKE_CXX_EXTENSIONS ON)
  68 set(CMAKE_CXX_STANDARD_REQUIRED ON)
  69
  70 if(CMAKE_BUILD_TYPE STREQUAL "Release" OR CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
  71     set(IS_RELEASE_BUILD ON)
  72 endif()
  73
  74 set(FIRMWARE_VERSION ${PROJECT_VERSION})
  75
  76 option(WARNINGS_AS_ERRORS "Make all warnings into errors")
  77 message("-- toolchain: ${TOOLCHAIN}, WARNINGS_AS_ERRORS: ${WARNINGS_AS_ERRORS}")
  78
  79 set(COMMON_COMPILE_DEFINITIONS
  80     FC_VERSION_MAJOR=${CMAKE_PROJECT_VERSION_MAJOR}
  81     FC_VERSION_MINOR=${CMAKE_PROJECT_VERSION_MINOR}
  82     FC_VERSION_PATCH_LEVEL=${CMAKE_PROJECT_VERSION_PATCH}
  83     FC_VERSION_TYPE="${VERSION_TYPE}"
  84 )
  85
  86 if (NOT SITL)
  87     include(openocd)
  88     include(svd)
  89 endif()
  90
  91 include(stm32)
  92 include(at32)
  93 include(sitl)
  94
  95 add_subdirectory(src)
  96
  97 collect_targets()
  98
  99 message("-- Build type: ${CMAKE_BUILD_TYPE}")
 100 include(ci)