board/RPXlite_dw/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2004
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     /* WARNING - the following is hand-optimized to fit within  */
  57     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  58
  59     cpu/mpc8xx/start.o  (.text)
  60     common/dlmalloc.o   (.text)
  61     lib_ppc/ppcstring.o (.text)
  62     lib_generic/vsprintf.o      (.text)
  63     lib_generic/crc32.o         (.text)
  64     lib_generic/zlib.o          (.text)
  65 /* XXX ?
  66     . = env_offset;
  67 */
  68     common/environment.o(.text)
  69
  70     *(.text)
  71     *(.fixup)
  72     *(.got1)
  73   }
  74   _etext = .;
  75   PROVIDE (etext = .);
  76   .rodata    :
  77   {
  78     *(.rodata)
  79     *(.rodata1)
  80     *(.rodata.str1.4)
  81     *(.eh_frame)
  82   }
  83   .fini      : { *(.fini)    } =0
  84   .ctors     : { *(.ctors)   }
  85   .dtors     : { *(.dtors)   }
  86
  87   /* Read-write section, merged into data segment: */
  88   . = (. + 0x00FF) & 0xFFFFFF00;
  89   _erotext = .;
  90   PROVIDE (erotext = .);
  91   .reloc   :
  92   {
  93     *(.got)
  94     _GOT2_TABLE_ = .;
  95     *(.got2)
  96     _FIXUP_TABLE_ = .;
  97     *(.fixup)
  98   }
  99   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
 100   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 101
 102   .data    :
 103   {
 104     *(.data)
 105     *(.data1)
 106     *(.sdata)
 107     *(.sdata2)
 108     *(.dynamic)
 109     CONSTRUCTORS
 110   }
 111   _edata  =  .;
 112   PROVIDE (edata = .);
 113
 114   . = .;
 115   __u_boot_cmd_start = .;
 116   .u_boot_cmd : { *(.u_boot_cmd) }
 117   __u_boot_cmd_end = .;
 118
 119
 120   . = .;
 121   __start___ex_table = .;
 122   __ex_table : { *(__ex_table) }
 123   __stop___ex_table = .;
 124
 125   . = ALIGN(256);
 126   __init_begin = .;
 127   .text.init : { *(.text.init) }
 128   .data.init : { *(.data.init) }
 129   . = ALIGN(256);
 130   __init_end = .;
 131
 132   __bss_start = .;
 133   .bss       :
 134   {
 135    *(.sbss) *(.scommon)
 136    *(.dynbss)
 137    *(.bss)
 138    *(COMMON)
 139   }
 140   _end = . ;
 141   PROVIDE (end = .);
 142 }