src/main/target/link/stm32_flash_h7_split.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_split.ld
   5 **
   6 **  Abstract    : Common linker script for STM32 devices.
   7 **
   8 *****************************************************************************
   9 */
  10
  11 /* Entry Point */
  12 ENTRY(Reset_Handler)
  13
  14 /* Highest address of the user mode stack */
  15 _estack = ORIGIN(STACKRAM) + LENGTH(STACKRAM);    /* end of RAM */
  16
  17 /* Base address where the config is stored. */
  18 __config_start = ORIGIN(FLASH_CONFIG);
  19 __config_end = ORIGIN(FLASH_CONFIG) + LENGTH(FLASH_CONFIG);
  20
  21 /* Define output sections */
  22 SECTIONS
  23 {
  24   /* The startup code goes first into FLASH */
  25   .isr_vector :
  26   {
  27     . = ALIGN(4);
  28     PROVIDE (isr_vector_table_base = .);
  29     KEEP(*(.isr_vector)) /* Startup code */
  30     . = ALIGN(4);
  31   } >FLASH
  32
  33   /* The program code and other data goes into FLASH */
  34   .text :
  35   {
  36     . = ALIGN(4);
  37     *(.text)           /* .text sections (code) */
  38     *(.text*)          /* .text* sections (code) */
  39     *(.rodata)         /* .rodata sections (constants, strings, etc.) */
  40     *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
  41     *(.glue_7)         /* glue arm to thumb code */
  42     *(.glue_7t)        /* glue thumb to arm code */
  43     *(.eh_frame)
  44
  45     KEEP (*(.init))
  46     KEEP (*(.fini))
  47
  48     . = ALIGN(4);
  49     _etext = .;        /* define a global symbols at end of code */
  50   } >FLASH1
  51
  52   tcm_code = LOADADDR(.tcm_code);
  53   .tcm_code (NOLOAD) :
  54   {
  55     . = ALIGN(4);
  56     tcm_code_start = .;
  57     *(.tcm_code)
  58     *(.tcm_code*)
  59     . = ALIGN(4);
  60     tcm_code_end = .;
  61   } >ITCM_RAM AT >FLASH1
  62
  63   .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
  64   .ARM : {
  65     __exidx_start = .;
  66     *(.ARM.exidx*)
  67     __exidx_end = .;
  68   } >FLASH
  69
  70   .busdev_registry :
  71   {
  72     PROVIDE_HIDDEN (__busdev_registry_start = .);
  73     KEEP (*(.busdev_registry))
  74     KEEP (*(SORT(.busdev_registry.*)))
  75     PROVIDE_HIDDEN (__busdev_registry_end = .);
  76   } >FLASH
  77
  78   .preinit_array     :
  79   {
  80     PROVIDE_HIDDEN (__preinit_array_start = .);
  81     KEEP (*(.preinit_array*))
  82     PROVIDE_HIDDEN (__preinit_array_end = .);
  83   } >FLASH1
  84   .init_array :
  85   {
  86     PROVIDE_HIDDEN (__init_array_start = .);
  87     KEEP (*(SORT(.init_array.*)))
  88     KEEP (*(.init_array*))
  89     PROVIDE_HIDDEN (__init_array_end = .);
  90   } >FLASH1
  91   .fini_array :
  92   {
  93     PROVIDE_HIDDEN (__fini_array_start = .);
  94     KEEP (*(.fini_array*))
  95     KEEP (*(SORT(.fini_array.*)))
  96     PROVIDE_HIDDEN (__fini_array_end = .);
  97   } >FLASH1
  98   .pg_registry :
  99   {
 100     PROVIDE_HIDDEN (__pg_registry_start = .);
 101     KEEP (*(.pg_registry))
 102     KEEP (*(SORT(.pg_registry.*)))
 103     PROVIDE_HIDDEN (__pg_registry_end = .);
 104   } >FLASH1
 105   .pg_resetdata :
 106   {
 107     PROVIDE_HIDDEN (__pg_resetdata_start = .);
 108     KEEP (*(.pg_resetdata))
 109     PROVIDE_HIDDEN (__pg_resetdata_end = .);
 110   } >FLASH1
 111
 112   /* used by the startup to initialize data */
 113   _sidata = .;
 114
 115   /* Initialized data sections goes into RAM, load LMA copy after code */
 116   .data :
 117   {
 118     . = ALIGN(4);
 119     _sdata = .;        /* create a global symbol at data start */
 120     *(.data)           /* .data sections */
 121     *(.data*)          /* .data* sections */
 122
 123     . = ALIGN(4);
 124     _edata = .;        /* define a global symbol at data end */
 125   } >RAM AT> FLASH1
 126
 127   /* Uninitialized data section */
 128   . = ALIGN(4);
 129   .bss :
 130   {
 131     /* This is used by the startup in order to initialize the .bss secion */
 132     _sbss = .;         /* define a global symbol at bss start */
 133     __bss_start__ = _sbss;
 134     *(.bss)
 135     *(SORT_BY_ALIGNMENT(.bss*))
 136     *(COMMON)
 137
 138     . = ALIGN(4);
 139     _ebss = .;         /* define a global symbol at bss end */
 140     __bss_end__ = _ebss;
 141   } >RAM
 142
 143   .fastram_bss (NOLOAD) :
 144   {
 145     __fastram_bss_start__ = .;
 146     *(.fastram_bss)
 147     *(SORT_BY_ALIGNMENT(.fastram_bss*))
 148     . = ALIGN(4);
 149     __fastram_bss_end__ = .;
 150   } >FASTRAM
 151
 152   .DMA_RAM (NOLOAD) :
 153   {
 154     . = ALIGN(32);
 155     PROVIDE(dmaram_start = .);
 156     _sdmaram = .;
 157     _dmaram_start__ = _sdmaram;
 158     KEEP(*(.DMA_RAM))
 159     PROVIDE(dmaram_end = .);
 160     _edmaram = .;
 161     _dmaram_end__ = _edmaram;
 162   } >D2_RAM
 163
 164   .DMA_RW_D2 (NOLOAD) :
 165   {
 166     . = ALIGN(32);
 167     PROVIDE(dmarw_start = .);
 168     _sdmarw = .;
 169     _dmarw_start__ = _sdmarw;
 170     KEEP(*(.DMA_RW))
 171     PROVIDE(dmarw_end = .);
 172     _edmarw = .;
 173     _dmarw_end__ = _edmarw;
 174   } >D2_RAM
 175
 176   .DMA_RW_AXI (NOLOAD) :
 177   {
 178     . = ALIGN(32);
 179     PROVIDE(dmarwaxi_start = .);
 180     _sdmarwaxi = .;
 181     _dmarwaxi_start__ = _sdmarwaxi;
 182     KEEP(*(.DMA_RW_AXI))
 183     PROVIDE(dmarwaxi_end = .);
 184     _edmarwaxi = .;
 185     _dmarwaxi_end__ = _edmarwaxi;
 186   } >RAM
 187
 188   /* User_heap_stack section, used to check that there is enough RAM left */
 189   _heap_stack_end = ORIGIN(STACKRAM)+LENGTH(STACKRAM) - 8; /* 8 bytes to allow for alignment */
 190   _heap_stack_begin = _heap_stack_end - _Min_Stack_Size  - _Min_Heap_Size;
 191   . = _heap_stack_begin;
 192   ._user_heap_stack :
 193   {
 194     . = ALIGN(4);
 195     PROVIDE ( end = . );
 196     PROVIDE ( _end = . );
 197     . = . + _Min_Heap_Size;
 198     . = . + _Min_Stack_Size;
 199     . = ALIGN(4);
 200   } >STACKRAM = 0xa5
 201
 202   /* MEMORY_bank1 section, code must be located here explicitly            */
 203   /* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
 204   .memory_b1_text :
 205   {
 206     *(.mb1text)        /* .mb1text sections (code) */
 207     *(.mb1text*)       /* .mb1text* sections (code)  */
 208     *(.mb1rodata)      /* read-only data (constants) */
 209     *(.mb1rodata*)
 210   } >MEMORY_B1
 211
 212   /* Remove information from the standard libraries */
 213   /DISCARD/ :
 214   {
 215     libc.a ( * )
 216     libm.a ( * )
 217     libgcc.a ( * )
 218   }
 219
 220   .ARM.attributes 0 : { *(.ARM.attributes) }
 221 }