m4/jaylink.m4

   1 ##
   2 ## This file is part of the libjaylink project.
   3 ##
   4 ## Copyright (C) 2016 Marc Schink <jaylink-dev@marcschink.de>
   5 ##
   6 ## This program is free software: you can redistribute it and/or modify
   7 ## it under the terms of the GNU General Public License as published by
   8 ## the Free Software Foundation, either version 2 of the License, or
   9 ## (at your option) any later version.
  10 ##
  11 ## This program is distributed in the hope that it will be useful,
  12 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ## GNU General Public License for more details.
  15 ##
  16 ## You should have received a copy of the GNU General Public License
  17 ## along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18 ##
  19
  20 # serial 20161011
  21
  22 ## _JAYLINK_SET_PACKAGE_VERSION(prefix, version, major, minor, micro)
  23 ##
  24 m4_define([_JAYLINK_SET_PACKAGE_VERSION], [
  25         m4_assert([$# == 5])
  26
  27         # Get the Git repository description. Ensure that we use our Git
  28         # repository even when there is a parent Git repository.
  29         git_version=`git -C "$srcdir" --git-dir=.git describe --dirty 2> /dev/null`
  30
  31         # If available, use the Git description as package version. Otherwise,
  32         # use the version provided by Autoconf.
  33         AS_IF([test -n "$git_version"], [version="$git_version"],
  34                 [version="$2"])
  35
  36         AC_SUBST([$1_MAJOR], [$3])
  37         AC_SUBST([$1_MINOR], [$4])
  38         AC_SUBST([$1_MICRO], [$5])
  39         AC_SUBST([$1], [$version])
  40 ])
  41
  42 ## JAYLINK_SET_PACKAGE_VERSION(prefix, version)
  43 ##
  44 ## Parse the package version string of the format <major>.<minor>.<micro> and
  45 ## set the variables <prefix>_{MAJOR,MINOR,MICRO} to their corresponding
  46 ## values.
  47 ##
  48 ## Set the variable <prefix> to the package version string. If Git is
  49 ## available, append the short Git revision hash of the current commit to the
  50 ## version string if there is no release tag for the package version on it.
  51 ##
  52 AC_DEFUN([JAYLINK_SET_PACKAGE_VERSION], [
  53         m4_assert([$# == 2])
  54
  55         _JAYLINK_SET_PACKAGE_VERSION([$1], [$2],
  56                 m4_unquote(m4_split(m4_expand([$2]), [\.])))
  57 ])
  58
  59 ## _JAYLINK_SET_LIBRARY_VERSION(prefix, version, current, revision, age)
  60 ##
  61 m4_define([_JAYLINK_SET_LIBRARY_VERSION], [
  62         m4_assert([$# == 5])
  63
  64         AC_SUBST([$1_CURRENT], [$3])
  65         AC_SUBST([$1_REVISION], [$4])
  66         AC_SUBST([$1_AGE], [$5])
  67         AC_SUBST([$1], [$2])
  68 ])
  69
  70 ## JAYLINK_SET_LIBRARY_VERSION(prefix, version)
  71 ##
  72 ## Parse the library version string of the format <current>:<revision>:<age>
  73 ## and set the variables <prefix>_{CURRENT,REVISION,AGE} to their corresponding
  74 ## values.
  75 ##
  76 ## Set the variable <prefix> to the library version string.
  77 ##
  78 AC_DEFUN([JAYLINK_SET_LIBRARY_VERSION], [
  79         m4_assert([$# == 2])
  80
  81         _JAYLINK_SET_LIBRARY_VERSION([$1], [$2],
  82                 m4_unquote(m4_split([$2], [:])))
  83 ])