ground/gcs/copydata.pro

   1 include(gcs.pri)
   2
   3 TEMPLATE = aux
   4
   5 # Copy Qt runtime libraries into the build directory (to run or package)
   6 equals(copyqt, 1) {
   7     linux {
   8         QT_LIBS = libQt5Core.so.5 \
   9                   libQt5Gui.so.5 \
  10                   libQt5Widgets.so.5 \
  11                   libQt5Network.so.5 \
  12                   libQt5OpenGL.so.5 \
  13                   libQt5Sql.so.5 \
  14                   libQt5Svg.so.5 \
  15                   libQt5Test.so.5 \
  16                   libQt5Xml.so.5 \
  17                   libQt5Declarative.so.5 \
  18                   libQt5XmlPatterns.so.5 \
  19                   libQt5Script.so.5 \
  20                   libQt5Concurrent.so.5 \
  21                   libQt5PrintSupport.so.5 \
  22                   libQt5SerialPort.so.5 \
  23                   libQt5Multimedia.so.5 \
  24                   libQt5MultimediaWidgets.so.5 \
  25                   libQt5Quick.so.5 \
  26                   libQt5QuickWidgets.so.5 \
  27                   libQt5Qml.so.5 \
  28                   libQt5DBus.so.5 \
  29                   libQt5QuickParticles.so.5 \
  30                   libqgsttools_p.so.1 \
  31                   libicui18n.so.53 \
  32                   libicuuc.so.53 \
  33                   libicudata.so.53
  34         for(lib, QT_LIBS) {
  35             addCopyFileTarget($${lib},$$[QT_INSTALL_LIBS],$${GCS_QT_LIBRARY_PATH})
  36         }
  37
  38         QT_PLUGINS = iconengines/libqsvgicon.so \
  39                      imageformats/libqgif.so \
  40                      imageformats/libqico.so \
  41                      imageformats/libqjpeg.so \
  42                      imageformats/libqmng.so \
  43                      imageformats/libqsvg.so \
  44                      imageformats/libqtiff.so \
  45                      mediaservice/libgstaudiodecoder.so \
  46                      mediaservice/libgstmediaplayer.so \
  47                      platforms/libqxcb.so \
  48                      sqldrivers/libqsqlite.so
  49     }
  50
  51     win32 {
  52         # set debug suffix if needed
  53         CONFIG(debug, debug|release):DS = "d"
  54
  55         # copy Qt DLLs
  56         QT_DLLS = Qt5Core$${DS}.dll \
  57                   Qt5Gui$${DS}.dll \
  58                   Qt5Widgets$${DS}.dll \
  59                   Qt5Network$${DS}.dll \
  60                   Qt5OpenGL$${DS}.dll \
  61                   Qt5Sql$${DS}.dll \
  62                   Qt5Svg$${DS}.dll \
  63                   Qt5Test$${DS}.dll \
  64                   Qt5Xml$${DS}.dll \
  65                   Qt5Declarative$${DS}.dll \
  66                   Qt5XmlPatterns$${DS}.dll \
  67                   Qt5Script$${DS}.dll \
  68                   Qt5Concurrent$${DS}.dll \
  69                   Qt5PrintSupport$${DS}.dll \
  70                   Qt5SerialPort$${DS}.dll \
  71                   Qt5Multimedia$${DS}.dll \
  72                   Qt5MultimediaWidgets$${DS}.dll \
  73                   Qt5Quick$${DS}.dll \
  74                   Qt5QuickWidgets$${DS}.dll \
  75                   Qt5Qml$${DS}.dll \
  76                   icuin53.dll \
  77                   icudt53.dll \
  78                   icuuc53.dll
  79         # it is more robust to take the following DLLs from Qt rather than from MinGW
  80         QT_DLLS += libgcc_s_dw2-1.dll \
  81                    libstdc++-6.dll \
  82                    libwinpthread-1.dll
  83         for(dll, QT_DLLS) {
  84             addCopyFileTarget($${dll},$$[QT_INSTALL_BINS],$${GCS_APP_PATH})
  85         }
  86
  87         # copy OpenSSL DLLs
  88         OPENSSL_DLLS = \
  89             ssleay32.dll \
  90             libeay32.dll
  91         for(dll, OPENSSL_DLLS) {
  92             addCopyFileTarget($${dll},$${OPENSSL_DIR},$${GCS_APP_PATH})
  93         }
  94
  95         # copy OpenGL DLL
  96         OPENGL_DLLS = \
  97             opengl32_32/opengl32.dll
  98         for(dll, OPENGL_DLLS) {
  99             addCopyFileTarget($${dll},$${MESAWIN_DIR},$${GCS_APP_PATH})
 100         }
 101
 102         QT_PLUGINS = iconengines/qsvgicon$${DS}.dll \
 103                      imageformats/qgif$${DS}.dll \
 104                      imageformats/qico$${DS}.dll \
 105                      imageformats/qjpeg$${DS}.dll \
 106                      imageformats/qmng$${DS}.dll \
 107                      imageformats/qsvg$${DS}.dll \
 108                      imageformats/qtiff$${DS}.dll \
 109                      platforms/qwindows$${DS}.dll \
 110                      mediaservice/dsengine$${DS}.dll \
 111                      sqldrivers/qsqlite$${DS}.dll
 112     }
 113
 114     for(plugin, QT_PLUGINS) {
 115         addCopyFileTarget($${plugin},$$[QT_INSTALL_PLUGINS],$${GCS_QT_PLUGINS_PATH})
 116     }
 117
 118     # Copy QtQuick2 complete directories
 119     # Some of these directories have a lot of files
 120     # Easier to copy everything
 121     QT_QUICK2_DIRS = QtQuick/Controls \
 122                      QtQuick/Dialogs \
 123                      QtQuick/Layouts \
 124                      QtQuick/LocalStorage \
 125                      QtQuick/Particles.2 \
 126                      QtQuick/PrivateWidgets \
 127                      QtQuick/Window.2 \
 128                      QtQuick/XmlListModel \
 129                      QtQuick.2
 130     for(dir, QT_QUICK2_DIRS) {
 131         addCopyDirTarget($${dir},$$[QT_INSTALL_QML],$${GCS_QT_QML_PATH})
 132     }
 133 }