djgpp/config.sed

   1 # Additional editing of Makefiles
   2 /ac_given_INSTALL=/,/^CEOF/ {
   3   /^CEOF$/ i\
   4 # DJGPP specific Makefile changes.\
   5   /^aliaspath * *=/s,:,";",g\
   6   /^lispdir *   *=/ c\\\\\
   7 lispdir = \\$(prefix)/gnu/emacs/site-lisp\
   8   /TEXINPUTS=/s,:,";",g\
   9   /PATH=/s,:,";",g\
  10   s,config\\.h\\.in,config.h-in,g\
  11   s,\\.tab\\.c,_tab.c,g\
  12   s,\\.tab\\.h,_tab.h,g\
  13   s,\\.old\\.,_old.,g\
  14   s,libcharset\\.h\\.in,libcharset.h-in,g\
  15   s,Makefile\\.in\\.in,Makefile.in-in,g\
  16   s,Makefile\\.am\\.in,Makefile.am-in,g\
  17   /^install-info-am:/,/^$/ s,file-\\[0-9\\]\\[0-9\\],& \\$\\$file[0-9] \\$\\$file[0-9][0-9],\
  18   /^\\.y\\.c:/,/^$/ {\
  19     /\\\$(YACC)/ {\
  20       s,[       ]*&&.*$,,\
  21       a\\\\\
  22         -mv -f y_tab.c \\$*.c\\\\\
  23         -@test -f y.tab.c && mv -f y.tab.c \\$*.c\\\\\
  24         -@test -f y.tab.h && mv -f y.tab.h y_tab.h\
  25     }\
  26   }
  27 }
  28
  29 # Rename config.h.in into config.h-in
  30 /^ *CONFIG_HEADERS=/,/^EOF/ {
  31   s|"lib/config\.h|&:lib/config.h-in|
  32   s|"config\.h|&:config.h-in|
  33 }
  34
  35 # Rename iconv.h.in into iconv.h-in
  36 /^ *CONFIG_FILES=/,/^EOF/ {
  37   s|include/iconv\.h|&:include/iconv.h-in|
  38 }
  39
  40 # Replace (command) > /dev/null with `command > /dev/null`, since
  41 # parenthesized commands always return zero status in the ported Bash,
  42 # even if the named command doesn't exist
  43 /if ([^|;]*null/{
  44   s,(,`,
  45   s,),,
  46   s,;  *then,`; then,
  47 }
  48
  49 # DOS-style absolute file names should be supported as well
  50 /\*) srcdir=/s,/\*,[\\\\/]* | [A-z]:[\\\\/]*,
  51 /\$]\*) INSTALL=/s,\[/\$\]\*,[\\\\/$]* | [A-z]:[\\\\/]*,
  52 /\$]\*) ac_rel_source=/s,\[/\$\]\*,[\\\\/$]* | [A-z]:[\\\\/]*,
  53
  54 # Switch the order of the two Sed commands, since DOS path names
  55 # could include a colon
  56 /ac_file_inputs=/s,\( -e "s%\^%\$ac_given_srcdir/%"\)\( -e "s%:% $ac_given_srcdir/%g"\),\2\1,
  57
  58 # Prevent the spliting of conftest.subs.
  59 # The sed script: conftest.subs is split into 48 or 90 lines long files.
  60 # This will produce sed scripts called conftest.s1, conftest.s2, etc.
  61 # that will not work if conftest.subs contains a multi line sed command
  62 # at line #90. In this case the first part of the sed command will be the
  63 # last line of conftest.s1 and the rest of the command will be the first lines
  64 # of conftest.s2. So both script will not work properly.
  65 # This matches the configure script produced by Autoconf 2.12
  66 /ac_max_sed_cmds=[0-9]/ s,=.*$,=`sed -n "$=" conftest.subs`,
  67 # This matches the configure script produced by Autoconf 2.14a
  68 /ac_max_sed_lines=[0-9]/ s,=.*$,=`sed -n "$=" $ac_cs_root.subs `,
  69
  70 # The following two items are changes needed for configuring
  71 # and compiling across partitions.
  72 # 1) The given srcdir value is always translated from the
  73 #    "x:" syntax into "/dev/x" syntax while we run configure.
  74 /^[     ]*-srcdir=\*.*$/ a\
  75     ac_optarg=`echo "$ac_optarg" | sed "s,^\\([A-Za-z]\\):,/dev/\\1,"`
  76 /set X `ls -Lt \$srcdir/ i\
  77    if `echo $srcdir | grep "^/dev/" - > /dev/null`; then\
  78      srcdir=`echo "$srcdir" | sed -e "s%^/dev/%%" -e "s%/%:/%"`\
  79    fi
  80
  81 #  2) We need links across partitions,
  82 #     so we will use "cp -pf" instead of "ln".
  83 /# Make a symlink if possible; otherwise try a hard link./,/EOF/ {
  84   s,;.*then, 2>/dev/null || cp -pf \$srcdir/\$ac_source \$ac_dest&,
  85 }