meson.build

   1 project('liba', 'c', 'cpp',
   2         default_options: [
   3             'c_std=c11',
   4             'cpp_std=c++11',
   5             'b_ndebug=if-release',
   6             'buildtype=debugoptimized',
   7         ],
   8         license: 'MPL-2.0',
   9         version: '0.1.13')
  10
  11 a_have_h = configuration_data()
  12 a_have_h.set('version', meson.version())
  13 a_have_h.set('A_VERSION', meson.project_version())
  14 a_have_h.set('A_VERSION_MAJOR', meson.project_version().split('.')[0])
  15 a_have_h.set('A_VERSION_MINOR', meson.project_version().split('.')[1])
  16 a_have_h.set('A_VERSION_PATCH', meson.project_version().split('.')[2])
  17 a_have_h.set('A_SIZE_FLOAT', get_option('float'))
  18 if target_machine.endian() == 'little'
  19     a_have_h.set('A_BYTE_ORDER', 1234)
  20 elif target_machine.endian() == 'big'
  21     a_have_h.set('A_BYTE_ORDER', 4321)
  22 endif
  23
  24 compiler = meson.get_compiler('c')
  25 a_have_h.set('A_SIZE_POINTER', compiler.sizeof('void *'))
  26
  27 math = ['expm1', 'log1p', 'hypot', 'atan2',
  28         'csqrt', 'cpow', 'cexp', 'clog',
  29         'csin', 'ccos', 'ctan',
  30         'csinh', 'ccosh', 'ctanh',
  31         'casin', 'cacos', 'catan',
  32         'casinh', 'cacosh', 'catanh']
  33
  34 foreach func: math
  35     float = get_option('float').to_int()
  36     have = 'A_HAVE_' + func.to_upper()
  37     if  float == 4
  38         func = func + 'f'
  39     elif float > 8
  40         func = func + 'l'
  41     endif
  42     if compiler.has_function(func)
  43         a_have_h.set(have, '1')
  44     endif
  45 endforeach
  46
  47 configure_file(
  48     input: 'include/a.meson.h.in',
  49     output: 'a.meson.h',
  50     configuration: a_have_h,
  51 )
  52
  53 c_args = []
  54 sources = [
  55     'include/a/a.h',
  56     'include/a/avl.h',
  57     'include/a/buf.h',
  58     'include/a/complex.h',
  59     'include/a/crc.h',
  60     'include/a/fuzzy.h',
  61     'include/a/hpf.h',
  62     'include/a/list.h',
  63     'include/a/lpf.h',
  64     'include/a/math.h',
  65     'include/a/mf.h',
  66     'include/a/notefreqs.h',
  67     'include/a/pid.h',
  68     'include/a/pid_fuzzy.h',
  69     'include/a/pid_neuro.h',
  70     'include/a/poly.h',
  71     'include/a/que.h',
  72     'include/a/rbt.h',
  73     'include/a/slist.h',
  74     'include/a/str.h',
  75     'include/a/tf.h',
  76     'include/a/trajbell.h',
  77     'include/a/trajpoly3.h',
  78     'include/a/trajpoly5.h',
  79     'include/a/trajpoly7.h',
  80     'include/a/trajtrap.h',
  81     'include/a/utf.h',
  82     'include/a/vec.h',
  83     'include/a/version.h',
  84     'src/a.c',
  85     'src/avl.c',
  86     'src/buf.c',
  87     'src/complex.c',
  88     'src/crc.c',
  89     'src/fuzzy.c',
  90     'src/math.c',
  91     'src/mf.c',
  92     'src/pid.c',
  93     'src/pid_fuzzy.c',
  94     'src/pid_neuro.c',
  95     'src/poly.c',
  96     'src/que.c',
  97     'src/rbt.c',
  98     'src/str.c',
  99     'src/tf.c',
 100     'src/trajbell.c',
 101     'src/trajpoly3.c',
 102     'src/trajpoly5.c',
 103     'src/trajpoly7.c',
 104     'src/trajtrap.c',
 105     'src/utf.c',
 106     'src/vec.c',
 107     'src/version.c',
 108 ]
 109
 110 a_include = include_directories('include')
 111 a_meson_h = meson.current_build_dir() / 'a.meson.h'
 112 a_h = meson.current_source_dir() / 'include' / 'a' / 'a.h'
 113
 114 python = import('python').find_installation()
 115 res = run_command(python, '-c', '''import os, sys
 116 dir = os.path.dirname('@1@')
 117 src = os.path.basename('@0@')
 118 dst = os.path.basename('@1@')
 119 cur = "#if defined(A_HAVE_H)"
 120 new = '#include "' + dst + '"\n' + cur
 121 with open('@0@', "r") as f:
 122     txt = f.read()
 123 res = txt.replace(cur, new)
 124 if res != txt:
 125     new = os.path.join(dir, src)
 126     with open(new, "wb") as f:
 127         f.write(res.encode())
 128 dir = os.path.dirname('@0@')
 129 res = os.path.relpath('@1@', dir)
 130 sys.stdout.write(res.replace("\\", "/"))
 131 '''.format(a_h, a_meson_h), capture: true, check: true
 132 )
 133 if res.returncode() == 0
 134     c_args += ['-DA_EXPORTS', '-DA_HAVE_H="' + res.stdout() + '"']
 135 endif
 136
 137 a = both_libraries('a', sources, c_args: c_args, cpp_args: c_args,
 138     dependencies: compiler.find_library('m', required: false),
 139     implicit_include_directories: false,
 140     include_directories: a_include,
 141     install: true,
 142     link_args: get_option('math'),
 143     name_prefix: 'lib',
 144     pic: true,
 145     version: meson.project_version(),
 146 )
 147
 148 install_headers(a_meson_h, subdir: 'a')
 149 install_headers(meson.current_build_dir() / 'a.h', subdir: 'a')
 150 install_subdir('include/a', exclude_files: ['a.h'],
 151     install_dir: get_option('includedir'),
 152 )
 153
 154 if get_option('rust')
 155     rust_args = []
 156     add_languages('rust')
 157     if get_option('float').to_int() == 4
 158         rust_args += ['--cfg', 'feature="float"']
 159     endif
 160     static_library('liba', 'src/lib.rs',
 161         rust_args: rust_args,
 162         install: true,
 163         link_with: a.get_static_lib(),
 164     )
 165 endif
 166
 167 subdir('java')
 168 subdir('lua')
 169 subdir('python')
 170 subdir('quickjs')