board/stxgp3/u-boot.lds

   1 /*
   2  * (C) Copyright 2003 Embedded Edge, LLC
   3  * Dan Malek, <dan@embeddededge.com>
   4  * Copied from ADS85xx.
   5  * Updates for Silicon Tx GP3 8560.
   6  *
   7  * (C) Copyright 2002,2003,Motorola,Inc.
   8  * Xianghua Xiao, X.Xiao@motorola.com.
   9  *
  10  * See file CREDITS for list of people who contributed to this
  11  * project.
  12  *
  13  * This program is free software; you can redistribute it and/or
  14  * modify it under the terms of the GNU General Public License as
  15  * published by the Free Software Foundation; either version 2 of
  16  * the License, or (at your option) any later version.
  17  *
  18  * This program is distributed in the hope that it will be useful,
  19  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  20  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21  * GNU General Public License for more details.
  22  *
  23  * You should have received a copy of the GNU General Public License
  24  * along with this program; if not, write to the Free Software
  25  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  26  * MA 02111-1307 USA
  27  */
  28
  29 OUTPUT_ARCH(powerpc)
  30 SEARCH_DIR(/lib); SEARCH_DIR(/usr/lib); SEARCH_DIR(/usr/local/lib); SEARCH_DIR(/usr/local/powerpc-any-elf/lib);
  31 /* Do we need any of these for elf?
  32    __DYNAMIC = 0;    */
  33 SECTIONS
  34 {
  35   .resetvec 0xFFFFFFFC :
  36   {
  37     *(.resetvec)
  38   } = 0xffff
  39
  40   .bootpg 0xFFFFF000 :
  41   {
  42     cpu/mpc85xx/start.o (.bootpg)
  43     board/stxgp3/init.o (.bootpg)
  44   } = 0xffff
  45
  46   /* Read-only sections, merged into text segment: */
  47   . = + SIZEOF_HEADERS;
  48   .interp : { *(.interp) }
  49   .hash          : { *(.hash)           }
  50   .dynsym        : { *(.dynsym)         }
  51   .dynstr        : { *(.dynstr)         }
  52   .rel.text      : { *(.rel.text)               }
  53   .rela.text     : { *(.rela.text)      }
  54   .rel.data      : { *(.rel.data)               }
  55   .rela.data     : { *(.rela.data)      }
  56   .rel.rodata    : { *(.rel.rodata)     }
  57   .rela.rodata   : { *(.rela.rodata)    }
  58   .rel.got       : { *(.rel.got)                }
  59   .rela.got      : { *(.rela.got)               }
  60   .rel.ctors     : { *(.rel.ctors)      }
  61   .rela.ctors    : { *(.rela.ctors)     }
  62   .rel.dtors     : { *(.rel.dtors)      }
  63   .rela.dtors    : { *(.rela.dtors)     }
  64   .rel.bss       : { *(.rel.bss)                }
  65   .rela.bss      : { *(.rela.bss)               }
  66   .rel.plt       : { *(.rel.plt)                }
  67   .rela.plt      : { *(.rela.plt)               }
  68   .init          : { *(.init)   }
  69   .plt : { *(.plt) }
  70   .text      :
  71   {
  72     cpu/mpc85xx/start.o (.text)
  73     board/stxgp3/init.o (.text)
  74     cpu/mpc85xx/commproc.o (.text)
  75     cpu/mpc85xx/traps.o (.text)
  76     cpu/mpc85xx/interrupts.o (.text)
  77     cpu/mpc85xx/serial_scc.o (.text)
  78     cpu/mpc85xx/ether_fcc.o (.text)
  79     cpu/mpc85xx/cpu_init.o (.text)
  80     cpu/mpc85xx/cpu.o (.text)
  81     cpu/mpc85xx/speed.o (.text)
  82     cpu/mpc85xx/spd_sdram.o (.text)
  83     common/dlmalloc.o (.text)
  84     lib_generic/crc32.o (.text)
  85     lib_ppc/extable.o (.text)
  86     lib_generic/zlib.o (.text)
  87     *(.text)
  88     *(.fixup)
  89     *(.got1)
  90    }
  91     _etext = .;
  92     PROVIDE (etext = .);
  93     .rodata    :
  94    {
  95     *(.rodata)
  96     *(.rodata1)
  97     *(.rodata.str1.4)
  98     *(.eh_frame)
  99   }
 100   .fini      : { *(.fini)    } =0
 101   .ctors     : { *(.ctors)   }
 102   .dtors     : { *(.dtors)   }
 103
 104   /* Read-write section, merged into data segment: */
 105   . = (. + 0x00FF) & 0xFFFFFF00;
 106   _erotext = .;
 107   PROVIDE (erotext = .);
 108   .reloc   :
 109   {
 110     *(.got)
 111     _GOT2_TABLE_ = .;
 112     *(.got2)
 113     _FIXUP_TABLE_ = .;
 114     *(.fixup)
 115   }
 116   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >> 2;
 117   __fixup_entries = (. - _FIXUP_TABLE_) >> 2;
 118
 119   .data    :
 120   {
 121     *(.data)
 122     *(.data1)
 123     *(.sdata)
 124     *(.sdata2)
 125     *(.dynamic)
 126     CONSTRUCTORS
 127   }
 128   _edata  =  .;
 129   PROVIDE (edata = .);
 130
 131   . = .;
 132   __u_boot_cmd_start = .;
 133   .u_boot_cmd : { *(.u_boot_cmd) }
 134   __u_boot_cmd_end = .;
 135
 136   . = .;
 137   __start___ex_table = .;
 138   __ex_table : { *(__ex_table) }
 139   __stop___ex_table = .;
 140
 141   . = ALIGN(256);
 142   __init_begin = .;
 143   .text.init : { *(.text.init) }
 144   .data.init : { *(.data.init) }
 145   . = ALIGN(256);
 146   __init_end = .;
 147
 148   __bss_start = .;
 149   .bss       :
 150   {
 151    *(.sbss) *(.scommon)
 152    *(.dynbss)
 153    *(.bss)
 154    *(COMMON)
 155   }
 156   _end = . ;
 157   PROVIDE (end = .);
 158 }