kernel/hack-module.awk

   1
   2 /^int kvm_init\(/ { anon_inodes = 1 }
   3
   4 /return 0;/ && anon_inodes {
   5     print "\tr = kvm_init_anon_inodes();";
   6     print "\tif (r) {";
   7     print "\t\t__free_page(bad_page);";
   8     print "\t\tgoto out;";
   9     print "\t}";
  10     print "\tpreempt_notifier_sys_init();";
  11     printf("\tprintk(\"loaded kvm module (%s)\\n\");\n", version);
  12     anon_inodes = 0
  13 }
  14
  15 /^void kvm_exit/ { anon_inodes_exit = 1 }
  16
  17 /\}/ && anon_inodes_exit {
  18     print "\tkvm_exit_anon_inodes();";
  19     print "\tpreempt_notifier_sys_exit();";
  20     anon_inodes_exit = 0
  21 }
  22
  23 /MODULE_AUTHOR/ {
  24     printf("MODULE_INFO(version, \"%s\");\n", version)
  25 }
  26
  27 /^static void vmx_load_host_state/ {
  28     vmx_load_host_state = 1
  29 }
  30
  31 /vmcs_readl\(HOST_GS_BASE\)/ &&  vmx_load_host_state {
  32     $0 = "\t\twrmsrl(MSR_GS_BASE, gsbase);";
  33     vmx_load_host_state = 0
  34 }
  35
  36 /atomic_inc\(&kvm->mm->mm_count\);/ { $0 = "mmget(&kvm->mm->mm_count);" }
  37
  38 /^\t\.fault = / {
  39     fcn = gensub(/,/, "", "g", $3)
  40     $0 = "\t.VMA_OPS_FAULT(fault) = VMA_OPS_FAULT_FUNC(" fcn "),"
  41 }
  42
  43 /^static int .*_stat_get/ {
  44     $3 = "__" $3
  45 }
  46
  47 /DEFINE_SIMPLE_ATTRIBUTE.*_stat_get/ {
  48     name = gensub(/,/, "", "g", $2);
  49     print "MAKE_SIMPLE_ATTRIBUTE_GETTER(" name ")"
  50 }
  51
  52 { sub(/linux\/mm_types\.h/, "linux/mm.h") }
  53
  54 { sub(/tsc_khz/, "kvm_tsc_khz") }
  55
  56 { sub(/\<desc_struct\>/, "kvm_desc_struct") }
  57 { sub(/\<ldttss_desc64\>/, "kvm_ldttss_desc64") }
  58 { sub(/\<desc_ptr\>/, "kvm_desc_ptr") }
  59
  60 /^\t\.name = "kvm"/ { $0 = "\tset_kset_name(\"kvm\")," }
  61
  62 { print }
  63
  64 /kvm_x86_ops->run/ {
  65     print "\tspecial_reload_dr7();"
  66 }
  67
  68 /unsigned long flags;/ &&  vmx_load_host_state {
  69     print "\tunsigned long gsbase;"
  70 }
  71
  72 /local_irq_save/ &&  vmx_load_host_state {
  73     print "\t\tgsbase = vmcs_readl(HOST_GS_BASE);"
  74 }