board/o2dnt/u-boot.lds

   1 /*
   2  * (C) Copyright 2005
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * See file CREDITS for list of people who contributed to this
   6  * project.
   7  *
   8  * This program is free software; you can redistribute it and/or
   9  * modify it under the terms of the GNU General Public License as
  10  * published by the Free Software Foundation; either version 2 of
  11  * the License, or (at your option) any later version.
  12  *
  13  * This program is distributed in the hope that it will be useful,
  14  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  15  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16  * GNU General Public License for more details.
  17  *
  18  * You should have received a copy of the GNU General Public License
  19  * along with this program; if not, write to the Free Software
  20  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  21  * MA 02111-1307 USA
  22  */
  23
  24 OUTPUT_ARCH(powerpc)
  25 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  26 /* Do we need any of these for elf?
  27    __DYNAMIC = 0;    */
  28 SECTIONS
  29 {
  30   /* Read-only sections, merged into text segment: */
  31   . = + SIZEOF_HEADERS;
  32   .interp : { *(.interp) }
  33   .hash          : { *(.hash)           }
  34   .dynsym        : { *(.dynsym)         }
  35   .dynstr        : { *(.dynstr)         }
  36   .rel.text      : { *(.rel.text)               }
  37   .rela.text     : { *(.rela.text)      }
  38   .rel.data      : { *(.rel.data)               }
  39   .rela.data     : { *(.rela.data)      }
  40   .rel.rodata    : { *(.rel.rodata)     }
  41   .rela.rodata   : { *(.rela.rodata)    }
  42   .rel.got       : { *(.rel.got)                }
  43   .rela.got      : { *(.rela.got)               }
  44   .rel.ctors     : { *(.rel.ctors)      }
  45   .rela.ctors    : { *(.rela.ctors)     }
  46   .rel.dtors     : { *(.rel.dtors)      }
  47   .rela.dtors    : { *(.rela.dtors)     }
  48   .rel.bss       : { *(.rel.bss)                }
  49   .rela.bss      : { *(.rela.bss)               }
  50   .rel.plt       : { *(.rel.plt)                }
  51   .rela.plt      : { *(.rela.plt)               }
  52   .init          : { *(.init)   }
  53   .plt : { *(.plt) }
  54   .text      :
  55   {
  56     cpu/mpc5xxx/start.o (.text)
  57     *(.text)
  58     *(.fixup)
  59     *(.got1)
  60     . = ALIGN(16);
  61     *(.rodata)
  62     *(.rodata1)
  63     *(.rodata.str1.4)
  64     *(.eh_frame)
  65   }
  66   .fini      : { *(.fini)    } =0
  67   .ctors     : { *(.ctors)   }
  68   .dtors     : { *(.dtors)   }
  69
  70   /* Read-write section, merged into data segment: */
  71   . = (. + 0x0FFF) & 0xFFFFF000;
  72   _erotext = .;
  73   PROVIDE (erotext = .);
  74   .reloc   :
  75   {
  76     *(.got)
  77     _GOT2_TABLE_ = .;
  78     *(.got2)
  79     _FIXUP_TABLE_ = .;
  80     *(.fixup)
  81   }
  82   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
  83   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
  84
  85   .data    :
  86   {
  87     *(.data)
  88     *(.data1)
  89     *(.sdata)
  90     *(.sdata2)
  91     *(.dynamic)
  92     CONSTRUCTORS
  93   }
  94   _edata  =  .;
  95   PROVIDE (edata = .);
  96
  97   . = .;
  98   __u_boot_cmd_start = .;
  99   .u_boot_cmd : { *(.u_boot_cmd) }
 100   __u_boot_cmd_end = .;
 101
 102
 103   . = .;
 104   __start___ex_table = .;
 105   __ex_table : { *(__ex_table) }
 106   __stop___ex_table = .;
 107
 108   . = ALIGN(4096);
 109   __init_begin = .;
 110   .text.init : { *(.text.init) }
 111   .data.init : { *(.data.init) }
 112   . = ALIGN(4096);
 113   __init_end = .;
 114
 115   __bss_start = .;
 116   .bss       :
 117   {
 118    *(.sbss) *(.scommon)
 119    *(.dynbss)
 120    *(.bss)
 121    *(COMMON)
 122   }
 123   _end = . ;
 124   PROVIDE (end = .);
 125 }