Modules/FindLibLZMA.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #[=======================================================================[.rst:
   5 FindLibLZMA
   6 -----------
   7
   8 Find LZMA compression algorithm headers and library.
   9
  10
  11 Imported Targets
  12 ^^^^^^^^^^^^^^^^
  13
  14 .. versionadded:: 3.14
  15
  16 This module defines :prop_tgt:`IMPORTED` target ``LibLZMA::LibLZMA``, if
  17 liblzma has been found.
  18
  19 Result variables
  20 ^^^^^^^^^^^^^^^^
  21
  22 This module will set the following variables in your project:
  23
  24 ``LIBLZMA_FOUND``
  25   True if liblzma headers and library were found.
  26 ``LIBLZMA_INCLUDE_DIRS``
  27   Directory where liblzma headers are located.
  28 ``LIBLZMA_LIBRARIES``
  29   Lzma libraries to link against.
  30 ``LIBLZMA_HAS_AUTO_DECODER``
  31   True if lzma_auto_decoder() is found (required).
  32 ``LIBLZMA_HAS_EASY_ENCODER``
  33   True if lzma_easy_encoder() is found (required).
  34 ``LIBLZMA_HAS_LZMA_PRESET``
  35   True if lzma_lzma_preset() is found (required).
  36 ``LIBLZMA_VERSION``
  37   .. versionadded:: 3.26
  38     the version of LZMA found.
  39
  40   See also legacy variable ``LIBLZMA_VERSION_STRING``.
  41
  42 Legacy Variables
  43 ^^^^^^^^^^^^^^^^
  44
  45 The following variables are provided for backward compatibility:
  46
  47 ``LIBLZMA_VERSION_MAJOR``
  48   The major version of lzma
  49 ``LIBLZMA_VERSION_MINOR``
  50   The minor version of lzma
  51 ``LIBLZMA_VERSION_PATCH``
  52   The patch version of lzma
  53 ``LIBLZMA_VERSION_STRING``
  54   version number as a string (ex: "5.0.3")
  55
  56   .. versionchanged:: 3.26
  57     Superseded by ``LIBLZMA_VERSION``.
  58
  59 #]=======================================================================]
  60
  61 cmake_policy(PUSH)
  62 cmake_policy(SET CMP0159 NEW) # file(STRINGS) with REGEX updates CMAKE_MATCH_<n>
  63
  64 find_path(LIBLZMA_INCLUDE_DIR lzma.h )
  65 if(NOT LIBLZMA_LIBRARY)
  66   find_library(LIBLZMA_LIBRARY_RELEASE NAMES lzma liblzma NAMES_PER_DIR PATH_SUFFIXES lib)
  67   find_library(LIBLZMA_LIBRARY_DEBUG NAMES lzmad liblzmad NAMES_PER_DIR PATH_SUFFIXES lib)
  68   include(${CMAKE_CURRENT_LIST_DIR}/SelectLibraryConfigurations.cmake)
  69   select_library_configurations(LIBLZMA)
  70 else()
  71   file(TO_CMAKE_PATH "${LIBLZMA_LIBRARY}" LIBLZMA_LIBRARY)
  72 endif()
  73
  74 if(LIBLZMA_INCLUDE_DIR AND EXISTS "${LIBLZMA_INCLUDE_DIR}/lzma/version.h")
  75     file(STRINGS "${LIBLZMA_INCLUDE_DIR}/lzma/version.h" LIBLZMA_HEADER_CONTENTS REGEX "#define LZMA_VERSION_[A-Z]+ [0-9]+")
  76
  77     string(REGEX REPLACE ".*#define LZMA_VERSION_MAJOR ([0-9]+).*" "\\1" LIBLZMA_VERSION_MAJOR "${LIBLZMA_HEADER_CONTENTS}")
  78     string(REGEX REPLACE ".*#define LZMA_VERSION_MINOR ([0-9]+).*" "\\1" LIBLZMA_VERSION_MINOR "${LIBLZMA_HEADER_CONTENTS}")
  79     string(REGEX REPLACE ".*#define LZMA_VERSION_PATCH ([0-9]+).*" "\\1" LIBLZMA_VERSION_PATCH "${LIBLZMA_HEADER_CONTENTS}")
  80
  81     set(LIBLZMA_VERSION_STRING "${LIBLZMA_VERSION_MAJOR}.${LIBLZMA_VERSION_MINOR}.${LIBLZMA_VERSION_PATCH}")
  82     set(LIBLZMA_VERSION ${LIBLZMA_VERSION_STRING})
  83     unset(LIBLZMA_HEADER_CONTENTS)
  84 endif()
  85
  86 # We're using new code known now as XZ, even library still been called LZMA
  87 # it can be found in http://tukaani.org/xz/
  88 # Avoid using old codebase
  89 if (LIBLZMA_LIBRARY)
  90   include(${CMAKE_CURRENT_LIST_DIR}/CheckLibraryExists.cmake)
  91   set(CMAKE_REQUIRED_QUIET_SAVE ${CMAKE_REQUIRED_QUIET})
  92   set(CMAKE_REQUIRED_QUIET ${LibLZMA_FIND_QUIETLY})
  93   if(NOT LIBLZMA_LIBRARY_RELEASE AND NOT LIBLZMA_LIBRARY_DEBUG)
  94     set(LIBLZMA_LIBRARY_check ${LIBLZMA_LIBRARY})
  95   elseif(LIBLZMA_LIBRARY_RELEASE)
  96     set(LIBLZMA_LIBRARY_check ${LIBLZMA_LIBRARY_RELEASE})
  97   elseif(LIBLZMA_LIBRARY_DEBUG)
  98     set(LIBLZMA_LIBRARY_check ${LIBLZMA_LIBRARY_DEBUG})
  99   endif()
 100   check_library_exists(${LIBLZMA_LIBRARY_check} lzma_auto_decoder "" LIBLZMA_HAS_AUTO_DECODER)
 101   check_library_exists(${LIBLZMA_LIBRARY_check} lzma_easy_encoder "" LIBLZMA_HAS_EASY_ENCODER)
 102   check_library_exists(${LIBLZMA_LIBRARY_check} lzma_lzma_preset "" LIBLZMA_HAS_LZMA_PRESET)
 103   unset(LIBLZMA_LIBRARY_check)
 104   set(CMAKE_REQUIRED_QUIET ${CMAKE_REQUIRED_QUIET_SAVE})
 105 endif ()
 106
 107 include(FindPackageHandleStandardArgs)
 108 find_package_handle_standard_args(LibLZMA  REQUIRED_VARS  LIBLZMA_LIBRARY
 109                                                           LIBLZMA_INCLUDE_DIR
 110                                                           LIBLZMA_HAS_AUTO_DECODER
 111                                                           LIBLZMA_HAS_EASY_ENCODER
 112                                                           LIBLZMA_HAS_LZMA_PRESET
 113                                            VERSION_VAR    LIBLZMA_VERSION
 114                                  )
 115 mark_as_advanced( LIBLZMA_INCLUDE_DIR LIBLZMA_LIBRARY )
 116
 117 if (LIBLZMA_FOUND)
 118     set(LIBLZMA_LIBRARIES ${LIBLZMA_LIBRARY})
 119     set(LIBLZMA_INCLUDE_DIRS ${LIBLZMA_INCLUDE_DIR})
 120     if(NOT TARGET LibLZMA::LibLZMA)
 121         add_library(LibLZMA::LibLZMA UNKNOWN IMPORTED)
 122         set_target_properties(LibLZMA::LibLZMA PROPERTIES
 123                               INTERFACE_INCLUDE_DIRECTORIES "${LIBLZMA_INCLUDE_DIR}"
 124                               IMPORTED_LINK_INTERFACE_LANGUAGES C)
 125
 126         if(LIBLZMA_LIBRARY_RELEASE)
 127             set_property(TARGET LibLZMA::LibLZMA APPEND PROPERTY
 128                 IMPORTED_CONFIGURATIONS RELEASE)
 129             set_target_properties(LibLZMA::LibLZMA PROPERTIES
 130                 IMPORTED_LOCATION_RELEASE "${LIBLZMA_LIBRARY_RELEASE}")
 131         endif()
 132
 133         if(LIBLZMA_LIBRARY_DEBUG)
 134             set_property(TARGET LibLZMA::LibLZMA APPEND PROPERTY
 135                 IMPORTED_CONFIGURATIONS DEBUG)
 136             set_target_properties(LibLZMA::LibLZMA PROPERTIES
 137                 IMPORTED_LOCATION_DEBUG "${LIBLZMA_LIBRARY_DEBUG}")
 138         endif()
 139
 140         if(NOT LIBLZMA_LIBRARY_RELEASE AND NOT LIBLZMA_LIBRARY_DEBUG)
 141             set_target_properties(LibLZMA::LibLZMA PROPERTIES
 142                 IMPORTED_LOCATION "${LIBLZMA_LIBRARY}")
 143         endif()
 144     endif()
 145 endif ()
 146
 147 cmake_policy(POP)