board/m5282evb/u-boot.lds

   1 /*
   2  * (C) Copyright 2000-2003
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(m68k)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     /* WARNING - the following is hand-optimized to fit within  */
  57     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  58
  59     cpu/mcf52x2/start.o (.text)
  60     common/dlmalloc.o   (.text)
  61     lib_generic/string.o        (.text)
  62     lib_generic/vsprintf.o      (.text)
  63     lib_generic/crc32.o (.text)
  64     lib_generic/zlib.o  (.text)
  65
  66 /*    . = env_offset; */
  67     common/environment.o(.text)
  68
  69     *(.text)
  70     *(.fixup)
  71     *(.got1)
  72   }
  73   _etext = .;
  74   PROVIDE (etext = .);
  75   .rodata    :
  76   {
  77     *(.rodata)
  78     *(.rodata1)
  79   }
  80   .fini      : { *(.fini)    } =0
  81   .ctors     : { *(.ctors)   }
  82   .dtors     : { *(.dtors)   }
  83
  84   /* Read-write section, merged into data segment: */
  85   . = (. + 0x00FF) & 0xFFFFFF00;
  86   _erotext = .;
  87   PROVIDE (erotext = .);
  88     .reloc   :
  89   {
  90     __got_start = .;
  91     *(.got)
  92     __got_end = .;
  93     _GOT2_TABLE_ = .;
  94     *(.got2)
  95     _FIXUP_TABLE_ = .;
  96     *(.fixup)
  97   }
  98   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  99   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
 100
 101   .data    :
 102   {
 103     *(.data)
 104     *(.data1)
 105     *(.sdata)
 106     *(.sdata2)
 107     *(.dynamic)
 108     CONSTRUCTORS
 109   }
 110   _edata  =  .;
 111   PROVIDE (edata = .);
 112
 113   . = .;
 114   __u_boot_cmd_start = .;
 115   .u_boot_cmd : { *(.u_boot_cmd) }
 116   __u_boot_cmd_end = .;
 117
 118   . = .;
 119   __start___ex_table = .;
 120   __ex_table : { *(__ex_table) }
 121   __stop___ex_table = .;
 122
 123   . = ALIGN(256);
 124   __init_begin = .;
 125   .text.init : { *(.text.init) }
 126   .data.init : { *(.data.init) }
 127   . = ALIGN(256);
 128   __init_end = .;
 129
 130   __bss_start = .;
 131   .bss       :
 132   {
 133    _sbss = .;
 134    *(.sbss) *(.scommon)
 135    *(.dynbss)
 136    *(.bss)
 137    *(COMMON)
 138    . = ALIGN(4);
 139    _ebss = .;
 140   }
 141   _end = . ;
 142   PROVIDE (end = .);
 143 }