ground/gcs/opengl.pro

   1 # copy legacy OpenGL DLL
   2
   3 TEMPLATE = aux
   4
   5 include(gcs.pri)
   6
   7 MESAWIN_DIR = $$(MESAWIN_DIR)
   8 isEmpty(MESAWIN_DIR):MESAWIN_DIR = $${TOOLS_DIR}/mesawin
   9
  10 # opengl32.dll will be copied to ./bin/opengl32/ for the installer to use
  11 # the installer packages the dll and optionally allows to install it to ./bin/
  12 # this implies that the opengl32.dll will not be used in a dev environment,
  13 # unless it is copied to the ./bin/ ...
  14
  15 exists($${MESAWIN_DIR}) {
  16     contains(QT_ARCH, i386) {
  17         # take opengl32.dll from mesa (32 bit)
  18         OPENGL_DIR = $${MESAWIN_DIR}/opengl32_32
  19     }
  20     else {
  21         # take opengl32.dll from mesa (64 bit)
  22         OPENGL_DIR = $${MESAWIN_DIR}/opengl32_64
  23     }
  24 }
  25 else {
  26     # take opengl32.dll from mingw32/bin/
  27     # WARNING : doesn't currently work, GCS crashes at startup when using msys2 opengl32.dll
  28     warning("msys2 opengl32.dll breaks GCS, please install mesa with: make mesawin_install")
  29     # skip installing opengl32.dll, the package target will fail when creating the installer
  30     #OPENGL_DIR = $$[QT_INSTALL_BINS]
  31 }
  32
  33 OPENGL_DLLS = \
  34     opengl32.dll
  35
  36 exists($${OPENGL_DIR}):for(dll, OPENGL_DLLS) {
  37     addCopyFileTarget($${dll},$${OPENGL_DIR},$${GCS_APP_PATH}/opengl32)
  38 }