src/main/target/link/stm32_flash_split.ld

   1 /*
   2 *****************************************************************************
   3 **
   4 **  File        : stm32_flash_split.ld
   5 **
   6 **  Abstract    : Common linker script for STM32 devices.
   7 **
   8 *****************************************************************************
   9 */
  10
  11 /* Entry Point */
  12 ENTRY(Reset_Handler)
  13
  14 /* Highest address of the user mode stack */
  15 _estack = ORIGIN(STACKRAM) + LENGTH(STACKRAM);    /* end of RAM */
  16
  17 /* Base address where the config is stored. */
  18 __config_start = ORIGIN(FLASH_CONFIG);
  19 __config_end = ORIGIN(FLASH_CONFIG) + LENGTH(FLASH_CONFIG);
  20
  21 /* Define output sections */
  22 SECTIONS
  23 {
  24   /* The startup code goes first into FLASH */
  25   .isr_vector :
  26   {
  27     . = ALIGN(4);
  28     PROVIDE (isr_vector_table_base = .);
  29     KEEP(*(.isr_vector)) /* Startup code */
  30     . = ALIGN(4);
  31   } >FLASH
  32
  33   /* The program code and other data goes into FLASH */
  34   .text :
  35   {
  36     . = ALIGN(4);
  37     *(.text)           /* .text sections (code) */
  38     *(.text*)          /* .text* sections (code) */
  39     *(.rodata)         /* .rodata sections (constants, strings, etc.) */
  40     *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
  41     *(.glue_7)         /* glue arm to thumb code */
  42     *(.glue_7t)        /* glue thumb to arm code */
  43     *(.eh_frame)
  44
  45     KEEP (*(.init))
  46     KEEP (*(.fini))
  47
  48     . = ALIGN(4);
  49     _etext = .;        /* define a global symbols at end of code */
  50   } >FLASH1
  51
  52    .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
  53     .ARM : {
  54     __exidx_start = .;
  55       *(.ARM.exidx*)
  56       __exidx_end = .;
  57     } >FLASH
  58
  59   .busdev_registry :
  60   {
  61     PROVIDE_HIDDEN (__busdev_registry_start = .);
  62     KEEP (*(.busdev_registry))
  63     KEEP (*(SORT(.busdev_registry.*)))
  64     PROVIDE_HIDDEN (__busdev_registry_end = .);
  65   } >FLASH
  66
  67   .preinit_array     :
  68   {
  69     PROVIDE_HIDDEN (__preinit_array_start = .);
  70     KEEP (*(.preinit_array*))
  71     PROVIDE_HIDDEN (__preinit_array_end = .);
  72   } >FLASH1
  73   .init_array :
  74   {
  75     PROVIDE_HIDDEN (__init_array_start = .);
  76     KEEP (*(SORT(.init_array.*)))
  77     KEEP (*(.init_array*))
  78     PROVIDE_HIDDEN (__init_array_end = .);
  79   } >FLASH1
  80   .fini_array :
  81   {
  82     PROVIDE_HIDDEN (__fini_array_start = .);
  83     KEEP (*(.fini_array*))
  84     KEEP (*(SORT(.fini_array.*)))
  85     PROVIDE_HIDDEN (__fini_array_end = .);
  86   } >FLASH1
  87   .pg_registry :
  88   {
  89     PROVIDE_HIDDEN (__pg_registry_start = .);
  90     KEEP (*(.pg_registry))
  91     KEEP (*(SORT(.pg_registry.*)))
  92     PROVIDE_HIDDEN (__pg_registry_end = .);
  93   } >FLASH1
  94   .pg_resetdata :
  95   {
  96     PROVIDE_HIDDEN (__pg_resetdata_start = .);
  97     KEEP (*(.pg_resetdata))
  98     PROVIDE_HIDDEN (__pg_resetdata_end = .);
  99   } >FLASH1
 100
 101   /* used by the startup to initialize data */
 102   _sidata = .;
 103
 104   /* Initialized data sections goes into RAM, load LMA copy after code */
 105   .data :
 106   {
 107     . = ALIGN(4);
 108     _sdata = .;        /* create a global symbol at data start */
 109     *(.data)           /* .data sections */
 110     *(.data*)          /* .data* sections */
 111
 112     . = ALIGN(4);
 113     _edata = .;        /* define a global symbol at data end */
 114   } >RAM AT> FLASH1
 115
 116   /* Uninitialized data section */
 117   . = ALIGN(4);
 118   .bss :
 119   {
 120     /* This is used by the startup in order to initialize the .bss secion */
 121     _sbss = .;         /* define a global symbol at bss start */
 122     __bss_start__ = _sbss;
 123     *(.bss)
 124     *(SORT_BY_ALIGNMENT(.bss*))
 125     *(COMMON)
 126
 127     . = ALIGN(4);
 128     _ebss = .;         /* define a global symbol at bss end */
 129     __bss_end__ = _ebss;
 130   } >RAM
 131
 132   .fastram_bss (NOLOAD) :
 133   {
 134     __fastram_bss_start__ = .;
 135     *(.fastram_bss)
 136     *(SORT_BY_ALIGNMENT(.fastram_bss*))
 137     . = ALIGN(4);
 138     __fastram_bss_end__ = .;
 139   } >FASTRAM
 140
 141   /* User_heap_stack section, used to check that there is enough RAM left */
 142   _heap_stack_end = ORIGIN(STACKRAM)+LENGTH(STACKRAM) - 8; /* 8 bytes to allow for alignment */
 143   _heap_stack_begin = _heap_stack_end - _Min_Stack_Size  - _Min_Heap_Size;
 144   . = _heap_stack_begin;
 145   ._user_heap_stack :
 146   {
 147     . = ALIGN(4);
 148     PROVIDE ( end = . );
 149     PROVIDE ( _end = . );
 150     . = . + _Min_Heap_Size;
 151     . = . + _Min_Stack_Size;
 152     . = ALIGN(4);
 153   } >STACKRAM = 0xa5
 154
 155   /* MEMORY_bank1 section, code must be located here explicitly            */
 156   /* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
 157   .memory_b1_text :
 158   {
 159     *(.mb1text)        /* .mb1text sections (code) */
 160     *(.mb1text*)       /* .mb1text* sections (code)  */
 161     *(.mb1rodata)      /* read-only data (constants) */
 162     *(.mb1rodata*)
 163   } >MEMORY_B1
 164
 165   /* Remove information from the standard libraries */
 166   /DISCARD/ :
 167   {
 168     libc.a ( * )
 169     libm.a ( * )
 170     libgcc.a ( * )
 171   }
 172
 173   .ARM.attributes 0 : { *(.ARM.attributes) }
 174 }