meson.build

   1 project('liba', 'c', 'cpp',
   2         default_options: [
   3             'c_std=c11',
   4             'cpp_std=c++11',
   5             'b_ndebug=if-release',
   6             'default_library=both',
   7             'buildtype=debugoptimized',
   8         ],
   9         license: 'MPL-2.0',
  10         version: '0.1.7')
  11
  12 a_have_h = configuration_data()
  13 a_have_h.set('version', meson.version())
  14 a_have_h.set('A_VERSION', meson.project_version())
  15 a_have_h.set('A_VERSION_MAJOR', meson.project_version().split('.')[0])
  16 a_have_h.set('A_VERSION_MINOR', meson.project_version().split('.')[1])
  17 a_have_h.set('A_VERSION_PATCH', meson.project_version().split('.')[2])
  18 a_have_h.set('A_SIZE_FLOAT', get_option('float'))
  19 if target_machine.endian() == 'little'
  20     a_have_h.set('A_BYTE_ORDER', 1234)
  21 elif target_machine.endian() == 'big'
  22     a_have_h.set('A_BYTE_ORDER', 4321)
  23 endif
  24
  25 compiler = meson.get_compiler('c')
  26 a_have_h.set('A_SIZE_POINTER', compiler.sizeof('void *'))
  27
  28 math = ['expm1', 'log1p', 'hypot', 'atan2',
  29         'csqrt', 'cpow', 'cexp', 'clog',
  30         'csin', 'ccos', 'ctan',
  31         'csinh', 'ccosh', 'ctanh',
  32         'casin', 'cacos', 'catan',
  33         'casinh', 'cacosh', 'catanh']
  34
  35 foreach func: math
  36     float = get_option('float').to_int()
  37     have = 'A_HAVE_@0@'.format(func.to_upper())
  38     if  float == 4
  39         func = func + 'f'
  40     elif float > 8
  41         func = func + 'l'
  42     endif
  43     if compiler.has_function(func)
  44         a_have_h.set(have, '1')
  45     endif
  46 endforeach
  47
  48 sources = [
  49     'include/a/a.h',
  50     'include/a/avl.h',
  51     'include/a/buf.h',
  52     'include/a/complex.h',
  53     'include/a/crc.h',
  54     'include/a/fuzzy.h',
  55     'include/a/hpf.h',
  56     'include/a/list.h',
  57     'include/a/lpf.h',
  58     'include/a/math.h',
  59     'include/a/mf.h',
  60     'include/a/notefreqs.h',
  61     'include/a/operator.h',
  62     'include/a/pid.h',
  63     'include/a/pid_fuzzy.h',
  64     'include/a/pid_neuro.h',
  65     'include/a/poly.h',
  66     'include/a/que.h',
  67     'include/a/rbt.h',
  68     'include/a/slist.h',
  69     'include/a/str.h',
  70     'include/a/tf.h',
  71     'include/a/trajbell.h',
  72     'include/a/trajpoly3.h',
  73     'include/a/trajpoly5.h',
  74     'include/a/trajpoly7.h',
  75     'include/a/trajtrap.h',
  76     'include/a/utf.h',
  77     'include/a/vec.h',
  78     'include/a/version.h',
  79     'src/a.c',
  80     'src/avl.c',
  81     'src/buf.c',
  82     'src/complex.c',
  83     'src/crc.c',
  84     'src/fuzzy.c',
  85     'src/math.c',
  86     'src/mf.c',
  87     'src/pid.c',
  88     'src/pid_fuzzy.c',
  89     'src/pid_neuro.c',
  90     'src/poly.c',
  91     'src/que.c',
  92     'src/rbt.c',
  93     'src/str.c',
  94     'src/tf.c',
  95     'src/trajbell.c',
  96     'src/trajpoly3.c',
  97     'src/trajpoly5.c',
  98     'src/trajpoly7.c',
  99     'src/trajtrap.c',
 100     'src/utf.c',
 101     'src/vec.c',
 102     'src/version.c',
 103     'src/version.cc',
 104 ]
 105
 106 python = import('python').find_installation()
 107 fixup_py = join_paths(meson.current_source_dir(), 'meson', 'fixup.py')
 108 a_meson_h = join_paths(meson.current_build_dir(), 'a.meson.h')
 109 a_h = configure_file(output: 'a.h', input: 'include/a/a.h',
 110     command: [python, fixup_py, a_meson_h, '@INPUT@']
 111 )
 112
 113 configure_file(input: 'include/a.meson.h.in', output: 'a.meson.h', configuration: a_have_h)
 114 add_project_arguments('-DA_EXPORTS', '-DA_HAVE_H="a.meson.h"', language: ['c', 'cpp'])
 115 library('a', sources,
 116         dependencies: compiler.find_library('m', required: false),
 117         include_directories: include_directories('include'),
 118         soversion: meson.project_version().split('.')[0],
 119         version: meson.project_version(),
 120         link_args: get_option('math'),
 121         install: true)
 122
 123 install_headers(a_h, subdir: 'a')
 124 install_headers(a_meson_h, subdir: 'a')
 125 install_subdir('include/a', install_dir: get_option('includedir'))