meson.build

   1 project('liba', 'c', 'cpp',
   2         default_options: [
   3             'c_std=c11',
   4             'cpp_std=c++11',
   5             'b_ndebug=if-release',
   6             'buildtype=debugoptimized',
   7         ],
   8         license: 'MPL-2.0',
   9         version: '0.1.15')
  10
  11 a_have_h = configuration_data()
  12 a_have_h.set('version', meson.version())
  13 a_have_h.set('A_VERSION', meson.project_version())
  14 a_have_h.set('A_VERSION_MAJOR', meson.project_version().split('.')[0])
  15 a_have_h.set('A_VERSION_MINOR', meson.project_version().split('.')[1])
  16 a_have_h.set('A_VERSION_PATCH', meson.project_version().split('.')[2])
  17 a_have_h.set('A_SIZE_FLOAT', get_option('float'))
  18 if target_machine.endian() == 'little'
  19     a_have_h.set('A_BYTE_ORDER', 1234)
  20 elif target_machine.endian() == 'big'
  21     a_have_h.set('A_BYTE_ORDER', 4321)
  22 endif
  23
  24 compiler = meson.get_compiler('c')
  25 a_have_h.set('A_SIZE_POINTER', compiler.sizeof('void *'))
  26
  27 math = ['expm1', 'log1p', 'hypot', 'atan2',
  28         'csqrt', 'cpow', 'cexp', 'clog',
  29         'csin', 'ccos', 'ctan',
  30         'csinh', 'ccosh', 'ctanh',
  31         'casin', 'cacos', 'catan',
  32         'casinh', 'cacosh', 'catanh']
  33
  34 foreach func: math
  35     float = get_option('float').to_int()
  36     have = 'A_HAVE_' + func.to_upper()
  37     if  float == 4
  38         func = func + 'f'
  39     elif float > 8
  40         func = func + 'l'
  41     endif
  42     if compiler.has_function(func)
  43         a_have_h.set(have, '1')
  44     endif
  45 endforeach
  46
  47 configure_file(
  48     input: 'include/a.meson.h.in',
  49     output: 'a.meson.h',
  50     configuration: a_have_h,
  51 )
  52
  53 c_args = []
  54 sources = [
  55     'include/a/a.h',
  56     'include/a/avl.h',
  57     'include/a/buf.h',
  58     'include/a/complex.h',
  59     'include/a/crc.h',
  60     'include/a/fuzzy.h',
  61     'include/a/hash.h',
  62     'include/a/hpf.h',
  63     'include/a/list.h',
  64     'include/a/lpf.h',
  65     'include/a/math.h',
  66     'include/a/mf.h',
  67     'include/a/notefreqs.h',
  68     'include/a/pid.h',
  69     'include/a/pid_fuzzy.h',
  70     'include/a/pid_neuro.h',
  71     'include/a/poly.h',
  72     'include/a/que.h',
  73     'include/a/rbt.h',
  74     'include/a/regress.h',
  75     'include/a/regress_linear.h',
  76     'include/a/regress_simple.h',
  77     'include/a/slist.h',
  78     'include/a/str.h',
  79     'include/a/tf.h',
  80     'include/a/trajbell.h',
  81     'include/a/trajpoly3.h',
  82     'include/a/trajpoly5.h',
  83     'include/a/trajpoly7.h',
  84     'include/a/trajtrap.h',
  85     'include/a/utf.h',
  86     'include/a/vec.h',
  87     'include/a/version.h',
  88     'src/a.c',
  89     'src/avl.c',
  90     'src/buf.c',
  91     'src/complex.c',
  92     'src/crc.c',
  93     'src/fuzzy.c',
  94     'src/hash.c',
  95     'src/math.c',
  96     'src/mf.c',
  97     'src/pid.c',
  98     'src/pid_fuzzy.c',
  99     'src/pid_neuro.c',
 100     'src/poly.c',
 101     'src/que.c',
 102     'src/rbt.c',
 103     'src/regress.c',
 104     'src/regress_linear.c',
 105     'src/regress_simple.c',
 106     'src/str.c',
 107     'src/tf.c',
 108     'src/trajbell.c',
 109     'src/trajpoly3.c',
 110     'src/trajpoly5.c',
 111     'src/trajpoly7.c',
 112     'src/trajtrap.c',
 113     'src/utf.c',
 114     'src/vec.c',
 115     'src/version.c',
 116 ]
 117
 118 a_include = include_directories('include')
 119 a_meson_h = meson.current_build_dir() / 'a.meson.h'
 120 a_h = meson.current_source_dir() / 'include' / 'a' / 'a.h'
 121
 122 python = import('python').find_installation()
 123 res = run_command(python, '-c', '''import os, sys
 124 dir = os.path.dirname('@1@')
 125 src = os.path.basename('@0@')
 126 dst = os.path.basename('@1@')
 127 cur = "#if defined(A_HAVE_H)"
 128 new = '#include "' + dst + '"\n' + cur
 129 with open('@0@', "r") as f:
 130     txt = f.read()
 131 res = txt.replace(cur, new)
 132 if res != txt:
 133     new = os.path.join(dir, src)
 134     with open(new, "wb") as f:
 135         f.write(res.encode())
 136 dir = os.path.dirname('@0@')
 137 res = os.path.relpath('@1@', dir)
 138 sys.stdout.write(res.replace("\\", "/"))
 139 '''.format(a_h, a_meson_h), capture: true, check: true
 140 )
 141 if res.returncode() == 0
 142     c_args += ['-DA_EXPORTS', '-DA_HAVE_H="' + res.stdout() + '"']
 143 endif
 144
 145 a = both_libraries('a', sources, c_args: c_args, cpp_args: c_args,
 146     dependencies: compiler.find_library('m', required: false),
 147     implicit_include_directories: false,
 148     include_directories: a_include,
 149     install: true,
 150     link_args: get_option('math'),
 151     name_prefix: 'lib',
 152     pic: true,
 153     version: meson.project_version(),
 154 )
 155
 156 install_headers(a_meson_h, subdir: 'a')
 157 install_headers(meson.current_build_dir() / 'a.h', subdir: 'a')
 158 install_subdir('include/a', exclude_files: ['a.h'],
 159     install_dir: get_option('includedir'),
 160 )
 161
 162 if get_option('rust')
 163     rust_args = []
 164     add_languages('rust')
 165     if get_option('float').to_int() == 4
 166         rust_args += ['--cfg', 'feature="float"']
 167     endif
 168     static_library('liba', 'src/lib.rs',
 169         rust_args: rust_args,
 170         install: true,
 171         link_with: a.get_static_lib(),
 172     )
 173 endif
 174
 175 subdir('java')
 176 subdir('lua')
 177 subdir('python')
 178 subdir('quickjs')