Modules/FindQt3.cmake

   1 # Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
   2 # file Copyright.txt or https://cmake.org/licensing for details.
   3
   4 #[=======================================================================[.rst:
   5 FindQt3
   6 -------
   7
   8 Locate Qt include paths and libraries
   9
  10 This module defines:
  11
  12 ::
  13
  14   QT_INCLUDE_DIR    - where to find qt.h, etc.
  15   QT_LIBRARIES      - the libraries to link against to use Qt.
  16   QT_DEFINITIONS    - definitions to use when
  17                       compiling code that uses Qt.
  18   QT_FOUND          - If false, don't try to use Qt.
  19   QT_VERSION_STRING - the version of Qt found
  20
  21
  22
  23 If you need the multithreaded version of Qt, set QT_MT_REQUIRED to
  24 TRUE
  25
  26 Also defined, but not for general use are:
  27
  28 ::
  29
  30   QT_MOC_EXECUTABLE, where to find the moc tool.
  31   QT_UIC_EXECUTABLE, where to find the uic tool.
  32   QT_QT_LIBRARY, where to find the Qt library.
  33   QT_QTMAIN_LIBRARY, where to find the qtmain
  34    library. This is only required by Qt3 on Windows.
  35 #]=======================================================================]
  36
  37 cmake_policy(PUSH)
  38 cmake_policy(SET CMP0159 NEW) # file(STRINGS) with REGEX updates CMAKE_MATCH_<n>
  39
  40 # These are around for backwards compatibility
  41 # they will be set
  42 #  QT_WRAP_CPP, set true if QT_MOC_EXECUTABLE is found
  43 #  QT_WRAP_UI set true if QT_UIC_EXECUTABLE is found
  44
  45 # If Qt4 has already been found, fail.
  46 if(QT4_FOUND)
  47   if(Qt3_FIND_REQUIRED)
  48     message( FATAL_ERROR "Qt3 and Qt4 cannot be used together in one project.")
  49   else()
  50     if(NOT Qt3_FIND_QUIETLY)
  51       message( STATUS    "Qt3 and Qt4 cannot be used together in one project.")
  52     endif()
  53     cmake_policy(POP)
  54     return()
  55   endif()
  56 endif()
  57
  58
  59 file(GLOB GLOB_PATHS /usr/lib/qt-3*)
  60 foreach(GLOB_PATH ${GLOB_PATHS})
  61   list(APPEND GLOB_PATHS_BIN "${GLOB_PATH}/bin")
  62 endforeach()
  63 find_path(QT_INCLUDE_DIR
  64   NAMES qt.h
  65   PATHS
  66   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
  67   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
  68   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
  69   $ENV{QTDIR}/include
  70   ${GLOB_PATHS}
  71   /usr/share/qt3/include
  72   C:/Progra~1/qt/include
  73   /usr/local/include/X11/qt3
  74   PATH_SUFFIXES lib/qt/include lib/qt3/include include/qt include/qt3 qt/include qt3/include
  75   )
  76
  77 # if qglobal.h is not in the qt_include_dir then set
  78 # QT_INCLUDE_DIR to NOTFOUND
  79 if(NOT EXISTS ${QT_INCLUDE_DIR}/qglobal.h)
  80   set(QT_INCLUDE_DIR QT_INCLUDE_DIR-NOTFOUND CACHE PATH "path to Qt3 include directory" FORCE)
  81 endif()
  82
  83 if(QT_INCLUDE_DIR)
  84   #extract the version string from qglobal.h
  85   file(STRINGS ${QT_INCLUDE_DIR}/qglobal.h QGLOBAL_H REGEX "#define[\t ]+QT_VERSION_STR[\t ]+\"[0-9]+.[0-9]+.[0-9]+[a-z]*\"")
  86   string(REGEX REPLACE ".*\"([0-9]+.[0-9]+.[0-9]+[a-z]*)\".*" "\\1" qt_version_str "${QGLOBAL_H}")
  87   unset(QGLOBAL_H)
  88
  89   # Under windows the qt library (MSVC) has the format qt-mtXYZ where XYZ is the
  90   # version X.Y.Z, so we need to remove the dots from version
  91   string(REGEX REPLACE "\\." "" qt_version_str_lib "${qt_version_str}")
  92   set(QT_VERSION_STRING "${qt_version_str}")
  93 endif()
  94
  95 file(GLOB GLOB_PATHS_LIB /usr/lib/qt-3*/lib/)
  96 if (QT_MT_REQUIRED)
  97   find_library(QT_QT_LIBRARY
  98     NAMES
  99     qt-mt qt-mt${qt_version_str_lib} qt-mtnc${qt_version_str_lib}
 100     qt-mtedu${qt_version_str_lib} qt-mt230nc qt-mtnc321 qt-mt3
 101     PATHS
 102       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 103       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 104       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 105       ENV QTDIR
 106       ${GLOB_PATHS_LIB}
 107       /usr/share/qt3
 108       C:/Progra~1/qt
 109     PATH_SUFFIXES
 110       lib lib/qt lib/qt3 qt qt3 qt/lib qt3/lib
 111     )
 112
 113 else ()
 114   find_library(QT_QT_LIBRARY
 115     NAMES
 116     qt qt-${qt_version_str_lib} qt-edu${qt_version_str_lib}
 117     qt-mt qt-mt${qt_version_str_lib} qt-mtnc${qt_version_str_lib}
 118     qt-mtedu${qt_version_str_lib} qt-mt230nc qt-mtnc321 qt-mt3
 119     PATHS
 120       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 121       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 122       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 123       ENV QTDIR
 124       ${GLOB_PATHS_LIB}
 125       /usr/share/qt3
 126       C:/Progra~1/qt/lib
 127     PATH_SUFFIXES
 128       lib lib/qt lib/qt3 qt qt3 qt/lib qt3/lib
 129     )
 130 endif ()
 131
 132
 133 find_library(QT_QASSISTANTCLIENT_LIBRARY
 134   NAMES qassistantclient
 135   PATHS
 136     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 137     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 138     "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 139     ENV QTDIR
 140     ${GLOB_PATHS_LIB}
 141     /usr/share/qt3
 142     C:/Progra~1/qt
 143   PATH_SUFFIXES
 144     lib lib/qt lib/qt3 qt qt3 qt/lib qt3/lib
 145   )
 146
 147 # Qt 3 should prefer QTDIR over the PATH
 148 find_program(QT_MOC_EXECUTABLE
 149   NAMES moc-qt3 moc3 moc3-mt moc
 150   HINTS
 151     ENV QTDIR
 152   PATHS
 153   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
 154   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
 155   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
 156   ${GLOB_PATHS_BIN}
 157     /usr/share/qt3
 158     C:/Progra~1/qt
 159   PATH_SUFFIXES
 160     bin lib/qt lib/qt3 qt qt3 qt/bin qt3/bin lib/qt/bin lib/qt3/bin
 161   )
 162
 163 if(QT_MOC_EXECUTABLE)
 164   set ( QT_WRAP_CPP "YES")
 165 endif()
 166
 167 # Qt 3 should prefer QTDIR over the PATH
 168 find_program(QT_UIC_EXECUTABLE
 169   NAMES uic-qt3 uic3 uic3-mt uic
 170   HINTS
 171     ENV QTDIR
 172   PATHS
 173   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]/include/Qt"
 174   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]/include/Qt"
 175   "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]/include/Qt"
 176   ${GLOB_PATHS_BIN}
 177     /usr/share/qt3
 178     C:/Progra~1/qt
 179   PATH_SUFFIXES
 180     bin lib/qt lib/qt3 qt qt3 qt/bin qt3/bin lib/qt/bin lib/qt3/bin
 181   )
 182
 183 if(QT_UIC_EXECUTABLE)
 184   set ( QT_WRAP_UI "YES")
 185 endif()
 186
 187 if (WIN32)
 188   find_library(QT_QTMAIN_LIBRARY
 189     NAMES qtmain
 190     HINTS
 191       ENV QTDIR
 192       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.1;InstallDir]"
 193       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.2.0;InstallDir]"
 194       "[HKEY_CURRENT_USER\\Software\\Trolltech\\Qt3Versions\\3.1.0;InstallDir]"
 195     PATHS
 196       "$ENV{ProgramFiles}/qt"
 197       "C:/Program Files/qt"
 198     PATH_SUFFIXES
 199       lib
 200     DOC "This Library is only needed by and included with Qt3 on MSWindows. It should be NOTFOUND, undefined or IGNORE otherwise."
 201     )
 202 endif ()
 203
 204 #support old QT_MIN_VERSION if set, but not if version is supplied by find_package()
 205 if(NOT Qt3_FIND_VERSION AND QT_MIN_VERSION)
 206   set(Qt3_FIND_VERSION ${QT_MIN_VERSION})
 207 endif()
 208
 209 # if the include a library are found then we have it
 210 include(FindPackageHandleStandardArgs)
 211 if (CMAKE_FIND_PACKAGE_NAME STREQUAL "Qt")
 212   # FindQt include()'s this module. It's an old pattern, but rather than trying
 213   # to suppress this from outside the module (which is then sensitive to the
 214   # contents, detect the case in this module and suppress it explicitly.
 215   set(FPHSA_NAME_MISMATCHED 1)
 216 endif ()
 217 find_package_handle_standard_args(Qt3
 218                                   REQUIRED_VARS QT_QT_LIBRARY QT_INCLUDE_DIR QT_MOC_EXECUTABLE
 219                                   VERSION_VAR QT_VERSION_STRING)
 220 unset(FPHSA_NAME_MISMATCHED)
 221 set(QT_FOUND ${QT3_FOUND} )
 222
 223 if(QT_FOUND)
 224   set( QT_LIBRARIES ${QT_LIBRARIES} ${QT_QT_LIBRARY} )
 225   set( QT_DEFINITIONS "")
 226
 227   if (WIN32 AND NOT CYGWIN)
 228     if (QT_QTMAIN_LIBRARY)
 229       # for version 3
 230       set (QT_DEFINITIONS -DQT_DLL -DQT_THREAD_SUPPORT -DNO_DEBUG)
 231       set (QT_LIBRARIES imm32.lib ${QT_QT_LIBRARY} ${QT_QTMAIN_LIBRARY} )
 232       set (QT_LIBRARIES ${QT_LIBRARIES} winmm wsock32)
 233     else ()
 234       # for version 2
 235       set (QT_LIBRARIES imm32.lib ws2_32.lib ${QT_QT_LIBRARY} )
 236     endif ()
 237   else ()
 238     set (QT_LIBRARIES ${QT_QT_LIBRARY} )
 239
 240     set (QT_DEFINITIONS -DQT_SHARED -DQT_NO_DEBUG)
 241     if(QT_QT_LIBRARY MATCHES "qt-mt")
 242       set (QT_DEFINITIONS ${QT_DEFINITIONS} -DQT_THREAD_SUPPORT -D_REENTRANT)
 243     endif()
 244
 245   endif ()
 246
 247   if (QT_QASSISTANTCLIENT_LIBRARY)
 248     set (QT_LIBRARIES ${QT_QASSISTANTCLIENT_LIBRARY} ${QT_LIBRARIES})
 249   endif ()
 250
 251   # Backwards compatibility for CMake1.4 and 1.2
 252   set (QT_MOC_EXE ${QT_MOC_EXECUTABLE} )
 253   set (QT_UIC_EXE ${QT_UIC_EXECUTABLE} )
 254   # for unix add X11 stuff
 255   if(UNIX)
 256     find_package(X11)
 257     if (X11_FOUND)
 258       set (QT_LIBRARIES ${QT_LIBRARIES} ${X11_LIBRARIES})
 259     endif ()
 260     if (CMAKE_DL_LIBS)
 261       set (QT_LIBRARIES ${QT_LIBRARIES} ${CMAKE_DL_LIBS})
 262     endif ()
 263   endif()
 264   if(QT_QT_LIBRARY MATCHES "qt-mt")
 265     find_package(Threads)
 266     set(QT_LIBRARIES ${QT_LIBRARIES} ${CMAKE_THREAD_LIBS_INIT})
 267   endif()
 268 endif()
 269
 270 if(QT_MOC_EXECUTABLE)
 271   execute_process(COMMAND ${QT_MOC_EXECUTABLE} "-v"
 272                   OUTPUT_VARIABLE QTVERSION_MOC
 273                   ERROR_QUIET)
 274 endif()
 275 if(QT_UIC_EXECUTABLE)
 276   execute_process(COMMAND ${QT_UIC_EXECUTABLE} "-version"
 277                   OUTPUT_VARIABLE QTVERSION_UIC
 278                   ERROR_QUIET)
 279 endif()
 280
 281 set(_QT_UIC_VERSION_3 FALSE)
 282 if("${QTVERSION_UIC}" MATCHES " 3.")
 283   set(_QT_UIC_VERSION_3 TRUE)
 284 endif()
 285
 286 set(_QT_MOC_VERSION_3 FALSE)
 287 if("${QTVERSION_MOC}" MATCHES " 3.")
 288   set(_QT_MOC_VERSION_3 TRUE)
 289 endif()
 290
 291 set(QT_WRAP_CPP FALSE)
 292 if (QT_MOC_EXECUTABLE AND _QT_MOC_VERSION_3)
 293   set ( QT_WRAP_CPP TRUE)
 294 endif ()
 295
 296 set(QT_WRAP_UI FALSE)
 297 if (QT_UIC_EXECUTABLE AND _QT_UIC_VERSION_3)
 298   set ( QT_WRAP_UI TRUE)
 299 endif ()
 300
 301 mark_as_advanced(
 302   QT_INCLUDE_DIR
 303   QT_QT_LIBRARY
 304   QT_QTMAIN_LIBRARY
 305   QT_QASSISTANTCLIENT_LIBRARY
 306   QT_UIC_EXECUTABLE
 307   QT_MOC_EXECUTABLE
 308   QT_WRAP_CPP
 309   QT_WRAP_UI
 310   )
 311
 312 cmake_policy(POP)