ground/ground.pro

   1 #
   2 # Top level Qt-Creator project file for OpenPilot GCS
   3 # Copyright (c) 2009-2013, The OpenPilot Team, http://www.openpilot.org
   4 #
   5 # This meta-project allows qt-creator users to open and configure a
   6 # single project and build all required software to produce the GCS.
   7 # This includes regenerating all uavobject-synthetic files.
   8 #
   9 # NOTE: to use this meta-project you MUST perform these steps once
  10 # for each source tree checkout:
  11 # - Open <top>/ground/ground.pro in qt-creator
  12 # - Select the "Projects" tab
  13 # - Under Build Settings/General heading activate "Shadow build"
  14 # - Set "Build directory" below to <top>/build
  15 # Here <top> = the full path to the base of your git source tree which
  16 # should contain "flight", "ground", etc.
  17 #
  18 # NOTE: only debug qt-creator builds are supported on Windows.
  19 #       Release builds may fail because it seems that qt-creator does not
  20 #       define QTMINGW variable used to copy MinGW DLLs in release builds.
  21 #
  22 # There is a minor problem with dependencies. qmake needs synthetic
  23 # files when it generates GCS Makefiles. But we do not have
  24 # uavobjgenerator built yet. So we use the following trick: at make
  25 # stage in uavobject-synthetics we rerun qmake for openpilotgcs.pro
  26 # and regenerate GCS Makefiles using just built synthetic files.
  27 # It takes some extra time but solves the dependency problem.
  28 #
  29 # Please note that this meta-project is only intended to be used by
  30 # qt-creator users. Top level Makefile handles all dependencies itself
  31 # and does not use ground.pro.
  32
  33 cache()
  34
  35 message("Make sure you have shadow build path set as noted in ground.pro. Build will fail otherwise")
  36
  37 TEMPLATE  = subdirs
  38
  39 SUBDIRS = \
  40         sub_openpilotgcs \
  41         sub_uavobject-synthetics \
  42         sub_uavobjgenerator
  43
  44 # uavobjgenerator
  45 sub_uavobjgenerator.subdir = uavobjgenerator
  46
  47 # uavobject-synthetics
  48 sub_uavobject-synthetics.subdir = uavobject-synthetics
  49 sub_uavobject-synthetics.depends = sub_uavobjgenerator
  50
  51 # openpilotgcs
  52 sub_openpilotgcs.subdir  = openpilotgcs
  53 sub_openpilotgcs.depends = sub_uavobject-synthetics