added visible note about loser GPU

[k8vacspelynky.git] / mapent / characters / shopkeeper.vc

/**********************************************************************************
 * Copyright (c) 2008, 2009 Derek Yu and Mossmouth, LLC
 * Copyright (c) 2010, Moloch
 * Copyright (c) 2018, Ketmar Dark
 *
 * This file is part of Spelunky.
 *
 * You can redistribute and/or modify Spelunky, including its source code, under
 * the terms of the Spelunky User License.
 *
 * Spelunky is distributed in the hope that it will be entertaining and useful,
 * but WITHOUT WARRANTY.  Please see the Spelunky User License for more details.
 *
 * The Spelunky User License should be available in "Game Information", which
 * can be found in the Resource Explorer, or as an external file called COPYING.
 * If not, please obtain a new copy of Spelunky from <http://spelunkyworld.com/>
 *
 **********************************************************************************/
// he is an enemy in the original, but... meh
class MonsterShopkeeper['oShopkeeper'] : MapEnemy;

name style;
string shopkeeperName;

array!string namelist;

int throwCount;
int turnTimer;
int stunMax;

int cash;
int betValue;
int kissValue;

int firing;
int firingMax;

bool welcomed;
bool angered;
bool outlaw;
bool broke; // bank
bool hasGun;
bool hisGunIsAsh;
bool tryToJumpOut; // if a player is trying to corner a shopkeeper, try to run and jump

/*
IDLE = 0;
WALK = 1;
ATTACK = 2;
THROWN = 3;
PATROL = 4;
FOLLOW = 5;
STUNNED = 98;
DEAD = 99;
*/


name prizes[9];


final name chooseName (
  optional name n0,
  optional name n1,
  optional name n2,
  optional name n3,
  optional name n4,
  optional name n5,
  optional name n6,
  optional name n7)
{
  int count = 0;
  if (specified_n0) ++count;
  if (specified_n1) ++count;
  if (specified_n2) ++count;
  if (specified_n3) ++count;
  if (specified_n4) ++count;
  if (specified_n5) ++count;
  if (specified_n6) ++count;
  if (specified_n7) ++count;
  if (!count) return '';

  for (;;) {
    auto idx = global.randOther(0, count);
    if (specified_n0) { if (idx-- == 0) return n0; }
    if (specified_n1) { if (idx-- == 0) return n1; }
    if (specified_n2) { if (idx-- == 0) return n2; }
    if (specified_n3) { if (idx-- == 0) return n3; }
    if (specified_n4) { if (idx-- == 0) return n4; }
    if (specified_n5) { if (idx-- == 0) return n5; }
    if (specified_n6) { if (idx-- == 0) return n6; }
    if (specified_n7) { if (idx-- == 0) return n7; }
  }
}


// select a single item for sequence of dice house prizes during level generation
name scrGeneratePrize () {
  if (global.randRoom(1, 40) == 1) return 'oJetpack';
  if (global.randRoom(1, 25) == 1) return 'oCapePickup';
  if (global.randRoom(1, 20) == 1) return 'oShotgun';
  if (global.randRoom(1, 10) == 1) return 'oGloves';
  if (global.randRoom(1, 10) == 1) return 'oTeleporter';
  if (global.randRoom(1, 8) == 1) return 'oMattock';
  if (global.randRoom(1, 8) == 1) return 'oPaste';
  if (global.randRoom(1, 8) == 1) return 'oSpringShoes';
  if (global.randRoom(1, 8) == 1) return 'oSpikeShoes';
  if (global.randRoom(1, 8) == 1) return 'oCompass';
  if (global.randRoom(1, 8) == 1) return 'oPistol';
  if (global.randRoom(1, 8) == 1) return 'oMachete';
  return 'oBombBox';
}


void generatePrizes () {
  foreach (ref name pname; prizes) pname = '';
  // select sequence of next 9 prizes
  foreach (auto idx, ref name pname; prizes) {
    // don't generate dupliate prizes
    for (;;) {
      name prz = scrGeneratePrize();
      bool found = false;
      foreach (int cidx; 0..idx) if (prizes[cidx] == prz) { found = true; break; }
      if (!found) {
        pname = prz;
        break;
      }
    }
  }
}


bool hasAnyPrize () {
  foreach (name pname; prizes) if (pname) return true;
  return !!level.findCrapsPrize();
}


string genName () {
  return namelist[global.randOther(0, namelist.length-1)];
}


override bool initialize () {
  if (!::initialize()) return false;
  setSprite('sShopLeft');
  auto spf = getSpriteFrame();
  setCollisionBounds(2, 0, spf.width-2, spf.height);
  cash = 5000*(global.levelType+1)+global.randRoom(0, global.currLevel*2000);
  betValue = 1000+global.currLevel*500;
  kissValue = 10000+5000*(global.currLevel-2);
  //initFixDirection();
  shopkeeperName = genName();
  if (level.levelKind == GameLevel::LevelKind.Stars) {
    status = ATTACK;
    hasGun = false;
    deathTimer = 200;
    stunMax = 60;
  } else {
    writeln("*** generated Shopkeeper at tile (", ix/16, ",", iy/16, ")");
  }
  return true;
}


override void onAnimationLooped () {
  if (spriteLName == 'sShopThrowL') {
    status = ATTACK;
    setSprite('sShopLeft');
  }
}


override bool onExplosionTouch (MapObject xplo) {
  if (invincible) return false;
  writeln("shopkeeper touched by an explosion");

  if (xplo.fltx < fltx) xVel = global.randOther(4, 6); else xVel = -global.randOther(4, 6);
  yVel = -6;
  burning = 50;
  hp -= global.config.explosionDmg;
  spillBlood();
  //if (hp <= 0 && !leavesBody) instanceRemove();

  //FIXME: move anger code to separate method and call it here

  return true;
}


override bool onTouchedByPlayer (PlayerPawn plr) {
  if (dead || status == DEAD) return false;
  if (!angered) return false;
  return ::onTouchedByPlayer(plr);
}


// return `false` to do standard weapon processing
override bool onTouchedByPlayerWeapon (PlayerPawn plr, PlayerWeapon wpn) {
  if (heldBy) return true;
  if (hp > 0 && !dead && !stunned && status < STUNNED) wpn.hitEnemy = true;
  if (wpn.slashing) {
    wpn.hitEnemy = true;
    hp -= wpn.damage;
    spillBlood();
    status = THROWN;
    counter = stunMax;
  }
  angerIt();
  yVel = -2;
  xVel = (plr.xCenter < xCenter ? 1 : -1);
  plr.playSound('sndHit');
  if (status < STUNNED && !wpn.slashing) status = ATTACK;
  return true;
}


override void onBulletHit (ObjBullet bullet) {
  //if (dead) return;

  writeln("shopkeeper hit by bullet");
  if (heldBy) heldBy.holdItem = none;

  if (hp > 0) {
    countsAsKill = true;
    hp -= bullet.damage;
  }
  spillBlood();

  yVel = -6;
  status = THROWN;
  counter = stunMax;

  xVel = bullet.xVel*0.3;

  //FIXME: move anger code to separate method and call it here
}


// return `false` to prevent
// owner is usually a player
override bool onLostAsHeldItem (MapObject owner, LostCause cause, optional float xvel, optional float yvel) {
  resaleValue = 0;

  if (cause == LostCause.Whoa) {
    xVel = (owner.dir == Dir.Left ? -2 : 2);
    playSound('sndHit');
    return true;
  }

  if (cause == LostCause.Drop) {
    visible = true;
    resaleValue = 0;
  } else if (cause == LostCause.Dead || cause == LostCause.Stunned) {
    visible = true;
    status = THROWN;
    counter = stunMax;
  }

  if (specified_xvel) xVel = xvel;
  if (specified_yvel) yVel = yvel;

  return true;
}


override void onBeforeThrowBy (PlayerPawn plr) {
  if (plr./*kDown*/scrPlayerIsDucking()) {
    status = THROWN;
    flty -= 2;
    counter = stunMax;
  } else {
    // throw - damsel freaks out after stun
    status = THROWN;
    counter = stunMax;
    flty -= 4;
    if (hp > 0) playSound('sndHit');
  }
}


// return `true` if item hits the character
// this is called after item's event
//TODO: he should take away player's shotgun
//TODOK8: he should take and use pistols
override bool onHitByItem (MapItem item) {
  if (item isa ItemWeaponShotgun && hp > 0 && status == ATTACK && !hasGun) {
    hasGun = true;
    hisGunIsAsh = (item isa ItemWeaponAshShotgun);
    item.instanceRemove();
    return true;
  }

  //writeln("char: acc=(", xAcc, ",", yAcc, "); vel=(", xVel, ",", yVel, ")");
  //writeln("item: acc=(", item.xAcc, ",", item.yAcc, "); vel=(", item.xVel, ",", item.yVel, ")");

  // don't hit friendly shopkeeper with items we're putting down
  if (!angered && (status == IDLE || status == FOLLOW) && item.safe) return false;

  if (item isa ItemDice && item.forSale) return false; // don't hit with a die

  // are we invincible?
  if (invincible) return false;
  // any items will fly thru stunned enemies (but not projectiles)
  if (status >= STUNNED && item !isa ItemProjectile) return false;
  if (item isa ItemProjectile && !ItemProjectile(item).canHarm(self)) return false;
  // item does no damage?
  if (!item.damage || item.forSale) return false;
  // speed check
  if (fabs(item.xVel) < ItemSpeedToHitX && fabs(item.yVel) < ItemSpeedToHitY) return false;
  // drop us
  if (heldBy) heldBy.holdItem = none;

  if (status == STUNNED) {
    if (fabs(xVel) < 1) xVel = (item.xVel < 0 ? -1.5 : 1.5);
    yVel = (self isa ItemProjectile ? -1.5 : -1.0);
  } else {
    xVel = item.xVel*0.3;
    yVel = (self isa ItemProjectile ? -6.0 : -2.0);
  }
  hp -= damage;
  if (hp <= 0) {
    auto proj = ItemProjectile(item);
    if (proj) countsAsKill = proj.launchedByPlayer;
  }
  if (!dead) spillBlood(amount:2);
  yVel = -6;
  status = THROWN;
  counter = stunMax;

  item.playSound('sndHit');

  return true; // it hit us
}


// virtual
// return `true` to stop player from holding it
override bool onTryPickup (PlayerPawn plr) {
  //writeln("try to pickup; res=", (dead || status >= STUNNED));
  return !(dead || status >= STUNNED);
}


// virtual
// various side effects
// called only if object was succesfully put into player hands
override void onPickedUp (PlayerPawn plr) {
  writeln("shopkeeper picked up");
}


void fireShotgun () {
  int x = ix, y = iy;
  int xofs, xsgn;
  bool asleft;

  if (dir == Dir.Left) {
    asleft = true;
    xofs = 4;
    xsgn = -1;
    auto blast = level.MakeMapObject(x, y+9, 'oShotgunBlast');
    if (blast) blast.setSprite('sShotgunBlastLeft');
  } else {
    asleft = false;
    xofs = 12;
    xsgn = 1;
    auto blast = level.MakeMapObject(x+16, y+9, 'oShotgunBlast');
    if (blast) blast.setSprite('sShotgunBlastRight');
  }

  if (level.isSolidAtPoint(x+xofs, y+8)) return;

  foreach (; 0..6) {
    auto obj = level.MakeMapObject(x+xofs, y+8, 'oBullet');
    if (!obj) continue;
    obj.xVel = (xsgn*global.randOther(6, 8))+xVel;
    if (asleft) {
      if (obj.xVel >= -6) obj.xVel = -6;
    } else {
      if (obj.xVel < 6) obj.xVel = 6;
    }
    //obj.yVel = random(1)-random(1);
    obj.yVel = global.randOtherFloat()-global.randOtherFloat();
    //obj.safe = true;
  }
}


// return true if this shopkeeper can process the item
// this won't be called for dead or angered shopkeepers
bool canSellItem (PlayerPawn plr, MapObject o) {
  if (!o) {
    // holding nothing: this may be dice bet, or kissing parlor
    return (style == 'Craps' || style == 'Kissing');
  }

  auto die = ItemDice(o);
  if (die) return (die.forSale && style == 'Craps');

  // sell items to shopkeeper?
  if (!o.forSale) {
    auto price = o.cost;
    //if (o.sellingToShopAllowed && price > 0) return true;
    //if (!o.sellingToShopAllowed || price < 1) return false;
    return true;
  }

  return o.forSale;
}


MonsterDamsel findSlaveDamsel () {
  return MonsterDamsel(level.findNearestObject(ix, iy, delegate bool (MapObject o) {
    auto sc = MonsterDamsel(o);
    if (!sc) return false;
    if (sc.dead || !sc.forSale && sc.heldBy) return false;
    return true;
  }, castClass:MonsterDamsel));
}


// return true to "use" item
// this won't be called for dead or angered shopkeepers
bool doSellItem (PlayerPawn plr, MapObject o) {
  if (!o) {
    // holding nothing: this may be dice bet, or kissing parlor
    if (style == 'Craps') {
      doCrapsBet(plr);
      // don't allow player to own the item
      return false;
    }
    // kissing parlor?
    if (style == 'Kissing') {
      if (!isPlayerInOurShop()) return false;
      auto dms = findSlaveDamsel();
      //writeln("11: STYLE: ", style, "; dms: ", (dms ? "TAN" : "ONA"));
      if (!dms) return false;
      //writeln("12: STYLE: ", style, "; dist=", level.player.distanceToEntity(dms));
      if (level.player.distanceToEntity(dms) > 16 || global.thiefLevel > 0 || global.murderer) return false;
      if (level.stats.money < kissValue) {
        level.osdMessageTalk(va("YOU NEED |%d| GOLD!\nGET OUTTA HERE, DEADBEAT!", kissValue), replace:true, inShopOnly:false);
        return false;
      }
      //writeln("13: STYLE: ", style, "; dms: ", GetClassName(dms.Class));
      //!!if (isRealLevel()) global.kissesBought += 1;
      dms.status = KISS;
      dms.setSprite(global.isDamsel ? 'sPKissL' : 'sDamselKissL');
      level.stats.takeMoney(kissValue);
      cash += kissValue;
      //!if (isRealLevel()) global.moneySpent += getKissValue();
      global.plife += 1;
      level.osdMessageTalk((global.isDamsel ? "NOW AIN'T HE SWEET!" : "NOW AIN'T SHE SWEET!"), replace:true, inShopOnly:false);
      return false;
    }
    return false;
  }

  /*
  if (forSale) {
    writeln("trying to buy '", GetClassName(o.Class), "'");
  } else {
    writeln("trying to sell '", GetClassName(o.Class), "'");
  }
  */

  auto die = ItemDice(o);
  if (die) {
    doCrapsBet(plr);
    // don't allow player to own the item
    return false;
  }

  // selling various items
  if (!o.forSale) {
    auto price = o.cost;
    if (!o.sellingToShopAllowed || price < 1) {
      // oops
      if (price < 1) {
        //writeln("price not set for ", (o.shopDesc ? o.shopDesc : string(o.objName).toUpperCase));
        level.osdMessageTalk("I WON'T BUY IT EVEN IF YOU WILL PAY ME FOR THAT!", replace:true, timeout:-1);
      } else /*if (!o.sellingToShopAllowed && price < 1)*/ {
        level.osdMessageTalk("YOU SHOULD NOT SELL IT!", replace:true, timeout:-1);
      }
      return false;
    }
    //!!!if (!(status == IDLE && abs(plr.ix-ix) < 80)) return false; // shopkeeper is busy or too far
    if (status != IDLE && status != FOLLOW) return false; // shopkeeper is busy
    price = max(1, round(price*0.894));
    // offer?
    if (!o.sellOfferDone) {
      if (price > cash) {
        level.osdMessageTalk(va("SORRY, I CAN'T BUY |%s| FOR |%d| GOLD.\nI HAVEN'T GOT ENOUGH MONEY!", (o.shopDesc ? o.shopDesc : string(o.objName).toUpperCase), price), replace:true, timeout:-1);
        return false;
      }
      level.osdMessageTalk(va("SELL |%s| FOR |%d| GOLD?\nPRESS $PAY AGAIN TO CONFIRM.", (o.shopDesc ? o.shopDesc : string(o.objName).toUpperCase), price), replace:true, timeout:-1);
      o.sellOfferDone = true;
      return false;
    }
    // deal
    o.sellOfferDone = false;
    if (price > cash) {
      level.osdMessageTalk(va("SORRY, I CAN'T BUY |%s| FOR |%d| GOLD.\nI HAVEN'T GOT ENOUGH MONEY!", (o.shopDesc ? o.shopDesc : string(o.objName).toUpperCase), price), replace:true, timeout:-1);
      return false;
    }
    if (o.heldBy) o.heldBy.holdItem = none;
    plr.addScore(price);
    cash -= price;
    plr.playSound('sndCoin');
    level.MakeMapObject(plr.ix, plr.iy-8, 'oBigCollect');
    level.osdMessageTalk("~PLEASURE DOING BUSINESS!~", replace:true, inShopOnly:false, timeout:4);
    auto idol = ItemGoldIdol(o);
    if (idol) idol.registerConverted(); // stats
    o.instanceRemove();
    return false;
  }

  if (!o.forSale) FatalError("oShopkeeper::doSellItem: the thing that should not be! (0)");

  if (o.shopType != style) {
    // not ours
    writeln("SELL-SKIP: me is ", style, "; item is from ", o.shopType);
    return false;
  }

  if (level.stats.money < plr.holdItem.cost) {
    level.osdMessageTalk("YOU HAVEN'T GOT ENOUGH MONEY!", replace:true);
    return false;
  }
  plr.playSound('sndCoin');
  // take away some money
  level.stats.takeMoney(o.cost);
  // give some money to shopkeeper
  cash += o.cost;
  // allow player to use the item
  o.forSale = false;
  level.osdMessageTalk("~PLEASURE DOING BUSINESS!~", replace:true, inShopOnly:false, timeout:4);
  return true;
}


// if we hit a bank, we cannot play anymore
bool isCrapsBetAllowed (PlayerPawn plr) {
  if (style != 'Craps') return false;
  if (plr.bet) return true; // already did
  if (!isPlayerInOurShop()) return false;
  // "no prize" probably means that we hit a bank
  return hasAnyPrize();
}


void doCrapsBet (PlayerPawn plr) {
  if (plr.bet) return; // already did
  if (!isPlayerInOurShop()) return; // oops
  resetAllDices();
  if (!isCrapsBetAllowed(plr)) return;
  if (level.stats.money >= betValue) {
    level.stats.takeMoney(betValue);
    plr.bet = betValue;
    cash += betValue;
  } else {
    level.osdMessageTalk("YOU HAVEN'T GOT ENOUGH MONEY!", replace:true);
  }
}


// returns current prize, creates new one
MapObject getCrapsPrize (PlayerPawn plr, optional bool generateNew) {
  auto prize = level.findCrapsPrize();
  if (!prize) return none;
  prize.forSale = false;
  prize.inDiceHouse = false;
  createCrapsPoofAt(prize.ix, prize.iy);
  if (generateNew || !specified_generateNew) {
    bool foundIt = false;
    foreach (auto idx, ref name pname; prizes) {
      if (pname) {
        auto np = level.MakeMapObject(prize.ix, prize.iy, pname);
        if (np) {
          np.forSale = true;
          np.inDiceHouse = true;
          np.shopType = 'Craps';
          foundIt = true;
        }
        pname = '';
        if (np) break;
      }
    }
    //if (!foundIt) level.osdMessageTalk("SORRY, WE DON'T HAVE PRIZES ANYMORE!");
  }
  // put prize near the player
  if (level.isInShop(prize.ix/16-3, prize.iy/16)) {
    prize.fltx -= 32;
  } else if (level.isInShop(prize.ix/16+3, prize.iy/16)) {
    prize.fltx += 32;
  } else {
    prize.fltx = plr.ix;
    prize.flty = plr.iy;
  }
  createCrapsPoofAt(prize.ix, prize.iy);
  return prize;
}


void createCrapsPoofAt (int x, int y) {
  auto obj = level.MakeMapObject(x-4, y+6, 'oPoof');
  if (obj) obj.xVel = -0.4;
  obj = level.MakeMapObject(x+4, y+6, 'oPoof');
  if (obj) obj.xVel = 0.4;
}


final void resetAllDices () {
  // reset all dices
  level.forEachObject(delegate bool (MapObject o) {
    if (!o.forSale || o.spectral || !o.isInstanceAlive) return false;
    auto dc = ItemDice(o);
    if (!dc) return false;
    if (dc.rollState != ItemDice::RollState.Rolling) {
      dc.resetRollState(); // allow to throw it again
    }
    return false;
  });
}


transient int rval, rcount, rtotal;

// 0: not ready yet
final int checkAllDices () {
  rval = 0;
  rcount = 0;
  rtotal = 0;

  level.forEachObject(delegate bool (MapObject o) {
    if (!o.forSale || o.spectral || !o.isInstanceAlive) return false;
    auto dc = ItemDice(o);
    if (!dc) return false;
    ++rtotal;
    if (dc.heldBy) return false;
    auto rv = dc.getRollNumber();
    if (rv) {
      rval += rv;
      ++rcount;
    }
    return false;
  });

  if (rcount == 0 || rcount != rtotal) return 0; // not yet
  return rval;
}


// return `true` to stop checking other shopkeepers
// this will be called for *EACH* shopkeeper, sorry
bool onDiePlayed (PlayerPawn plr, ItemDice die) {
  if (style != 'Craps') return false;
  if (angered || dead) return false;
  if (!die.forSale) return false;

  auto bet = plr.bet;
  if (!bet) {
    die.resetRollState(); // allow to throw it again
    return false;
  }

  auto rval = checkAllDices();
  if (!rval) return false;

  writeln("ROLL: ", rval);
  resetAllDices();

  //rval = 7; //dbg
  plr.bet = 0;

  if (rval == 7) {
    ++level.stats.totalDiceGamesWonPrize;
    plr.playSound('sndChestOpen');
    //cash += bet; // already taken in `doCrapsBet()`
    level.osdMessageTalk("YOU ROLLED A |SEVEN|!\n~YOU WIN A PRIZE!~", replace:true, inShopOnly:false);
    getCrapsPrize(plr);
  } else if (rval > 7) {
    if (cash >= bet) {
      ++level.stats.totalDiceGamesWon;
      level.osdMessageTalk(va("YOU ROLLED A |%d|!\nCONGRATULATIONS! YOU ~WIN~!", rval), replace:true, inShopOnly:false);
      plr.playSound('sndCoin');
      cash -= bet*2;
      plr.addScore(bet*2);
    } else {
      ++level.stats.totalDiceGamesWonPrize;
      broke = true;
      level.osdMessageTalk("YOU BROKE THE BANK!\n~TAKE THE PRIZE~!", replace:true, inShopOnly:false);
      plr.playSound('sndChestOpen');
      getCrapsPrize(plr, generateNew:false);
    }
  } else if (rval < 7) {
    ++level.stats.totalDiceGamesLost;
    level.osdMessageTalk(va("YOU ROLLED A |%d|!\nI'M SORRY, BUT YOU ~LOSE~!", rval), replace:true, inShopOnly:false, hiColor1:0xff_00_00);
    plr.playSound('sndThud');
    //cash += bet; // already taken in `doCrapsBet()`
  }

  return true;
}


void doCrapsShop () {
  auto plr = level.player;

  if (isPlayerInOurShop()) {
    if (plr.holdItem) {
      auto die = ItemDice(plr.holdItem);
      if (die) {
        if (!die.forSale) return;
        if (plr.bet) {
          level.osdMessageTalk("THROW A DICE, PLEASE.", replace:true);
        } else {
          if (!isCrapsBetAllowed(plr)) {
            level.osdMessageTalk("SORRY, I AM OUT OF BUSINESS.", replace:true);
            return;
          }
          if (level.stats.money < betValue) {
            level.osdMessageTalk(va("YOU DON'T HAVE ENOUGH MONEY\nTO BET |%d| GOLD.", betValue), replace:true);
          } else {
            level.osdMessageTalk(va("PRESS $PAY TO BET |%d| GOLD.", betValue), replace:true);
          }
        }
        return;
      }
    } else {
      if (plr.bet) {
        level.osdMessageTalk("THROW A DICE, PLEASE.", replace:true);
      } else {
        if (!level.osdGetTalkMessage()) {
          if (!isCrapsBetAllowed(plr)) {
            level.osdMessageTalk("SORRY, I AM OUT OF BUSINESS.", replace:true);
            return;
          }
          if (level.stats.money < betValue) {
            level.osdMessageTalk(va("YOU DON'T HAVE ENOUGH MONEY\nTO BET |%d| GOLD.", betValue), replace:true);
          } else {
            level.osdMessageTalk(va("PRESS $PAY TO BET |%d| GOLD.", betValue), replace:true);
          }
        }
      }
    }
  }

  // don't steal a prize
  auto obj = MapItem(plr.holdItem);
  if (obj && obj.forSale) {
    //writeln("0:item '", GetClassName(obj.Class), "'; inshop=", level.isInShop(level.player.ix/16, level.player.iy/16));
    if (obj !isa ItemDice && !level.isInShop(level.player.ix/16, level.player.iy/16)) {
      level.scrShopkeeperAnger(GameLevel::SCAnger.ItemStolen);
    }
  }
}


void dropShotgun () {
  if (hasGun) {
    auto obj = level.MakeMapObject(ix+8, iy+8, (hisGunIsAsh ? 'oAshShotgun' : 'oShotgun'));
    if (obj) {
      obj.yVel = global.randOther(4, 6);
      obj.xVel = global.randOther(4, 6)*(xVel < 0 ? -1 : 1);
    }
    hasGun = false;
    hisGunIsAsh = false;
  }
}


void angerIt () {
  if (angered) return;
  if (!outlaw) {
    level.forEachObject(delegate bool (MapObject o) {
      if (o.forSale && o.shopType == style) o.forSale = false;
      return false;
    });
  }
  angered = true;
}


final bool cbCheckMoveableNearby (MapTile t) {
  if (!t.solid || !t.moveable) return false;
  // check if it has a player nearby
  //writeln("SK-MOVEABLE: dx0=", t.x0-level.player.x0, "; dx1=", level.player.x1-t.x1, "; dy=", level.player.y1-t.y1);
  if (abs(level.player.y1-t.y1) < 4) {
    int dx0 = t.x0-level.player.x0;
    if (dx0 >= 10 && dx0 <= 14) return true;
    int dx1 = level.player.x1-t.x1;
    if (dx1 >= 10 && dx1 <= 14) return true;
    //if ((dx < 0 && dx < -16-4) || (dx >= 0 && dx < 4)) return true;
  }
  return false;
}


bool isPlayerInOurShop () {
  if (outlaw) return false;
  int ptx = level.player.ix/16, pty = level.player.iy/16;
  if (!level.isInShop(ptx, pty)) return false;
  return (style == level.lg.roomShopType(ptx, pty));
}


void setFollowStates () {
  auto plr = level.player;
  auto item = MapItem(plr.holdItem);
  if (!item) return;
  if (!item.forSale) return;
  if (item isa ItemDice) return; // never ever
  //writeln("0:item '", GetClassName(obj.Class), "'; inshop=", level.isInShop(level.player.ix/16, level.player.iy/16));
  int px = level.player.ix, py = level.player.iy;
  int ptx = px/16, pty = py/16;
  if (!level.isInShop(ptx, pty)) {
    //k8: anger all shopkeepers, why not?
    level.scrShopkeeperAnger(GameLevel::SCAnger.ItemStolen);
    return;
  }
  //auto sk = level.findNearestCalmShopkeeper(level.player.ix, level.player.iy);
  //if (sk) sk.status = FOLLOW; else status = FOLLOW;
  //auto pstyle = level.lg.roomShopType(level.player.ix/16, level.player.iy/16);
  foreach (MonsterShopkeeper sk; level.objGrid.inRectPix(px-176, py-176, 176*2, 176*2, precise:false, castClass:MonsterShopkeeper)) {
    if (sk.dead || sk.angered || sk.outlaw || sk.style == 'Craps') continue;
    if (sk.status != IDLE && sk.status != FOLLOW) continue;
    //if (sk.style != level.lg.roomShopType(level.player.ix/16, level.player.iy/16)) continue;
    if (item.shopType && item.shopType != sk.style) continue;
    sk.status = FOLLOW;
  }
}


override bool onSpearTrapHit (MapObject spear) {
  if (heldBy) heldBy.holdItem = none;

  countsAsKill = false;
  status = THROWN;
  counter = stunMax;
  yVel = -6;
  xVel = (spear.ix+8 < ix+8 ? 4 : -4);
  spear.playSound('sndHit');
  hp -= global.config.spearDmg;
  spillBlood();

  return false;
}


override void thinkFrame () {
  ::thinkFrame();
  //if (hitByArrow) writeln("after ::think hp=", hp);
  if (!isInstanceAlive) return;

  if (status == THROWN) {
    if (dead) {
      status = DEAD;
    } else {
      status = STUNNED;
    }
  }

  /*
  if (level.isInShop(level.player.ix/16, level.player.iy/16)) {
    writeln("me: ", style, "; player is in ", level.lg.roomShopType(level.player.ix/16, level.player.iy/16));
  }
  */

  if (!heldBy) {
    yVel = fmin(yVel+myGrav, 8);
    moveRel(xVel, yVel);
  }

  bool colLeft = !!isCollisionLeft(1);
  bool colRight = !!isCollisionRight(1);
  bool colBot = !!isCollisionBottom(1);
  bool colTop = !!isCollisionTop(1);

  if (colBot && status != STUNNED) yVel = 0;

  if (throwCount > 0) --throwCount;

  int x = ix, y = iy;

  // crushed
  if (!heldBy) {
    if ((status >= STUNNED && level.isSolidAtPoint(x+8, y+12)) ||
        (status < STUNNED && level.isSolidAtPoint(x+8, y+8)))
    {
      spillBlood();
      playSound('sndCavemanDie');
      if (hp > 0 && countsAsKill) level.addKill(objName);
      if (!outlaw) global.murderer = true;
      if (status != DEAD && !dead) dropShotgun();
      instanceRemove();
      return;
    }

    // check if player is cornered shopeekeper with a moveable block
    if (!global.config.optShopkeeperIdiots &&
        !angered && !outlaw && (status == IDLE || status == FOLLOW) &&
        !level.player.dead && !level.player.stunned && distanceToEntity(level.player) < 96+16) {
      auto leftsolid = level.isSolidAtPoint(x-8, y+8); //, delegate (bool) (MapTile t) { return (t.solid && !t.moveable); });
      auto rightsolid = level.isSolidAtPoint(x+16+8, y+8); //, delegate (bool) (MapTile t) { return (t.solid && !t.moveable); });
      if (leftsolid || rightsolid) {
        //writeln("checking for cornered shopkeeper... (l=", !!leftsolid, "; r=", !!rightsolid, "); y=", y, "; y0=", y0, "; h=", height);
        // some direction is blocked; check if there is a solid nearby, and a player behind it
        //foundSolidAndPlayer = false;
        int warnLength = 2*16;
        auto stl = level.checkTilesInRect(x0-warnLength, y0, warnLength, height, &cbCheckMoveableNearby);
        auto str = level.checkTilesInRect(x1, y0, warnLength, height, &cbCheckMoveableNearby);
        if ((str && leftsolid) || (stl && rightsolid)) {
          writeln("SHOPKEEPER IS CORNERED!");
          status = ATTACK;
          tryToJumpOut = true;
        }
      }
    }
  }

  if (status != DEAD && status != STUNNED && hp < 1) status = DEAD;

  auto plr = level.player;
  auto dist = distanceToEntityCenter(plr);

  if (status == IDLE || status == FOLLOW) {
    auto item = MapItem(plr.holdItem);
    if (item && item !isa ItemDice && item.forSale && item.shopType == style) {
      level.osdMessageTalk(va("BUY |%s| FOR |%d| GOLD.\nPRESS $PAY TO PURCHASE.", item.shopDesc, item.cost), replace:true);
    }
  }

  if (status == PATROL || status == WALK) {
    if (!plr.dead && plr.visible && dist <= 96 && plr.iy-(y+8) < 16) {
      status = ATTACK;
    } else if (abs(plr.ix-(x+8)) < 4) {
      status = ATTACK;
    }
  }

  // pickup shotgun (or get it from the player, lol)
  if (hp > 0 && !hasGun && (status == PATROL || status == WALK || status == ATTACK)) {
    level.isObjectInRect(x0, y0, width, height, delegate bool (MapObject o) {
      if (o isa ItemWeaponShotgun) {
        if (o.heldBy) o.heldBy.holdItem = none;
        hasGun = true;
        hisGunIsAsh = (o isa ItemWeaponAshShotgun);
        o.instanceRemove();
        return true;
      }
      return false;
    });
    // get from player
    if (!hasGun && level.player.holdItem isa ItemWeaponShotgun && plr.collidesWith(self)) {
      auto o = level.player.holdItem;
      if (o.heldBy) o.heldBy.holdItem = none;
      hasGun = true;
      hisGunIsAsh = (o isa ItemWeaponAshShotgun);
      o.instanceRemove();
    }
    // ...and from a pocket too
    if (!hasGun && level.player.pickedItem isa ItemWeaponShotgun && plr.collidesWith(self)) {
      auto o = level.player.pickedItem;
      if (o.heldBy) o.heldBy.holdItem = none;
      level.player.pickedItem = none;
      hasGun = true;
      hisGunIsAsh = (o isa ItemWeaponAshShotgun);
      o.instanceRemove();
    }
  }

  if (status == IDLE) {
    bounced = false;

    if (colLeft) fltx += 1;
    if (colRight) fltx -= 1;
    x = ix; // update cached value

    if (colLeft && colRight) status = ATTACK;

    dir = (plr.ix < x+8 ? Dir.Left : Dir.Right);

    if (yVel < 0 && colTop) yVel = 0;

    if (global.murderer || global.thiefLevel > 0) {
      status = PATROL;
    } else if (isPlayerInOurShop() && (!welcomed || level.player.shopType != style || !level.osdGetTalkMessage())) {
      //writeln("::: SHOP TYPE: ", level.lg.roomShopType(level.player.ix/16, level.player.iy/16));
      writeln("*** WELCOME TO SHOP: ", style);

      string msg;
      int hi2 = -1;
           if (style == 'Bomb') msg = "WELCOME TO |"~shopkeeperName~"'S| ~BOMB~ SHOP!";
      else if (style == 'Weapon') msg = "WELCOME TO |"~shopkeeperName~"'S| ~ARMORY~!";
      else if (style == 'Clothing') msg = "WELCOME TO |"~shopkeeperName~"'S| ~CLOTHING~ SHOP!";
      else if (style == 'Rare') msg = "WELCOME TO |"~shopkeeperName~"'S| ~SPECIALTY~ SHOP!";
      else if (style == 'Craps') msg = "WELCOME TO |"~shopkeeperName~"'S| ~DICE HOUSE~!";
      else if (style == 'Kissing') { msg = "WELCOME TO |"~shopkeeperName~"'S| ~KISSING PARLOR~!"; hi2 = 0xff_00_00; }
      else if (style == 'Ankh') msg = "I HAVE ~SOMETHING SPECIAL~...";
      else msg = "WELCOME TO |"~shopkeeperName~"'S| SUPPLY SHOP!";

      if (style == 'Craps') {
        msg = va("%s\nPRESS $PAY TO BET |%d| GOLD.", msg, betValue);
      } else if (style == 'Kissing') {
        msg = va("%s\n|%d| GOLD A KISS. PRESS $PAY.", msg, kissValue);
      }

      if (msg) level.osdMessageTalk(msg, replace:true, hiColor2:hi2);
    }
  }

  ///////////////
  // CRAPS
  ///////////////
  if (!angered && !outlaw && (status == IDLE || status == FOLLOW || !welcomed)) {
    if (!welcomed && level.isInShop(level.player.ix/16, level.player.iy/16) && level.lg.roomShopType(level.player.ix/16, level.player.iy/16) == style) welcomed = true;
    if (style == 'Craps') {
      doCrapsShop();
    } else if (plr.holdItem) {
      auto obj = MapItem(plr.holdItem);
      if (obj && obj.forSale) setFollowStates();
    }
  }

  if (status == FOLLOW) {
    if (style != 'Craps' && plr.holdItem) {
      auto obj = MapItem(plr.holdItem);
      if (obj && obj.forSale) {
        setFollowStates();
      } else if (!obj || !obj.forSale) {
        writeln("STOP FOLLOWING");
        status = IDLE;
      }
    }

    imageSpeed = 0.5;

    if (colLeft || colRight) dir ^= 1;

    if (turnTimer > 0) {
      turnTimer -= 1;
    } else if (abs(plr.iy-(y+8)) < 8 && colBot && dist > 16) {
      dir = (plr.ix < x ? Dir.Left : Dir.Right);
      turnTimer = 10;
    }

    float i = dist/16.0*1.5;
    xVel = fclamp((dir == Dir.Left ? -i : i), -3, 3);

    if (dist < 12 || plr.iy < y) xVel = 0;

    if (plr.holdItem) {
      auto obj = plr.holdItem;
      if (!obj.forSale || obj isa ItemDice) status = IDLE;
    } else {
      status = IDLE;
    }
  } else if (status == PATROL) {
    bounced = false;

    if (yVel < 0 && colBot) yVel = 0;

    if (colBot && counter > 0) --counter;
    if (counter < 1) {
      dir = global.randOther(0, 1);
      status = WALK;
    }
  } else if (status == WALK) {
    imageSpeed = 0.5;

    if (colLeft || colRight) dir ^= 1;

    xVel = (dir == Dir.Left ? -1.5 : 1.5);
    if (level.isSolidAtPoint(x+(dir == Dir.Left ? -1 : 16), y/*, -1, -1*/)) {
      status = PATROL;
      counter = global.randOther(20, 50);
      xVel = 0;
    }

    if (global.randOther(1, 100) == 1) {
      status = PATROL;
      counter = global.randOther(20, 50);
      xVel = 0;
    }
  } else if (status == ATTACK) {
    imageSpeed = 1;

    if (!angered) angerIt();

    if (turnTimer > 0) {
      turnTimer -= 1;
    } else if (abs(plr.iy-(y+8)) < 8 && colBot && dist > 16) {
      dir = (plr.ix < x ? Dir.Left : Dir.Right);
      turnTimer = 20;
    }

    if (colLeft || colRight) dir ^= 1;

    xVel = (dir == Dir.Left ? -3 : 3);

    if (hasGun) {
      if (firing > 0) {
        firing -= 1;
      } else if (abs(plr.iy-(y+8)) < 32) {
        if ((dir == Dir.Left && plr.ix < x+8 && dist < 96) ||
            (dir == Dir.Right && plr.ix > x+8 && dist < 96))
        {
          fireShotgun();
          yVel -= 1;
          xVel += (dir == Dir.Left ? 3 : -3);
          playSound('sndShotgun');
          firing = firingMax;
        }
      }
    }

    // jump
    if (!tryToJumpOut && plr.iy > y && abs(plr.ix-(x+8)) < 64) {
      // do nothing
    } else if ((dir == Dir.Left && level.isSolidAtPoint(x-16, y)) ||
               (dir == Dir.Right && level.isSolidAtPoint(x+32, y)))
    {
      if (colBot && !isCollisionTop(4)) {
        yVel = -global.randOther(7, 8);
        tryToJumpOut = false;
      }
      //else { if (facing == LEFT) xVel = -1.5; else xVel = 1.5; }
    } else if (plr.iy <= y+16 &&
               ((dir == Dir.Left && !level.isSolidAtPoint(x-16, y+16)) ||
                (dir == Dir.Right && !level.isSolidAtPoint(x+32, y+16))))
    {
      if (colBot && !isCollisionTop(4)) {
        yVel = -global.randOther(7, 8);
        tryToJumpOut = false;
      }
    }

    if (!colBot && plr.iy > y+8) {
      xVel = (dir == Dir.Left ? -1.5 : 1.5);
    }

    if (plr.dead || !plr.visible) status = WALK;
  } else if (status == STUNNED) {
    if (colBot) {
      setSprite('sShopStunL');
    } else if (bounced) {
      setSprite(yVel < 0 ? 'sShopBounceL' : 'sShopFallL');
    } else {
      setSprite(xVel < 0 ? 'sShopDieLL' : 'sShopDieLR');
    }

    if (colBot && !bounced) {
      bounced = true;
      spillBlood(amount:1);
    }

    if (heldBy || colBot) {
      if (counter > 0) {
        --counter;
      } else if (hp > 0) {
        status = ATTACK;
        if (heldBy) heldBy.holdItem = none;
      }
    }
    if (spriteLName == 'sShopStunL') {
      // YASM 1.8.1
      if (counter > 0 && counter < 30) imageSpeed = 0.8;
    } else {
      imageSpeed = 0.5;
    }
  } else if (status == DEAD) {
    if (!dead) {
      /*if (isRoom("rStars")) {
        if (oStarsRoom.kills < 99) oStarsRoom.kills += 1;
      } else*/ {
        if (countsAsKill) level.addKill(objName);
        /*
        if (isRealLevel()) global.enemyKills[19] += 1;
        global.shopkeepers += 1;
        global.kills += 1;
        */
        if (level.levelKind != GameLevel::LevelKind.Stars) {
          if (!outlaw) {
            global.murderer = true;
            if (false /*!isRealLevel()*/) {
              /*
              repeat(rand(1, 4)) {
                obj = instance_create(x+8, y+8, oGoldNugget);
                obj.yVel = -1;
                obj.xVel = rand(1, 3)-rand(1, 3);
              }
              */
            } else if (style != 'Bounty Hunter') {
              if (style == 'Craps') {
                cash += plr.bet;
                plr.bet = 0;
              }
              x = ix;
              y = iy;
              int loot = 0;
              while (cash > loot) {
                MapObject obj;
                if (cash >= loot+5000+trunc(ceil(5000.0/4.0)*global.levelType)) {
                  obj = level.MakeMapObject(x+8, y+8, chooseName('oGoldNugget', 'oGoldBar', 'oGoldBars', 'oEmeraldBig', 'oSapphireBig', 'oRubyBig', 'oDiamond'));
                } else if (cash >= loot+1600+trunc(ceil(1600.0/4.0)*global.levelType)) {
                  obj = level.MakeMapObject(x+8, y+8, chooseName('oGoldNugget', 'oGoldBar', 'oGoldBars', 'oEmeraldBig', 'oSapphireBig', 'oRubyBig'));
                } else if (cash >= loot+1000+trunc(ceil(1000.0/4.0)*global.levelType)) {
                  obj = level.MakeMapObject(x+8, y+8, chooseName('oGoldNugget', 'oGoldBar', 'oGoldBars'));
                } else {
                  obj = level.MakeMapObject(x+8, y+8, 'oGoldChunk');
                }
                if (obj) {
                  obj.yVel = -2;
                  obj.xVel = global.randOther(1, 4)-global.randOther(1, 4);
                } else {
                  writeln("SHOPKEEPER LOOT: WTF?!");
                }
                loot += obj.value+trunc(ceil(obj.value/4.0)*global.levelType);
              }
            } else {
              x = ix;
              y = iy;
              foreach (; 0..global.randOther(1, 4)) {
                auto obj = level.MakeMapObject(x+8, y+8, 'oGoldNugget');
                if (obj) {
                  obj.yVel = -1;
                  obj.xVel = global.randOther(1, 3)-global.randOther(1, 3);
                }
              }
            }
          } else {
            x = ix;
            y = iy;
            foreach (; 0..global.randOther(3, 6)) {
              auto obj = level.MakeMapObject(x+8, y+8, chooseName('oGoldNugget', 'oGoldNugget', 'oGoldBar', 'oGoldBar', 'oGoldBars', 'oEmeraldBig', 'oSapphireBig', 'oRubyBig'));
              if (obj) {
                obj.yVel = -1;
                obj.xVel = global.randOther(1, 3)-global.randOther(1, 3);
              }
            }
          }
        }
      }
      playSound('sndCavemanDie');
      dead = true;
    }
    setSprite('sShopDieL');
    if (fabs(xVel) > 0 || fabs(yVel) > 0) status = STUNNED;
  }

  if (status >= STUNNED) {
    dropShotgun();
    scrCheckCollisions();
    if (xVel == 0 && yVel == 0 && hp < 1) status = DEAD;
    //k8: it should be something like the following, but...
    /*
    if (fabs(xVel) <= 0.001 && fabs(yVel) <= 0.001 && hp < 1) {
      xVel = 0;
      yVel = 0;
      status = DEAD;
    }
    */
  }

  //if (isCollisionSolid()) y -= 2;

  if (xVel > 0) xVel -= 0.1;
  if (xVel < 0) xVel += 0.1;
  if (fabs(xVel) < 0.5) xVel = 0;

  if (status < STUNNED && status != THROWN) {
    setSprite(fabs(xVel) > 0 ? 'sShopRunLeft' : 'sShopLeft');
  }

  if (heldBy) {
    setSprite(hp > 0 ? 'sShopHeldL' : 'sShopDHeldL');
  }

  if (dead && deathTimer > 0 && level.levelKind == GameLevel::LevelKind.Stars) {
    if (--deathTimer == 0) {
      spillBlood();
      instanceRemove();
      return;
    }
  }
}


override void drawWithOfs (int xpos, int ypos, int scale, float currFrameDelta) {
  ::drawWithOfs(xpos, ypos, scale, currFrameDelta);

  if (hasGun && status != IDLE && status != FOLLOW) {
    int xi, yi;
    getInterpCoords(currFrameDelta, scale, out xi, out yi);

    auto spr = level.sprStore[dir == Dir.Left ? 'sShotgunLeft' : 'sShotgunRight'];
    auto spf = spr.frames[0];
    xi -= spf.xofs*scale;
    yi -= spf.yofs*scale;
    spf.blitAt(xi-xpos+(dir == Dir.Left ? 6 : 10)*scale, yi-ypos+10*scale, scale);
  }
}


defaultproperties {
  objName = 'Shopkeeper';
  //!style = "General";
  desc = "Shopkeeper";
  desc2 = "The only thing deadlier than this saleman's twelve gauge is his temper.";

  //setCollisionBounds(2, 0, sprite_width-2, sprite_height);
  xVel = 0;
  imageSpeed = 0.5;
  myGrav = 0.6;

  // stats
  hp = 20;
  invincible = 0;
  favor = 12;
  outlaw = false;
  broke = false;

  status = IDLE;

  bounced = false;
  dead = false;
  counter = 0;
  sightCounter = 0;
  turnTimer = 0;
  throwCount = 0;
  stunTime = 5;

  welcomed = false;
  angered = false;

  firing = 0;
  firingMax = 30;

  dir = Dir.Left;

  bounced = false;
  burning = false;
  counter = 200;
  stunMax = 100; //?!!!

  invincible = 0;

  removeCorpse = false; // only applies to enemies that have corpses (Caveman, Yeti, etc.)
  deathTimer = 200; // how many steps after death until corpse is removed

  countsAsKill = true; // sometimes it's not the player's fault!

  canPickUp = true;

  canBeHitByBullet = true;
  canBeNudged = false;

  hasGun = true;
  hisGunIsAsh = true;

  doBasicPhysics = false;
  leavesBody = true;
  canBeStunned = true;
  checkInsideBlock = false; // we'll do our own check


  namelist[$] = "AHKMED";
  namelist[$] = "TERRY";
  namelist[$] = "SMITHY";
  namelist[$] = "KASIM";
  namelist[$] = "DOUG";
  namelist[$] = "BEN";
  namelist[$] = "KERT";
  namelist[$] = "DUKE";
  namelist[$] = "TOBY";
  namelist[$] = "GUERT";
  namelist[$] = "PANCHO";
  namelist[$] = "EARL";
  namelist[$] = "IVAN";
  namelist[$] = "OLLIE";
  namelist[$] = "IDO";
  namelist[$] = "BOB";
  namelist[$] = "RUDY";
  namelist[$] = "JIMBO";
  namelist[$] = "ERIC";
  namelist[$] = "WILLY";
  namelist[$] = "MATT";
  namelist[$] = "LAZLO";
  namelist[$] = "WANG";
  namelist[$] = "PETER";
  namelist[$] = "ANDY";
  namelist[$] = "DONG";
  namelist[$] = "LEMMY";
  namelist[$] = "OMAR";
  namelist[$] = "VADIM";
  namelist[$] = "TARN";
  namelist[$] = "SLASH";
  namelist[$] = "LANCE";
  namelist[$] = "ALEC";
  namelist[$] = "NOEL";
  namelist[$] = "KYLE";
  namelist[$] = "DEREK";
  namelist[$] = "RICH";
  namelist[$] = "JON";
  namelist[$] = "TOM";
  namelist[$] = "PHIL";
  namelist[$] = "CALVIN";
  namelist[$] = "HASSAN";
  namelist[$] = "PAUL";
  namelist[$] = "COLIN";
  namelist[$] = "IAN";
  namelist[$] = "EDDIE";
  namelist[$] = "JAKE";
  namelist[$] = "JOEY";
  namelist[$] = "JOSH";
  namelist[$] = "STEVE";
}