configure.ac

   1 # libmodbus package version number, (as distinct from shared library version)
   2 # An odd micro number indicates in-progress development from Git
   3 # An even micro number indicates a released version
   4 #
   5 # Making a point release:
   6 # - increase libmodbus_version_micro to the next even number
   7 #
   8 # After the release:
   9 # - increase libmodbus_version_minor to the next odd number
  10 #
  11 # Take care to update the libtool versioning when required (LIBMODBUS_LD_*).
  12 # http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
  13 #
  14 m4_define([libmodbus_version_major], [3])
  15 m4_define([libmodbus_version_minor], [1])
  16 m4_define([libmodbus_version_micro], [1])
  17
  18 m4_define([libmodbus_release_status],
  19     [m4_if(m4_eval(libmodbus_version_minor % 2), [1], [snapshot], [release])])
  20
  21 m4_define([libmodbus_version],
  22     [libmodbus_version_major.libmodbus_version_minor.libmodbus_version_micro])
  23
  24 AC_PREREQ([2.63])
  25 AC_INIT([libmodbus],
  26         [libmodbus_version],
  27         [https://github.com/stephane/libmodbus/issues],
  28         [libmodbus],
  29         [http://libmodbus.org/])
  30 AC_CONFIG_SRCDIR([src/modbus.c])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32 AM_INIT_AUTOMAKE([check-news foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects])
  33 AC_PROG_CC_STDC
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AM_SILENT_RULES([yes])
  38
  39 LIBMODBUS_VERSION_MAJOR=libmodbus_version_major
  40 LIBMODBUS_VERSION_MINOR=libmodbus_version_minor
  41 LIBMODBUS_VERSION_MICRO=libmodbus_version_micro
  42 LIBMODBUS_VERSION=libmodbus_version
  43 AC_SUBST(LIBMODBUS_VERSION_MAJOR)
  44 AC_SUBST(LIBMODBUS_VERSION_MINOR)
  45 AC_SUBST(LIBMODBUS_VERSION_MICRO)
  46 AC_SUBST(LIBMODBUS_VERSION)
  47
  48 # ABI version
  49 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  50 LIBMODBUS_LD_CURRENT=6
  51 LIBMODBUS_LD_REVISION=0
  52 LIBMODBUS_LD_AGE=1
  53 LIBMODBUS_LT_VERSION_INFO=$LIBMODBUS_LD_CURRENT:$LIBMODBUS_LD_REVISION:$LIBMODBUS_LD_AGE
  54 AC_SUBST(LIBMODBUS_LT_VERSION_INFO)
  55
  56 AC_CANONICAL_HOST
  57
  58 # OS check
  59 os_win32="false"
  60 os_qnx="false"
  61 case "${host_os}" in
  62       *mingw32*)
  63     os_win32="true"
  64   ;;
  65       *nto-qnx*)
  66     os_qnx="true"
  67   ;;
  68 esac
  69 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "true")
  70 AM_CONDITIONAL(OS_QNX, test "$os_qnx" = "true")
  71
  72 LT_INIT([disable-static win32-dll pic-only])
  73 AC_CHECK_HEADERS([ \
  74     arpa/inet.h \
  75     byteswap.h \
  76     errno.h \
  77     fcntl.h \
  78     limits.h \
  79     linux/serial.h \
  80     netdb.h \
  81     netinet/in.h \
  82     netinet/tcp.h \
  83     sys/ioctl.h \
  84     sys/socket.h \
  85     sys/time.h \
  86     sys/types.h \
  87     termios.h \
  88     time.h \
  89     unistd.h \
  90 ])
  91
  92 # Check whether to build docs / install man pages
  93 AC_LIBMODBUS_CHECK_DOC_BUILD
  94
  95 # Cygwin defines IPTOS_LOWDELAY but can't handle that flag so it's necessary to
  96 # workaround that problem and Cygwin doesn't define MSG_DONTWAIT.
  97 AC_CHECK_DECLS([__CYGWIN__])
  98
  99 # Checks for library functions.
 100 AC_FUNC_FORK
 101 AC_CHECK_FUNCS([accept4 getaddrinfo gettimeofday inet_ntoa memset select socket strerror strlcpy])
 102
 103 # Required for getaddrinfo (TCP PI - IPv6)
 104 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 105 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 106    LIBS="$LIBS -lws2_32"
 107    AC_SUBST(LIBS)
 108 fi
 109
 110 # Check for RS485 support (Linux kernel version 2.6.28+)
 111 AC_CHECK_DECLS([TIOCSRS485], [], [], [[#include <sys/ioctl.h>]])
 112 # Check for RTS flags
 113 AC_CHECK_DECLS([TIOCM_RTS], [], [], [[#include <sys/ioctl.h>]])
 114
 115 # Wtype-limits is not supported by gcc 4.2 (default on recent Mac OS X)
 116 my_CFLAGS="-Wall \
 117 -Wmissing-declarations -Wmissing-prototypes \
 118 -Wnested-externs -Wpointer-arith \
 119 -Wpointer-arith -Wsign-compare -Wchar-subscripts \
 120 -Wstrict-prototypes -Wshadow \
 121 -Wformat-security"
 122 AC_SUBST([my_CFLAGS])
 123
 124 AC_CONFIG_HEADERS([config.h tests/unit-test.h])
 125 AC_CONFIG_FILES([
 126         Makefile
 127         src/Makefile
 128         src/modbus-version.h
 129         src/win32/modbus.dll.manifest
 130         doc/Makefile
 131         tests/Makefile
 132         libmodbus.pc
 133         libmodbus.spec
 134 ])
 135
 136 AC_OUTPUT
 137 AC_MSG_RESULT([
 138         $PACKAGE $VERSION
 139         ===============
 140
 141         prefix:                 ${prefix}
 142         sysconfdir:             ${sysconfdir}
 143         libdir:                 ${libdir}
 144         includedir:             ${includedir}
 145
 146         compiler:               ${CC}
 147         cflags:                 ${CFLAGS}
 148         ldflags:                ${LDFLAGS}
 149 ])