src/sed/testsuite/distrib.sed

   1 #   This is straight out of C News
   2 #
   3 #
   4 # All this does is massage the headers so they look like what news
   5 # software expects.  To:, Cc: and Resent-*: headers are masked.
   6 # Reply-To: is turned into references, which is questionable (could
   7 # just as well be dropped.
   8 #
   9 # The From: line is rewritten to use the "address (comments)" form
  10 # instead of "phrase <route>" form our mailer uses.  Also, addresses
  11 # with no "@domainname" are assumed to originate locally, and so are
  12 # given a domain.
  13 #
  14 # The Sender: field below reflects the address of the person who
  15 # maintains our mailing lists.  The Approved: field is in a special
  16 # form, so that we can do bidirectional gatewaying.  Any message
  17 # in a newsgroup that bears this stamp will not be fed into the
  18 # matching mailing list.
  19
  20 1i\
  21 Path: mailnewsgateway
  22         :a
  23         /^[Rr]eceived:/b r
  24         /^[Nn]ewsgroups:/b r
  25         /^[Pp]ath:/b r
  26         /^[Tt][Oo]:/s/^/Original-/
  27         /^[Cc][Cc]:/s/^/Original-/
  28         /^[Rr][Ee][Ss][Ee][Nn][Tt]-.*/s/^/Original-/
  29         /^[Mm][Ee][Ss][Ss][Aa][Gg][Ee]-[Ii][Dd]:/s/@/.alt.buddha.fat.short.guy@/
  30         s/^[Ii]n-[Rr]eply-[Tt]o:/References:/
  31         /^From:/{
  32                 s/<\([^@]*\)>$/<\1@$thissite>/
  33                 s/^From:[       ][      ]*\(.*\)  *<\(.*\)>$/From: \2 (\1)/
  34                 }
  35         s/-[Ii]d:/-ID:/
  36         s/^[Ss][Uu][Bb][Jj][Ee][Cc][Tt]:[       ]*$/Subject: (none)/
  37         s/^\([^:]*:\)[   ]*/\1 /
  38         /^$/{i\
  39 Newsgroups: alt.buddha.short.fat.guy\
  40 Distribution: world\
  41 Sender: news@cygnus.com\
  42 Approved: alt.buddha.short.fat.guy@cygnus.com
  43         b e
  44         }
  45         p
  46         n
  47         b a
  48         :r
  49         s/.*//g
  50         n
  51         /^[     ]/b r
  52         b a
  53         :e
  54         p
  55         n
  56         b e