ground/gcs/gcs.pro

   1 #
   2 # Qmake project for the OpenPilot GCS.
   3 # Copyright (c) 2009-2013, The OpenPilot Team, http://www.openpilot.org
   4 #
   5
   6 cache()
   7
   8 # check Qt version
   9 QT_VERSION = $$[QT_VERSION]
  10 QT_VERSION = $$split(QT_VERSION, ".")
  11 QT_VER_MAJ = $$member(QT_VERSION, 0)
  12 QT_VER_MIN = $$member(QT_VERSION, 1)
  13
  14 lessThan(QT_VER_MAJ, 5) | lessThan(QT_VER_MIN, 2) {
  15    error(OpenPilot GCS requires Qt 5.2.0 or newer but Qt $$[QT_VERSION] was detected.)
  16 }
  17
  18 macx {
  19     # This ensures that code is compiled with the /usr/bin version of gcc instead
  20     # of the gcc in XCode.app/Context/Development
  21     QMAKE_CC = /usr/bin/gcc
  22     QMAKE_CXX = /usr/bin/g++
  23     QMAKE_LINK = /usr/bin/g++
  24     QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.6
  25 }
  26
  27 include(gcs.pri)
  28
  29 TEMPLATE  = subdirs
  30 CONFIG   += ordered
  31
  32 DEFINES += USE_PATHPLANNER
  33
  34 SUBDIRS = src copydata
  35
  36 copydata.file = copydata.pro