libs/iovm/io/Z_Importer.io

   1 Importer := Object clone do(
   2         //metadoc Importer description A simple search path based auto-importer.
   3
   4         //doc Importer paths List of paths the proto importer will check while searching for protos to load.
   5         paths := method(FileImporter folders)
   6
   7         //doc Importer addSearchPath(path) Add a search path to the auto importer. Relative paths are made absolute before adding.
   8         addSearchPath    := method(p, paths appendIfAbsent(Path absolute(p) asSymbol))
   9
  10         //doc Importer removeSearchPath(path) Removes a search path from the auto importer. Relative paths should be removed from the same working directory as they were added.
  11         removeSearchPath := method(p, paths remove(Path absolute(p) asSymbol))
  12
  13         //doc Importer FileImporter An Importer for local source files.
  14         FileImporter := Object clone do(
  15                 importsFrom := "file"
  16
  17                 folders := list("")
  18
  19                 import := method(protoName,
  20                         if(?launchPath, folders appendIfAbsent(launchPath))
  21
  22                         folders foreach(folder,
  23                                 path := Path with(folder, protoName .. ".io") asSymbol
  24                                 if(File with(path) exists,
  25                                         Lobby doFile(path)
  26                                         return true
  27                                 )
  28                         )
  29                         false
  30                 )
  31         )
  32
  33         //doc Importer AddonImporter An Importer for addon modules.
  34         AddonImporter := Object clone do(
  35                 importsFrom := "dll"
  36
  37                 import := method(protoName,
  38                         if(hasAddon := AddonLoader hasAddonNamed(protoName),
  39                                 AddonLoader loadAddonNamed(protoName)
  40                         )
  41                         hasAddon
  42                 )
  43         )
  44
  45         //doc Importer importers List of Importer objects.
  46         importers := list(FileImporter, AddonImporter)
  47
  48         //doc Importer import(originalCallMessage) Imports an object or addon for the given Message.
  49         import := method(originalCall,
  50                 protoName := originalCall message name
  51
  52                 if(protoName at(0) isUppercase and(importer := importers detect(import(protoName))),
  53                         if(Lobby hasSlot(protoName) not,
  54                                 Exception raiseFrom(originalCall, "Importer slot '" .. protoName .. "' missing after " .. importer importsFrom .. " load")
  55                         )
  56                         Lobby getSlot(protoName)
  57                 ,
  58                         targetType := originalCall target type
  59                         Exception raiseFrom(originalCall, targetType .. " does not respond to '" .. protoName .. "'")
  60                 )
  61         )
  62
  63         //doc Importer autoImportingForward A forward method implementation placed in the Lobby when Importing is turned on.
  64         autoImportingForward := method(
  65                 Importer import(call)
  66         )
  67
  68         //doc Importer turnOn Turns on the Importer. Returns self.
  69         turnOn := method(
  70                 Lobby forward := self getSlot("autoImportingForward")
  71                 self
  72         )
  73
  74         //doc Importer turnOff Turns off the Importer. Returns self.
  75         turnOff := method(
  76                 Lobby removeSlot("forward")
  77                 self
  78         )
  79
  80         // Auto Importer is on by default
  81         turnOn
  82 )
  83