board/netta/u-boot.lds.debug

   1 /*
   2  * (C) Copyright 2000-2004
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     /* WARNING - the following is hand-optimized to fit within  */
  57     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  58
  59     cpu/mpc8xx/start.o          (.text)
  60     common/dlmalloc.o           (.text)
  61     lib_generic/vsprintf.o      (.text)
  62     lib_generic/crc32.o         (.text)
  63
  64     . = env_offset;
  65     common/environment.o(.text)
  66
  67     *(.text)
  68     *(.fixup)
  69     *(.got1)
  70   }
  71   _etext = .;
  72   PROVIDE (etext = .);
  73   .rodata    :
  74   {
  75     *(.rodata)
  76     *(.rodata1)
  77     *(.rodata.str1.4)
  78     *(.eh_frame)
  79   }
  80   .fini      : { *(.fini)    } =0
  81   .ctors     : { *(.ctors)   }
  82   .dtors     : { *(.dtors)   }
  83
  84   /* Read-write section, merged into data segment: */
  85   . = (. + 0x0FFF) & 0xFFFFF000;
  86   _erotext = .;
  87   PROVIDE (erotext = .);
  88   .reloc   :
  89   {
  90     *(.got)
  91     _GOT2_TABLE_ = .;
  92     *(.got2)
  93     _FIXUP_TABLE_ = .;
  94     *(.fixup)
  95   }
  96   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  97   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  98
  99   .data    :
 100   {
 101     *(.data)
 102     *(.data1)
 103     *(.sdata)
 104     *(.sdata2)
 105     *(.dynamic)
 106     CONSTRUCTORS
 107   }
 108   _edata  =  .;
 109   PROVIDE (edata = .);
 110
 111   __u_boot_cmd_start = .;
 112   .u_boot_cmd : { *(.u_boot_cmd) }
 113   __u_boot_cmd_end = .;
 114
 115
 116   __start___ex_table = .;
 117   __ex_table : { *(__ex_table) }
 118   __stop___ex_table = .;
 119
 120   . = ALIGN(4096);
 121   __init_begin = .;
 122   .text.init : { *(.text.init) }
 123   .data.init : { *(.data.init) }
 124   . = ALIGN(4096);
 125   __init_end = .;
 126
 127   __bss_start = .;
 128   .bss       :
 129   {
 130    *(.sbss) *(.scommon)
 131    *(.dynbss)
 132    *(.bss)
 133    *(COMMON)
 134   }
 135   _end = . ;
 136   PROVIDE (end = .);
 137 }