acinclude.m4

   1 # Configure paths for SDL
   2 # Sam Lantinga 9/21/99
   3 # stolen from Manish Singh
   4 # stolen back from Frank Belew
   5 # stolen from Manish Singh
   6 # Shamelessly stolen from Owen Taylor
   7 # /home/jonathan/DEV/sdl/test/acinclude.m4
   8 #
   9 dnl AM_PATH_SDL([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
  10 dnl Test for SDL, and define SDL_CFLAGS and SDL_LIBS
  11 dnl
  12 AC_DEFUN([AM_PATH_SDL],
  13 [dnl
  14 dnl Get the cflags and libraries from the sdl-config script
  15 dnl
  16 AC_ARG_WITH(sdl-prefix,[  --with-sdl-prefix=PFX   Prefix where SDL is installed (optional)],
  17             sdl_prefix="$withval", sdl_prefix="")
  18 AC_ARG_WITH(sdl-exec-prefix,[  --with-sdl-exec-prefix=PFX Exec prefix where SDL is installed (optional)],
  19             sdl_exec_prefix="$withval", sdl_exec_prefix="")
  20 AC_ARG_ENABLE(sdltest, [  --disable-sdltest       Do not try to compile and run a test SDL program],
  21                     , enable_sdltest=yes)
  22
  23   if test x$sdl_exec_prefix != x ; then
  24      sdl_args="$sdl_args --exec-prefix=$sdl_exec_prefix"
  25      if test x${SDL_CONFIG+set} != xset ; then
  26         SDL_CONFIG=$sdl_exec_prefix/bin/sdl-config
  27      fi
  28   fi
  29   if test x$sdl_prefix != x ; then
  30      sdl_args="$sdl_args --prefix=$sdl_prefix"
  31      if test x${SDL_CONFIG+set} != xset ; then
  32         SDL_CONFIG=$sdl_prefix/bin/sdl-config
  33      fi
  34   fi
  35
  36   AC_PATH_PROG(SDL_CONFIG, sdl-config, no)
  37   min_sdl_version=ifelse([$1], ,0.11.0,$1)
  38   AC_MSG_CHECKING(for SDL - version >= $min_sdl_version)
  39   no_sdl=""
  40   if test "$SDL_CONFIG" = "no" ; then
  41     no_sdl=yes
  42   else
  43     SDL_CFLAGS=`$SDL_CONFIG $sdlconf_args --cflags`
  44     SDL_LIBS=`$SDL_CONFIG $sdlconf_args --libs`
  45
  46     sdl_major_version=`$SDL_CONFIG $sdl_args --version | \
  47            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
  48     sdl_minor_version=`$SDL_CONFIG $sdl_args --version | \
  49            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
  50     sdl_micro_version=`$SDL_CONFIG $sdl_config_args --version | \
  51            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
  52     if test "x$enable_sdltest" = "xyes" ; then
  53       ac_save_CFLAGS="$CFLAGS"
  54       ac_save_LIBS="$LIBS"
  55       CFLAGS="$CFLAGS $SDL_CFLAGS"
  56       LIBS="$LIBS $SDL_LIBS"
  57 dnl
  58 dnl Now check if the installed SDL is sufficiently new. (Also sanity
  59 dnl checks the results of sdl-config to some extent
  60 dnl
  61       rm -f conf.sdltest
  62       AC_TRY_RUN([
  63 #include <stdio.h>
  64 #include <stdlib.h>
  65 #include <string.h>
  66 #include "SDL.h"
  67
  68 char*
  69 my_strdup (char *str)
  70 {
  71   char *new_str;
  72
  73   if (str)
  74     {
  75       new_str = (char *)malloc ((strlen (str) + 1) * sizeof(char));
  76       strcpy (new_str, str);
  77     }
  78   else
  79     new_str = NULL;
  80
  81   return new_str;
  82 }
  83
  84 int main (int argc, char *argv[])
  85 {
  86   int major, minor, micro;
  87   char *tmp_version;
  88
  89   /* This hangs on some systems (?)
  90   system ("touch conf.sdltest");
  91   */
  92   { FILE *fp = fopen("conf.sdltest", "a"); if ( fp ) fclose(fp); }
  93
  94   /* HP/UX 9 (%@#!) writes to sscanf strings */
  95   tmp_version = my_strdup("$min_sdl_version");
  96   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
  97      printf("%s, bad version string\n", "$min_sdl_version");
  98      exit(1);
  99    }
 100
 101    if (($sdl_major_version > major) ||
 102       (($sdl_major_version == major) && ($sdl_minor_version > minor)) ||
 103       (($sdl_major_version == major) && ($sdl_minor_version == minor) && ($sdl_micro_version >= micro)))
 104     {
 105       return 0;
 106     }
 107   else
 108     {
 109       printf("\n*** 'sdl-config --version' returned %d.%d.%d, but the minimum version\n", $sdl_major_version, $sdl_minor_version, $sdl_micro_version);
 110       printf("*** of SDL required is %d.%d.%d. If sdl-config is correct, then it is\n", major, minor, micro);
 111       printf("*** best to upgrade to the required version.\n");
 112       printf("*** If sdl-config was wrong, set the environment variable SDL_CONFIG\n");
 113       printf("*** to point to the correct copy of sdl-config, and remove the file\n");
 114       printf("*** config.cache before re-running configure\n");
 115       return 1;
 116     }
 117 }
 118
 119 ],, no_sdl=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 120        CFLAGS="$ac_save_CFLAGS"
 121        LIBS="$ac_save_LIBS"
 122      fi
 123   fi
 124   if test "x$no_sdl" = x ; then
 125      AC_MSG_RESULT(yes)
 126      ifelse([$2], , :, [$2])
 127   else
 128      AC_MSG_RESULT(no)
 129      if test "$SDL_CONFIG" = "no" ; then
 130        echo "*** The sdl-config script installed by SDL could not be found"
 131        echo "*** If SDL was installed in PREFIX, make sure PREFIX/bin is in"
 132        echo "*** your path, or set the SDL_CONFIG environment variable to the"
 133        echo "*** full path to sdl-config."
 134      else
 135        if test -f conf.sdltest ; then
 136         :
 137        else
 138           echo "*** Could not run SDL test program, checking why..."
 139           CFLAGS="$CFLAGS $SDL_CFLAGS"
 140           LIBS="$LIBS $SDL_LIBS"
 141           AC_TRY_LINK([
 142 #include <stdio.h>
 143 #include "SDL.h"
 144
 145 int main(int argc, char *argv[])
 146 { return 0; }
 147 #undef  main
 148 #define main K_and_R_C_main
 149 ],      [ return 0; ],
 150         [ echo "*** The test program compiled, but did not run. This usually means"
 151           echo "*** that the run-time linker is not finding SDL or finding the wrong"
 152           echo "*** version of SDL. If it is not finding SDL, you'll need to set your"
 153           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 154           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 155           echo "*** is required on your system"
 156           echo "***"
 157           echo "*** If you have an old version installed, it is best to remove it, although"
 158           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
 159         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 160           echo "*** exact error that occured. This usually means SDL was incorrectly installed"
 161           echo "*** or that you have moved SDL since it was installed. In the latter case, you"
 162           echo "*** may want to edit the sdl-config script: $SDL_CONFIG" ])
 163           CFLAGS="$ac_save_CFLAGS"
 164           LIBS="$ac_save_LIBS"
 165        fi
 166      fi
 167      SDL_CFLAGS=""
 168      SDL_LIBS=""
 169      ifelse([$3], , :, [$3])
 170   fi
 171   AC_SUBST(SDL_CFLAGS)
 172   AC_SUBST(SDL_LIBS)
 173   rm -f conf.sdltest
 174 ])