CMakeLists.txt

   1 set(CMAKE_POLICY_DEFAULT_CMP0048 NEW)
   2 set(CMAKE_POLICY_DEFAULT_CMP0063 NEW)
   3 cmake_minimum_required(VERSION 2.8.12...4.0)
   4 include(cmake/CMakeModulePath.cmake)
   5 include(cmake/Languages.cmake)
   6 project(liba ${LANGUAGES})
   7 include(cmake/Project.cmake)
   8 include(cmake/core/file.cmake)
   9 include(cmake/core/string.cmake)
  10 include(cmake/CMakeByteOrder.cmake)
  11 include(cmake/CMakeBuildType.cmake)
  12 include(cmake/EnabledLanguages.cmake)
  13 include(cmake/TargetSupportsSharedLibs.cmake)
  14 include(cmake/TargetSupportsExecutables.cmake)
  15 include(cmake/TargetSupportsRelocatable.cmake)
  16 include(cmake/TargetSupportsSymbolicLink.cmake)
  17
  18 option(LIBA_WARNINGS "Enable/Disable warnings" 0)
  19
  20 if(LIBA_WARNINGS)
  21   include(cmake/TargetWarnings.cmake)
  22 endif()
  23
  24 option(LIBA_ANALYZER "Enable/Disable analyzer" 0)
  25
  26 if(LIBA_ANALYZER)
  27   include(cmake/TargetAnalyzer.cmake)
  28 endif()
  29
  30 option(LIBA_SANITIZE "Enable/Disable sanitize" 0)
  31
  32 if(LIBA_SANITIZE)
  33   include(cmake/TargetSanitize.cmake)
  34 endif()
  35
  36 option(LIBA_STATIC "Enable/Disable finding and linking static libraries" 0)
  37
  38 if(LIBA_STATIC)
  39   include(cmake/CMakeFindLibraryStatic.cmake)
  40   include(cmake/TargetStatic.cmake)
  41 endif()
  42
  43 option(LIBA_CCACHE "Enable/Disable ccache" 0)
  44
  45 if(LIBA_CCACHE)
  46   include(cmake/UseCCache.cmake)
  47 endif()
  48
  49 if(UNIX)
  50   set(LIBA_MATH "m" CACHE FILEPATH "system math library")
  51 else()
  52   set(LIBA_MATH "" CACHE FILEPATH "system math library")
  53 endif()
  54
  55 include(CheckLibraryExists)
  56 set(LIBA_FLOAT 8 CACHE STRING "floating-point number bytes")
  57 set_property(CACHE LIBA_FLOAT PROPERTY STRINGS 4 8 16)
  58
  59 function(check_math VARIABLE FUNCTION)
  60   get_filename_component(LOCATION "${LIBA_MATH}" DIRECTORY)
  61   list(APPEND CMAKE_REQUIRED_LIBRARIES ${LIBA_MATH})
  62
  63   if(LIBA_FLOAT GREATER 8)
  64     set(FUNCTION ${FUNCTION}l)
  65   elseif(LIBA_FLOAT EQUAL 4)
  66     set(FUNCTION ${FUNCTION}f)
  67   endif()
  68
  69   check_library_exists("${LIBA_MATH}"
  70     ${FUNCTION} "${LOCATION}" ${VARIABLE}
  71   )
  72 endfunction()
  73
  74 check_math(A_HAVE_EXPM1 expm1)
  75 check_math(A_HAVE_LOG1P log1p)
  76 check_math(A_HAVE_HYPOT hypot)
  77 check_math(A_HAVE_ATAN2 atan2)
  78 check_math(A_HAVE_CSQRT csqrt)
  79 check_math(A_HAVE_CPOW cpow)
  80 check_math(A_HAVE_CEXP cexp)
  81 check_math(A_HAVE_CLOG clog)
  82 check_math(A_HAVE_CSIN csin)
  83 check_math(A_HAVE_CCOS ccos)
  84 check_math(A_HAVE_CTAN ctan)
  85 check_math(A_HAVE_CSINH csinh)
  86 check_math(A_HAVE_CCOSH ccosh)
  87 check_math(A_HAVE_CTANH ctanh)
  88 check_math(A_HAVE_CASIN casin)
  89 check_math(A_HAVE_CACOS cacos)
  90 check_math(A_HAVE_CATAN catan)
  91 check_math(A_HAVE_CASINH casinh)
  92 check_math(A_HAVE_CACOSH cacosh)
  93 check_math(A_HAVE_CATANH catanh)
  94
  95 option(LIBA_PYTHON "Enable/Disable python" 0)
  96
  97 if(LIBA_PYTHON)
  98   find_package(Python COMPONENTS Interpreter)
  99   find_package(Cython)
 100 endif()
 101
 102 option(LIBA_DOXYGEN "Enable/Disable doxygen" 0)
 103
 104 if(LIBA_DOXYGEN)
 105   find_package(Doxygen OPTIONAL_COMPONENTS dot mscgen dia)
 106 endif()
 107
 108 option(LIBA_CPPCHECK "Enable/Disable cppcheck" 0)
 109
 110 if(LIBA_CPPCHECK)
 111   find_package(cppcheck)
 112 endif()
 113
 114 option(LIBA_CLANG_TIDY "Enable/Disable clang-tidy" 0)
 115
 116 if(LIBA_CLANG_TIDY)
 117   find_package(ClangTidy)
 118 endif()
 119
 120 option(LIBA_IWYU "Enable/Disable include-what-you-use" 0)
 121
 122 if(LIBA_IWYU)
 123   find_package(IWYU)
 124 endif()
 125
 126 option(LIBA_IPO "Enable/Disable interprocedural optimization" 0)
 127
 128 # https://cmake.org/cmake/help/latest/module/CheckIPOSupported.html
 129 if(NOT CMAKE_VERSION VERSION_LESS 3.9 AND LIBA_IPO)
 130   cmake_policy(SET CMP0069 NEW)
 131   include(CheckIPOSupported)
 132   check_ipo_supported(RESULT LIBA_IPO)
 133 endif()
 134
 135 if(DEFINED ENV{ANDROID_ROOT} AND EXISTS $ENV{ANDROID_ROOT})
 136   option(LIBA_PIE "Enable/Disable position independent code" 1)
 137 else()
 138   option(LIBA_PIE "Enable/Disable position independent code" 0)
 139 endif()
 140
 141 # https://cmake.org/cmake/help/latest/module/CheckPIESupported.html
 142 if(NOT CMAKE_VERSION VERSION_LESS 3.14)
 143   cmake_policy(SET CMP0083 NEW)
 144   include(CheckPIESupported)
 145   check_pie_supported()
 146 endif()
 147
 148 function(set_library_options)
 149   if(LIBA_IWYU AND IWYU_FOUND)
 150     add_include_what_you_use(TARGETS ${ARGN})
 151   endif()
 152
 153   if(LIBA_CLANG_TIDY AND CLANG_TIDY_FOUND)
 154     add_clang_tidy(TARGETS ${ARGN} OPTIONS --fix)
 155   endif()
 156
 157   if(LIBA_CPPCHECK AND CPPCHECK_FOUND)
 158     add_cppcheck(TARGETS ${ARGN} OPTIONS --enable=warning,performance)
 159   endif()
 160
 161   if(CMAKE_C_COMPILER_ID MATCHES "TinyCC" AND CMAKE_STATIC_LIBRARY_SUFFIX STREQUAL .lib)
 162     set_property(TARGET ${ARGN} PROPERTY IMPORT_SUFFIX .def)
 163   endif()
 164
 165   set_target_properties(${ARGN} PROPERTIES INTERPROCEDURAL_OPTIMIZATION ${LIBA_IPO}
 166     C_VISIBILITY_PRESET hidden CXX_VISIBILITY_PRESET hidden VISIBILITY_INLINES_HIDDEN 1
 167   )
 168
 169   if(LIBA_WARNINGS)
 170     target_compile_warnings(${ARGN})
 171   endif()
 172
 173   if(LIBA_ANALYZER)
 174     target_compile_analyzer(${ARGN})
 175   endif()
 176 endfunction()
 177
 178 function(add_library_properties target scope source)
 179   target_compile_definitions(${target} ${scope} $<TARGET_PROPERTY:${source},${ARGV3}COMPILE_DEFINITIONS>)
 180   target_include_directories(${target} ${scope} $<TARGET_PROPERTY:${source},${ARGV3}INCLUDE_DIRECTORIES>)
 181
 182   if(${scope} MATCHES "PUBLIC|PRIVATE")
 183     set_property(TARGET ${target} APPEND PROPERTY LINK_LIBRARIES $<TARGET_PROPERTY:${source},${ARGV3}LINK_LIBRARIES>)
 184   endif()
 185
 186   if(${scope} MATCHES "PUBLIC|INTERFACE")
 187     set_property(TARGET ${target} APPEND PROPERTY INTERFACE_LINK_LIBRARIES $<TARGET_PROPERTY:${source},${ARGV3}LINK_LIBRARIES>)
 188   endif()
 189 endfunction()
 190
 191 option(LIBA_MIMALLOC "Enable/Disable override using mimalloc" 0)
 192
 193 if(LIBA_MIMALLOC)
 194   find_package(mimalloc)
 195 endif()
 196
 197 if(mimalloc_FOUND)
 198   if(TARGET mimalloc-static)
 199     set(MIMALLOC_LIBRARY mimalloc-static)
 200   else()
 201     set(MIMALLOC_LIBRARY mimalloc)
 202   endif()
 203 endif()
 204
 205 find_package(Git)
 206
 207 if(GIT_FOUND)
 208   function(git_command output)
 209     execute_process(ERROR_QUIET
 210       COMMAND ${GIT_EXECUTABLE} ${ARGN}
 211       OUTPUT_STRIP_TRAILING_WHITESPACE
 212       OUTPUT_VARIABLE ${output}
 213     )
 214     set(${output} ${${output}} PARENT_SCOPE)
 215   endfunction()
 216
 217   git_command(GIT_COMMIT_LONG log -1 --pretty=format:%H)
 218   git_command(GIT_COMMIT_DATE log -1 --pretty=format:%cd --date=format:%Y%m%d)
 219 endif()
 220
 221 if(GIT_COMMIT_DATE)
 222   set(PROJECT_VERSION_TWEAK ${GIT_COMMIT_DATE})
 223   set(${PROJECT_NAME}_VERSION_TWEAK ${GIT_COMMIT_DATE})
 224 endif()
 225
 226 if(NOT EXISTS "${A_HAVE_H}")
 227   set(A_HAVE_H ${CMAKE_CURRENT_BINARY_DIR}/a.cmake.h)
 228   configure_file(${CMAKE_CURRENT_LIST_DIR}/include/a.cmake.h.in ${A_HAVE_H})
 229 endif()
 230
 231 if(IS_ABSOLUTE "${LIBA_MATH}")
 232   get_filename_component(math ${LIBA_MATH} NAME_WE)
 233   string(REGEX REPLACE "^${CMAKE_STATIC_LIBRARY_PREFIX}(.+)" "\\1" math "${math}")
 234   set(LIBA_MATH $<BUILD_INTERFACE:${LIBA_MATH}> $<INSTALL_INTERFACE:${math}>)
 235   set(math)
 236 endif()
 237
 238 if(TARGET_SUPPORTS_SYMBOLIC_LINK)
 239   option(LIBA_SYMLINK "Enable/Disable symbolic link" 1)
 240 endif()
 241
 242 function(set_library_compile target)
 243   if(EXISTS "${A_HAVE_H}")
 244     file(RELATIVE_PATH a_have_h ${PROJECT_SOURCE_DIR}/include/a ${A_HAVE_H})
 245     target_compile_definitions(${target} PUBLIC $<BUILD_INTERFACE:A_HAVE_H="${a_have_h}">)
 246     set(a_have_h)
 247   endif()
 248
 249   if((LIBA_SYMLINK OR WIN32) AND TARGET_SUPPORTS_SYMBOLIC_LINK)
 250     set_target_properties(${target} PROPERTIES SOVERSION
 251       ${PROJECT_VERSION_MAJOR} VERSION ${PROJECT_VERSION}
 252     )
 253   endif()
 254
 255   set_target_properties(${target} PROPERTIES OUTPUT_NAME a
 256     POSITION_INDEPENDENT_CODE 1 DEFINE_SYMBOL A_EXPORTS
 257   )
 258   target_compile_definitions(${target} PRIVATE A_EXPORTS)
 259   target_include_directories(${target} BEFORE PUBLIC
 260     $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>
 261     $<INSTALL_INTERFACE:include>
 262   )
 263   get_property(TYPE TARGET ${target} PROPERTY TYPE)
 264
 265   if(${TYPE} MATCHES "(STATIC|SHARED|MODULE)_LIBRARY")
 266     target_link_libraries(${target} PUBLIC ${LIBA_MATH})
 267   endif()
 268
 269   set_library_options(${target})
 270 endfunction()
 271
 272 if(LIBA_CXX)
 273   file_scaner(SOURCES RECURSE include src EXT c h cc hh cpp hpp)
 274 else()
 275   file_scaner(SOURCES RECURSE include src EXT c h)
 276 endif()
 277
 278 add_library(a OBJECT ${SOURCES})
 279 set_library_compile(a)
 280
 281 if(LIBA_MIMALLOC AND mimalloc_FOUND)
 282   set_property(SOURCE ${CMAKE_CURRENT_LIST_DIR}/src/a.c
 283     APPEND PROPERTY COMPILE_DEFINITIONS A_HAVE_MIMALLOC_H
 284   )
 285
 286   if(CMAKE_VERSION VERSION_LESS 3.12)
 287     add_library_properties(a PUBLIC ${MIMALLOC_LIBRARY} INTERFACE_)
 288   else()
 289     target_link_libraries(a PUBLIC ${MIMALLOC_LIBRARY})
 290   endif()
 291 endif()
 292
 293 include(GNUInstallDirs)
 294 set(INSTALL_TARGETS "")
 295 set(LIBA_INSTALL "" CACHE STRING "Specify the installation")
 296
 297 if(NOT LIBA_INSTALL)
 298   list(APPEND INSTALL_TARGETS alib)
 299 endif()
 300
 301 add_library(alib STATIC $<TARGET_OBJECTS:a>)
 302 set_library_compile(alib)
 303
 304 if(LIBA_MIMALLOC AND mimalloc_FOUND)
 305   target_link_libraries(alib PUBLIC ${MIMALLOC_LIBRARY})
 306 endif()
 307
 308 if(TARGET_SUPPORTS_SHARED_LIBS)
 309   if(NOT LIBA_INSTALL)
 310     list(APPEND INSTALL_TARGETS liba)
 311   endif()
 312
 313   add_library(liba SHARED $<TARGET_OBJECTS:a>)
 314   set_library_compile(liba)
 315
 316   if(LIBA_MIMALLOC AND mimalloc_FOUND)
 317     target_link_libraries(liba PUBLIC ${MIMALLOC_LIBRARY})
 318   endif()
 319
 320   if(CMAKE_STATIC_LIBRARY_SUFFIX STREQUAL .lib)
 321     set_property(TARGET liba PROPERTY OUTPUT_NAME liba)
 322   endif()
 323
 324   target_compile_definitions(liba INTERFACE A_IMPORTS)
 325
 326   if(LIBA_STATIC)
 327     target_link_static(liba)
 328   endif()
 329 endif()
 330
 331 if(LIBA_SANITIZE)
 332   add_library(asan OBJECT ${SOURCES})
 333   set_library_compile(asan)
 334   target_compile_sanitize(asan)
 335
 336   if(LIBA_MIMALLOC AND mimalloc_FOUND)
 337     if(CMAKE_VERSION VERSION_LESS 3.12)
 338       add_library_properties(asan PUBLIC ${MIMALLOC_LIBRARY} INTERFACE_)
 339     else()
 340       target_link_libraries(asan PUBLIC ${MIMALLOC_LIBRARY})
 341     endif()
 342   endif()
 343
 344   if(TARGET_SUPPORTS_SHARED_LIBS)
 345     add_library(libasan SHARED $<TARGET_OBJECTS:asan>)
 346     set_library_compile(libasan)
 347
 348     set_property(TARGET libasan PROPERTY OUTPUT_NAME a.san)
 349     target_compile_definitions(libasan INTERFACE A_IMPORTS)
 350     target_link_sanitize(libasan)
 351
 352     if(LIBA_MIMALLOC AND mimalloc_FOUND)
 353       target_link_libraries(libasan PUBLIC ${MIMALLOC_LIBRARY})
 354     endif()
 355
 356     if(LIBA_STATIC)
 357       target_link_static(libasan)
 358     endif()
 359   endif()
 360 endif()
 361
 362 if(TARGET_SUPPORTS_RELOCATABLE)
 363   file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/lib/CMakeLists.txt "get_cmake_property(ENABLED_LANGUAGES ENABLED_LANGUAGES)
 364 foreach(LANG \${ENABLED_LANGUAGES})
 365 \tset(CMAKE_\${LANG}_CREATE_STATIC_LIBRARY \"\")
 366 \tset(CMAKE_\${LANG}_LINK_EXECUTABLE
 367 \t\t\"<CMAKE_\${LANG}_COMPILER> <FLAGS> -nostdlib -o <TARGET>.o -r <OBJECTS>\"
 368 \t\t\"\${CMAKE_COMMAND} -E copy <TARGET>.o <TARGET>\"
 369 \t)
 370 endforeach()
 371 set(CMAKE_EXECUTABLE_SUFFIX \"\")
 372 set(CMAKE_STATIC_LIBRARY_SUFFIX .o)
 373 set(CMAKE_STATIC_LIBRARY_PREFIX lib)
 374 add_executable(a.o \$<TARGET_OBJECTS:a>)
 375 add_library(liba.o STATIC \$<TARGET_OBJECTS:a>)
 376 set_library_compile(liba.o)\nadd_dependencies(liba.o a.o)
 377 set_target_properties(a.o PROPERTIES OUTPUT_NAME liba
 378 \tINTERPROCEDURAL_OPTIMIZATION \${LIBA_IPO}
 379 )
 380 if(LIBA_MIMALLOC AND mimalloc_FOUND)
 381 \ttarget_link_libraries(liba.o PUBLIC ${MIMALLOC_LIBRARY})
 382 endif()
 383 if(NOT LIBA_INSTALL)
 384 \tinstall(TARGETS liba.o EXPORT \${PROJECT_NAME}-targets
 385 \t\tARCHIVE DESTINATION \${CMAKE_INSTALL_LIBDIR}
 386 \t\tLIBRARY DESTINATION \${CMAKE_INSTALL_LIBDIR}
 387 \t)\nendif()")
 388   add_subdirectory(${CMAKE_CURRENT_BINARY_DIR}/lib lib)
 389 else()
 390   add_library(liba.o ALIAS alib)
 391 endif()
 392
 393 if(INSTALL_TARGETS)
 394   include(cmake/InstallTargets.cmake)
 395   install(DIRECTORY ${CMAKE_CURRENT_LIST_DIR}/include/a DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 396
 397   if(EXISTS "${A_HAVE_H}")
 398     install(FILES ${A_HAVE_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/a)
 399     install_fixup(${CMAKE_INSTALL_INCLUDEDIR}/a/a.h A_HAVE_H ${A_HAVE_H})
 400   endif()
 401 endif()
 402
 403 option(LIBA_PKGCONFIG "Enable/Disable pkgconfig" 0)
 404
 405 if(LIBA_PKGCONFIG)
 406   include(cmake/InstallPkgConfig.cmake)
 407   install_pkgconfig(${PROJECT_NAME} alib)
 408 endif()
 409
 410 option(LIBA_LIBTOOL "Enable/Disable libtool" 0)
 411
 412 if(LIBA_LIBTOOL AND INSTALL_TARGETS)
 413   include(cmake/InstallLibtool.cmake)
 414   install_libtool(${INSTALL_TARGETS})
 415 endif()
 416
 417 option(LIBA_VCPKG "Enable/Disable vcpkg" 0)
 418
 419 if(EXISTS ${CMAKE_CURRENT_LIST_DIR}/vcpkg AND LIBA_VCPKG AND GIT_COMMIT_LONG)
 420   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/vcpkg DESTINATION ${CMAKE_INSTALL_DATADIR})
 421   configure_file(
 422     ${CMAKE_CURRENT_SOURCE_DIR}/vcpkg/portfile.cmake
 423     ${CMAKE_CURRENT_BINARY_DIR}/vcpkg/ports/${PROJECT_NAME}/portfile.cmake
 424     @ONLY
 425   )
 426   configure_file(
 427     ${CMAKE_CURRENT_SOURCE_DIR}/vcpkg/vcpkg.json
 428     ${CMAKE_CURRENT_BINARY_DIR}/vcpkg/ports/${PROJECT_NAME}/vcpkg.json
 429     @ONLY
 430   )
 431 endif()
 432
 433 if(PROJECT_IS_TOP_LEVEL)
 434   add_custom_target(afmt)
 435   add_custom_target(adoc)
 436   include(CTest)
 437 endif()
 438
 439 if(NOT CMAKE_FIND_LIBRARY_PREFIXES)
 440   set(CMAKE_FIND_LIBRARY_PREFIXES ";lib")
 441 endif()
 442
 443 if(EXISTS ${CMAKE_CURRENT_LIST_DIR}/java/CMakeLists.txt)
 444   option(LIBA_JAVA "Enable/Disable java" 0)
 445
 446   if(LIBA_JAVA)
 447     find_package(Java)
 448     find_package(JNI)
 449   endif()
 450
 451   if(LIBA_JAVA AND Java_JAVAC_EXECUTABLE)
 452     add_subdirectory(java)
 453   endif()
 454 endif()
 455
 456 if(EXISTS ${CMAKE_CURRENT_LIST_DIR}/javascript/CMakeLists.txt)
 457   if(EMSCRIPTEN)
 458     option(LIBA_JAVASCRIPT "Enable/Disable javascript" 1)
 459   else()
 460     option(LIBA_JAVASCRIPT "Enable/Disable javascript" 0)
 461   endif()
 462
 463   if(LIBA_JAVASCRIPT)
 464     if(NOT EMSCRIPTEN)
 465       find_package(Emscripten)
 466     endif()
 467
 468     if(EMSCRIPTEN OR EMSCRIPTEN_FOUND)
 469       add_subdirectory(javascript)
 470     endif()
 471   endif()
 472 endif()
 473
 474 if(EXISTS ${CMAKE_CURRENT_LIST_DIR}/lua/CMakeLists.txt)
 475   option(LIBA_LUA "Enable/Disable lua" 0)
 476   option(LIBA_LUAJIT "Enable/Disable luajit" 0)
 477   option(LIBA_WITH_LUA "Enable/Disable build with lua" 0)
 478
 479   if(LIBA_LUA OR LIBA_LUAJIT OR LIBA_WITH_LUA)
 480     set(LUA_MATH_LIBRARY ${LIBA_MATH} CACHE STRING "lua math library")
 481   endif()
 482
 483   if(NOT LIBA_WITH_LUA AND LIBA_LUA)
 484     find_package(Lua OPTIONAL_COMPONENTS lua)
 485     set(LUA_LIBRARIES lualib)
 486   endif()
 487
 488   if((LIBA_LUA AND NOT LUA_FOUND AND NOT LIBA_WITH_LUA) OR LIBA_LUAJIT)
 489     find_package(LuaJIT OPTIONAL_COMPONENTS luajit)
 490     set(LUA_EXECUTABLE ${LUAJIT_EXECUTABLE})
 491     set(LUA_LIBRARIES luajit)
 492   endif()
 493
 494   if(LIBA_LUA AND LUA_FOUND)
 495     add_subdirectory(lua)
 496   elseif(LIBA_LUAJIT AND LUAJIT_FOUND)
 497     add_subdirectory(lua)
 498   elseif(LIBA_WITH_LUA)
 499     add_subdirectory(lua)
 500   endif()
 501 endif()
 502
 503 if(EXISTS ${CMAKE_CURRENT_LIST_DIR}/python/CMakeLists.txt)
 504   if(LIBA_PYTHON AND PYTHON_FOUND)
 505     add_subdirectory(python)
 506   endif()
 507 endif()
 508
 509 if(EXISTS ${CMAKE_CURRENT_LIST_DIR}/quickjs/CMakeLists.txt)
 510   option(LIBA_QUICKJS "Enable/Disable quickjs" 0)
 511
 512   if(LIBA_QUICKJS)
 513     find_package(QuickJS)
 514   endif()
 515
 516   if(LIBA_QUICKJS AND QUICKJS_FOUND)
 517     add_subdirectory(quickjs)
 518   endif()
 519 endif()
 520
 521 if(EXISTS ${CMAKE_CURRENT_LIST_DIR}/test/CMakeLists.txt)
 522   if(PROJECT_IS_TOP_LEVEL AND BUILD_TESTING)
 523     add_subdirectory(test)
 524   endif()
 525 endif()
 526
 527 set(CPACK_SOURCE_IGNORE_FILES
 528   ${CMAKE_CURRENT_LIST_DIR}/.git
 529   ${CMAKE_CURRENT_LIST_DIR}/.cache
 530   ${CMAKE_CURRENT_LIST_DIR}/.vscode
 531   ${CMAKE_CURRENT_LIST_DIR}/.github
 532   ${CMAKE_CURRENT_LIST_DIR}/.gitignore
 533   ${CMAKE_CURRENT_LIST_DIR}/.gitmodules
 534   ${CMAKE_CURRENT_LIST_DIR}/.gitattributes
 535   ${PROJECT_BINARY_DIR}
 536 )
 537 set(CPACK_RESOURCE_FILE_README ${CMAKE_CURRENT_LIST_DIR}/README.md)
 538 set(CPACK_RESOURCE_FILE_LICENSE ${CMAKE_CURRENT_LIST_DIR}/LICENSE.txt)
 539 include(CPack)
 540
 541 if(PROJECT_IS_TOP_LEVEL)
 542   find_package(ClangFormat)
 543 endif()
 544
 545 if(CLANG_FORMAT_FOUND)
 546   file_scaner(SOURCES RECURSE include src test java/src javascript/src lua/src quickjs/src EXT c h cc hh cpp hpp)
 547   add_clang_format(afmt.c VERBOSE ${SOURCES})
 548   add_dependencies(afmt afmt.c)
 549 endif()
 550
 551 if(PROJECT_IS_TOP_LEVEL AND LIBA_PYTHON)
 552   find_package(Black)
 553 endif()
 554
 555 if(PYTHON_FOUND AND BLACK_FOUND)
 556   add_black(afmt.py ${CMAKE_CURRENT_LIST_DIR})
 557   add_dependencies(afmt afmt.py)
 558 endif()
 559
 560 if(PYTHON_FOUND AND CYTHON_FOUND)
 561   set(OPTIONS)
 562
 563   if(NOT CMAKE_VERSION VERSION_LESS 3.2)
 564     file_scaner(SOURCES RECURSE python/src EXT c h cc hh cpp hpp)
 565     list(APPEND OPTIONS BYPRODUCTS ${SOURCES})
 566     file(GLOB PRODUCTS ${PROJECT_NAME}*.so ${PROJECT_NAME}*.pyd)
 567     list(APPEND OPTIONS ${PRODUCTS})
 568     file(GLOB_RECURSE PRODUCTS build/lib.*/*.* build/temp.*/*.*)
 569     list(APPEND OPTIONS ${PRODUCTS})
 570     set(PRODUCTS)
 571   endif()
 572
 573   add_custom_target(apy ALL # https://cython.readthedocs.io/en/stable
 574     ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_LIST_DIR}/setup.py ${OPTIONS}
 575   )
 576   set(OPTIONS)
 577 endif()
 578
 579 if(NOT CMAKE_VERSION VERSION_LESS 3.9 AND DOXYGEN_FOUND)
 580   # Project related configuration options
 581   set(DOXYGEN_CREATE_SUBDIRS YES)
 582   set(DOXYGEN_OPTIMIZE_OUTPUT_FOR_C YES)
 583
 584   # Build related configuration options
 585   set(DOXYGEN_EXTRACT_STATIC YES)
 586
 587   # Configuration options related to warning and progress messages
 588   set(DOXYGEN_WARN_IF_UNDOCUMENTED NO)
 589   set(DOXYGEN_WARN_NO_PARAMDOC YES)
 590
 591   # Configuration options related to the input files
 592   set(DOXYGEN_RECURSIVE YES)
 593
 594   # Configuration options related to source browsing
 595   # Configuration options related to the alphabetical class index
 596   # Configuration options related to the HTML output
 597   set(DOXYGEN_GENERATE_HTML YES)
 598   set(DOXYGEN_USE_MATHJAX YES)
 599   set(DOXYGEN_MATHJAX_VERSION MathJax_3)
 600
 601   # Configuration options related to the LaTeX output
 602   # Configuration options related to the RTF output
 603   # Configuration options related to the man page output
 604   # Configuration options related to the XML output
 605   set(DOXYGEN_GENERATE_XML YES)
 606
 607   # Configuration options related to the DOCBOOK output
 608   # Configuration options for the AutoGen Definitions output
 609   # Configuration options related to Sqlite3 output
 610   # Configuration options related to the Perl module output
 611   # Configuration options related to the preprocessor
 612   set(DOXYGEN_MACRO_EXPANSION YES)
 613   set(DOXYGEN_PREDEFINED
 614     "__STDC_VERSION__=201112L"
 615     "__cplusplus=201103L"
 616     "A_BYTE_ORDER=1234"
 617     "A_SIZE_POINTER=8"
 618     "A_INLINE:=inline"
 619     "A_EXTERN:="
 620     "A_INTERN:="
 621     "A_PUBLIC:="
 622     "A_HIDDEN:="
 623   )
 624
 625   file(STRINGS "${A_HAVE_H}" macros REGEX "#define[ ]+A_HAVE_.+")
 626
 627   foreach(macro ${macros})
 628     string(REGEX REPLACE "#define[ ]+(.*)[ ]+(.+)" "\\1=\\2" macro "${macro}")
 629     list(APPEND DOXYGEN_PREDEFINED ${macro})
 630   endforeach()
 631
 632   # Configuration options related to external references
 633   # Configuration options related to the dot tool
 634   if(Doxygen_dot_FOUND)
 635     set(DOXYGEN_HAVE_DOT YES)
 636     set(DOXYGEN_INTERACTIVE_SVG YES)
 637     set(DOXYGEN_DOT_IMAGE_FORMAT svg)
 638     set(DOXYGEN_DOT_MULTI_TARGETS YES)
 639   endif()
 640
 641   # https://www.doxygen.nl/manual/config.html
 642   doxygen_add_docs(adoc.c WORKING_DIRECTORY
 643     ${CMAKE_CURRENT_LIST_DIR}/include/a
 644     ${CMAKE_CURRENT_LIST_DIR}/include/a
 645     ${CMAKE_CURRENT_LIST_DIR}/README.md
 646   )
 647   add_dependencies(adoc adoc.c)
 648 endif()