board/cu824/u-boot.lds

   1 /*
   2  * (C) Copyright 2001
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     cpu/mpc824x/start.o (.text)
  57     lib_ppc/board.o (.text)
  58     lib_ppc/ppcstring.o (.text)
  59     lib_generic/vsprintf.o      (.text)
  60     lib_generic/crc32.o         (.text)
  61     lib_generic/zlib.o          (.text)
  62
  63                 . = DEFINED(env_offset) ? env_offset : .;
  64     common/environment.o (.text)
  65
  66                 *(.text)
  67
  68     *(.fixup)
  69     *(.got1)
  70     . = ALIGN(16);
  71     *(.rodata)
  72     *(.rodata1)
  73     *(.rodata.str1.4)
  74     *(.eh_frame)
  75   }
  76   .fini      : { *(.fini)    } =0
  77   .ctors     : { *(.ctors)   }
  78   .dtors     : { *(.dtors)   }
  79
  80   /* Read-write section, merged into data segment: */
  81   . = (. + 0x0FFF) & 0xFFFFF000;
  82   _erotext = .;
  83   PROVIDE (erotext = .);
  84   .reloc   :
  85   {
  86     *(.got)
  87     _GOT2_TABLE_ = .;
  88     *(.got2)
  89     _FIXUP_TABLE_ = .;
  90     *(.fixup)
  91   }
  92   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  93   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  94
  95   .data    :
  96   {
  97     *(.data)
  98     *(.data1)
  99     *(.sdata)
 100     *(.sdata2)
 101     *(.dynamic)
 102     CONSTRUCTORS
 103   }
 104   _edata  =  .;
 105   PROVIDE (edata = .);
 106
 107   . = .;
 108   __u_boot_cmd_start = .;
 109   .u_boot_cmd : { *(.u_boot_cmd) }
 110   __u_boot_cmd_end = .;
 111
 112
 113   . = .;
 114   __start___ex_table = .;
 115   __ex_table : { *(__ex_table) }
 116   __stop___ex_table = .;
 117
 118   . = ALIGN(4096);
 119   __init_begin = .;
 120   .text.init : { *(.text.init) }
 121   .data.init : { *(.data.init) }
 122   . = ALIGN(4096);
 123   __init_end = .;
 124
 125   __bss_start = .;
 126   .bss       :
 127   {
 128    *(.sbss) *(.scommon)
 129    *(.dynbss)
 130    *(.bss)
 131    *(COMMON)
 132   }
 133
 134   _end = . ;
 135   PROVIDE (end = .);
 136 }