vvp/configure.in

   1 AC_INIT(Makefile.in)
   2 AC_CONFIG_HEADER(config.h)
   3
   4 AC_PROG_CC
   5 AC_PROG_CXX
   6 AC_PROG_RANLIB
   7 AC_CHECK_TOOL(STRIP, strip, true)
   8
   9 AC_EXEEXT
  10 AC_SUBST(EXEEXT)
  11
  12 # Combined check for Microsoft-related bogosities; sets WIN32 if found
  13 AX_WIN32
  14
  15 # vvp32 is by default disabled
  16 #enable_vvp32=no
  17 AC_SUBST(enable_vvp32)
  18
  19 AC_CHECK_PROGS(LEX,flex,none)
  20 if test "$LEX" = "none"
  21 then
  22         echo "*** Error: No suitable flex found. ***"
  23         echo "    Please install the 'flex' package."
  24         exit 1
  25 fi
  26
  27 AC_CHECK_PROGS(YACC,bison,none)
  28 if test "$YACC" = "none"
  29 then
  30         echo "*** Error: No suitable bison found. ***"
  31         echo "    Please install the 'bison' package."
  32         exit 1
  33 fi
  34
  35 AC_PROG_INSTALL
  36
  37 AC_LANG_CPLUSPLUS
  38 AC_CHECK_HEADERS(getopt.h malloc.h inttypes.h iosfwd)
  39
  40 AC_CHECK_SIZEOF(unsigned long long)
  41 AC_CHECK_SIZEOF(unsigned long)
  42 AC_CHECK_SIZEOF(unsigned)
  43
  44 # For the interactive debugger to work, readline must be installed,
  45 # and that in turn requires termcap. check that the libs really do
  46 # exist.
  47 AC_CHECK_LIB(termcap, tputs)
  48 AC_CHECK_LIB(readline, readline)
  49 AC_CHECK_LIB(history, add_history)
  50 AC_CHECK_HEADERS(readline/readline.h readline/history.h)
  51
  52 # --
  53 # Look for a dl library to use. First look for the standard dlopen
  54 # functions, and failing that look for the HP specific shl_load function.
  55
  56 AC_CHECK_HEADERS(dlfcn.h dl.h, break)
  57
  58 DLLIB=''
  59 AC_CHECK_LIB(dl,dlopen,[DLLIB=-ldl])
  60 if test -z "$DLLIB" ; then
  61 AC_CHECK_LIB(dld,shl_load,[DLLIB=-ldld])
  62 fi
  63 AC_SUBST(DLLIB)
  64
  65 # may modify CPPFLAGS and CFLAGS
  66 AX_CPP_PRECOMP
  67
  68 # Processor specific compile flags
  69 case "${host}" in
  70     alpha*-*-linux*)
  71         CPPFLAGS="-mieee $CPPFLAGS"
  72         CFLAGS="-mieee $CFLAGS"
  73         ;;
  74 esac
  75
  76 # Check that these functions exist. They are mostly C99
  77 # functions that older compilers may not yet support.
  78 AC_CHECK_FUNCS(lround nan)
  79
  80 # see how we can give some resource usage stats with -v
  81 # Linux does not provide mem stats in rusage, use /proc/self/statm.
  82
  83 AC_CHECK_HEADERS(sys/resource.h)
  84 case "${host}" in *linux*) AC_DEFINE([LINUX], [1], [Host operating system is Linux.]) ;; esac
  85
  86 # Linker option used when compiling the target
  87 AX_LD_RDYNAMIC
  88
  89 AX_LD_EXTRALIBS
  90
  91 #######################
  92 ## test for underscores. The vpi module loader in vvm needs to know this
  93 ## in order to know the name of the start symbol for the .vpi module.
  94 #######################
  95
  96 AX_C_UNDERSCORES_LEADING
  97 AX_C_UNDERSCORES_TRAILING
  98
  99 #######################
 100 ## end of test for underscores
 101 #######################
 102
 103 AX_CPP_IDENT
 104
 105 # If not otherwise specified, set the libdir64 variable
 106 # to the same as libdir.
 107 AC_MSG_CHECKING(for libdir64 path)
 108 if test x${libdir64} = x
 109 then
 110         libdir64="${libdir}"
 111 fi
 112 AC_SUBST(libdir64)
 113 AC_MSG_RESULT(${libdir64})
 114
 115 # where to put vpi subdirectories
 116 AC_MSG_CHECKING(for VPI subdirectories)
 117 if test x${vpidir1} = x
 118 then
 119         vpidir1="."
 120 fi
 121
 122 AC_SUBST(vpidir1)
 123 AC_SUBST(vpidir2)
 124 AC_MSG_RESULT(${vpidir1} ${vpidir2})
 125
 126 AC_OUTPUT(Makefile)