Koha/Acquisition/Orders.pm

   1 package Koha::Acquisition::Orders;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Carp;
  21
  22 use Koha::Database;
  23
  24 use Koha::DateUtils qw( dt_from_string );
  25 use Koha::Acquisition::Order;
  26
  27 use base qw(Koha::Objects);
  28
  29 =head1 NAME
  30
  31 Koha::Acquisition::Orders object set class
  32
  33 =head1 API
  34
  35 =head2 Class Methods
  36
  37 =head3 filter_by_lates
  38
  39 my $late_orders = $orders->filter_by_lates($params);
  40
  41 Filter an order set given different parameters.
  42
  43 This is the equivalent method of the former GetLateOrders C4 subroutine
  44
  45 $params can be:
  46
  47 =over
  48
  49 =item C<delay> the number of days the basket has been closed
  50
  51 =item C<bookseller_id> the bookseller id
  52
  53 =item C<estimated_from> Beginning of the estimated delivery date
  54
  55 =item C<estimated_to> End of the estimated delivery date
  56
  57 =back
  58
  59 =cut
  60
  61 sub filter_by_lates {
  62     my ( $self, $params ) = @_;
  63     my $delay = $params->{delay};
  64     my $bookseller_id = $params->{bookseller_id};
  65     # my $branchcode = $params->{branchcode}; # FIXME do we really need this
  66     my $estimated_from = $params->{estimated_from};
  67     my $estimated_to = $params->{estimated_to};
  68     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
  69
  70     my @delivery_time_conditions;
  71     my $date_add = "DATE_ADD(basketno.closedate, INTERVAL COALESCE(booksellerid.deliverytime, booksellerid.deliverytime, 0) day)";
  72     if ( defined $estimated_from or defined $estimated_to ) {
  73         push @delivery_time_conditions, \[ "$date_add IS NOT NULL" ];
  74     }
  75     if ( defined $estimated_from ) {
  76         push @delivery_time_conditions, \[ "$date_add >= ?", $dtf->format_date($estimated_from) ];
  77     }
  78     if ( defined $estimated_to ) {
  79         push @delivery_time_conditions, \[ "$date_add <= ?", $dtf->format_date($estimated_to) ];
  80     }
  81     if ( defined $estimated_from and not defined $estimated_to ) {
  82         push @delivery_time_conditions, \[ "$date_add <= ?", $dtf->format_date(dt_from_string) ];
  83     }
  84
  85     $self->search(
  86         {
  87             -or => [
  88                 { datereceived => undef },
  89                 quantityreceived => { '<' => \'quantity' }
  90             ],
  91             'basketno.closedate' => [
  92                 -and =>
  93                 { '!=' => undef },
  94                 {
  95                     defined $delay
  96                     ? (
  97                         '<=' => $dtf->format_date(
  98                             dt_from_string->subtract( days => $delay )
  99                         )
 100                       )
 101                     : ()
 102                 }
 103               ],
 104             'datecancellationprinted' => undef,
 105             (
 106                 $bookseller_id
 107                 ? ( 'basketno.booksellerid' => $bookseller_id )
 108                 : ()
 109             ),
 110
 111             # ( $branchcode ? ('borrower.branchcode')) # FIXME branch is not a filter we may not need to implement this
 112
 113             ( @delivery_time_conditions ? ( -and => \@delivery_time_conditions ) : ()),
 114             (
 115                 C4::Context->preference('IndependentBranches')
 116                   && !C4::Context->IsSuperLibrarian
 117                 ? ( 'borrower.branchcode' => C4::Context->userenv->{branch} )
 118                 : ()
 119             ),
 120
 121             ( orderstatus => { '!=' => 'cancelled' } ),
 122
 123         },
 124         {
 125             '+select' => [\"DATE_ADD(basketno.closedate, INTERVAL COALESCE(booksellerid.deliverytime, booksellerid.deliverytime, 0) day)"],
 126             '+as' => ['estimated_delivery_date'],
 127             join => { 'basketno' => 'booksellerid' },
 128             prefetch => {'basketno' => 'booksellerid'},
 129         }
 130     );
 131 }
 132
 133 =head3 filter_by_current
 134
 135     $orders->filter_by_current
 136
 137 Return the orders of the set that have not been cancelled.
 138
 139 =cut
 140
 141 sub filter_by_current {
 142     my ($self) = @_;
 143     return $self->search(
 144         {
 145             datecancellationprinted => undef,
 146         }
 147     );
 148 }
 149
 150 =head3 filter_by_cancelled
 151
 152     $orders->filter_by_cancelled
 153
 154 Return the orders of the set that have been cancelled.
 155
 156 =cut
 157
 158 sub filter_by_cancelled {
 159     my ($self) = @_;
 160     return $self->search(
 161         {
 162             datecancellationprinted => { '!=' => undef }
 163         }
 164     );
 165 }
 166
 167 =head2 Internal methods
 168
 169 =head3 _type (internal)
 170
 171 =cut
 172
 173 sub _type {
 174     return 'Aqorder';
 175 }
 176
 177 =head3 object_class (internal)
 178
 179 =cut
 180
 181 sub object_class {
 182     return 'Koha::Acquisition::Order';
 183 }
 184
 185 1;