configure.ac

   1 # libmodbus package version number, (as distinct from shared library version)
   2 # An odd micro number indicates in-progress development from Git
   3 # An even micro number indicates a released version
   4 #
   5 # Making a point release:
   6 # - increase libmodbus_version_micro to the next even number
   7 #
   8 # After the release:
   9 # - increase libmodbus_version_minor to the next odd number
  10 #
  11 # Take care to update the libtool versioning when required (LIBMODBUS_LD_*).
  12 # http://www.gnu.org/software/libtool/manual/html_node/Libtool-versioning.html
  13 #
  14 m4_define([libmodbus_version_major], [3])
  15 m4_define([libmodbus_version_minor], [1])
  16 m4_define([libmodbus_version_micro], [10])
  17
  18 m4_define([libmodbus_release_status],
  19     [m4_if(m4_eval(libmodbus_version_minor % 2), [1], [snapshot], [release])])
  20
  21 m4_define([libmodbus_version],
  22     [libmodbus_version_major.libmodbus_version_minor.libmodbus_version_micro])
  23
  24 AC_PREREQ([2.63])
  25 AC_INIT([libmodbus],
  26         [libmodbus_version],
  27         [https://github.com/stephane/libmodbus/issues],
  28         [libmodbus],
  29         [http://libmodbus.org/])
  30 AC_CONFIG_SRCDIR([src/modbus.c])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32 AM_INIT_AUTOMAKE([check-news foreign 1.11 silent-rules tar-pax subdir-objects])
  33 AC_PROG_CC
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_CONFIG_MACRO_DIR([m4])
  37 AM_SILENT_RULES([yes])
  38
  39 LIBMODBUS_VERSION_MAJOR=libmodbus_version_major
  40 LIBMODBUS_VERSION_MINOR=libmodbus_version_minor
  41 LIBMODBUS_VERSION_MICRO=libmodbus_version_micro
  42 LIBMODBUS_VERSION=libmodbus_version
  43 AC_SUBST(LIBMODBUS_VERSION_MAJOR)
  44 AC_SUBST(LIBMODBUS_VERSION_MINOR)
  45 AC_SUBST(LIBMODBUS_VERSION_MICRO)
  46 AC_SUBST(LIBMODBUS_VERSION)
  47
  48 # ABI version
  49 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  50 LIBMODBUS_LD_CURRENT=6
  51 LIBMODBUS_LD_REVISION=0
  52 LIBMODBUS_LD_AGE=1
  53 LIBMODBUS_LT_VERSION_INFO=$LIBMODBUS_LD_CURRENT:$LIBMODBUS_LD_REVISION:$LIBMODBUS_LD_AGE
  54 AC_SUBST(LIBMODBUS_LT_VERSION_INFO)
  55
  56 AC_CANONICAL_HOST
  57
  58 # OS check
  59 os_win32="false"
  60 os_cygwin="false"
  61 os_qnx="false"
  62 os_sunos="false"
  63 case "${host_os}" in
  64       *mingw32*)
  65     os_win32="true"
  66   ;;
  67       *nto-qnx*)
  68     os_qnx="true"
  69   ;;
  70       *cygwin*)
  71     os_cygwin="true"
  72   ;;
  73       *solaris*)
  74     os_sunos="true"
  75   ;;
  76 esac
  77 AM_CONDITIONAL(OS_WIN32, test "$os_win32" = "true")
  78 AM_CONDITIONAL(OS_QNX, test "$os_qnx" = "true")
  79
  80 m4_pattern_forbid([^LT_INIT])dnl
  81 LT_INIT([disable-static win32-dll pic-only])
  82
  83 AC_CHECK_HEADERS([ \
  84     arpa/inet.h \
  85     byteswap.h \
  86     errno.h \
  87     fcntl.h \
  88     limits.h \
  89     linux/serial.h \
  90     netdb.h \
  91     netinet/in.h \
  92     netinet/ip.h \
  93     netinet/tcp.h \
  94     sys/ioctl.h \
  95     sys/params.h \
  96     sys/socket.h \
  97     sys/time.h \
  98     sys/types.h \
  99     termios.h \
 100     time.h \
 101     unistd.h \
 102 ])
 103
 104 # Cygwin defines IPTOS_LOWDELAY but can't handle that flag so it's necessary to
 105 # workaround that problem and Cygwin doesn't define MSG_DONTWAIT.
 106 AC_CHECK_DECLS([__CYGWIN__])
 107
 108 # Check for network function in libnetwork for Haiku
 109 AC_SEARCH_LIBS(accept, network socket)
 110
 111 # Checks for library functions.
 112 AC_CHECK_FUNCS([accept4 gai_strerror getaddrinfo gettimeofday inet_pton inet_ntop select socket strerror strlcpy])
 113
 114 # Required for MinGW with GCC v4.8.1 on Win7
 115 AC_DEFINE(WINVER, 0x0501, _)
 116
 117 # Required for bswap
 118 AC_C_INLINE
 119
 120 # libtool
 121 AC_PROG_CXX
 122
 123 # Various types
 124 AC_TYPE_INT64_T
 125 AC_TYPE_SIZE_T
 126 AC_TYPE_SSIZE_T
 127 AC_TYPE_UINT16_T
 128 AC_TYPE_UINT32_T
 129 AC_TYPE_UINT8_T
 130
 131 if test "$os_cygwin" = "false"; then
 132     # Required for getaddrinfo (TCP IP - IPv6)
 133     AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 134     if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 135         LIBS="$LIBS -lws2_32"
 136     AC_SUBST(LIBS)
 137     fi
 138 fi
 139
 140 if test "$os_sunos" = "true"; then
 141     LIBS="$LIBS -lnsl -lsocket"
 142     AC_SUBST(LIBS)
 143 fi
 144
 145 # Check for RS485 support (Linux kernel version 2.6.28+)
 146 AC_CHECK_DECLS([TIOCSRS485], [], [], [[#include <sys/ioctl.h>]])
 147 # Check for RTS flags
 148 AC_CHECK_DECLS([TIOCM_RTS], [], [], [[#include <sys/ioctl.h>]])
 149
 150 WARNING_CFLAGS="-Wall \
 151 -Wmissing-declarations -Wmissing-prototypes \
 152 -Wnested-externs -Wpointer-arith \
 153 -Wsign-compare -Wchar-subscripts \
 154 -Wstrict-prototypes -Wshadow \
 155 -Wformat-security"
 156 AC_SUBST([WARNING_CFLAGS])
 157
 158 # Build options
 159 AC_ARG_ENABLE(tests,
 160         AS_HELP_STRING([--disable-tests],
 161         [Build tests (default: yes)]),,
 162         [enable_tests=yes])
 163 AM_CONDITIONAL(BUILD_TESTS, [test $enable_tests != no])
 164
 165 AC_CONFIG_HEADERS([config.h tests/unit-test.h])
 166 AC_CONFIG_FILES([
 167         Makefile
 168         src/Makefile
 169         src/modbus-version.h
 170         src/win32/modbus.dll.manifest
 171         tests/Makefile
 172         libmodbus.pc
 173 ])
 174
 175 AC_ARG_ENABLE([debug],
 176   [AS_HELP_STRING([--enable-debug],
 177     [Enable debug symbols (default is no)])],
 178   [enable_debug=$enableval],
 179   [enable_debug=no])
 180
 181 AS_IF([test "x$enable_debug" = "xyes"], [
 182   CFLAGS="-g -O0"
 183   CXXFLAGS="-g -O0"
 184 ], [
 185   CFLAGS="-O2"
 186   CXXFLAGS="-O2"
 187 ])
 188
 189 AC_OUTPUT
 190 AC_MSG_RESULT([
 191         $PACKAGE $VERSION
 192         ===============
 193
 194         prefix:                 ${prefix}
 195         sysconfdir:             ${sysconfdir}
 196         libdir:                 ${libdir}
 197         includedir:             ${includedir}
 198
 199         compiler:               ${CC}
 200         cflags:                 ${CFLAGS} ${WARNING_CFLAGS}
 201         ldflags:                ${LDFLAGS}
 202
 203         tests:                  ${enable_tests}
 204 ])