ground/gcs/copydata.pro

   1 include(gcs.pri)
   2
   3 TEMPLATE = aux
   4
   5 # Copy Qt runtime libraries into the build directory (to run or package)
   6
   7 linux {
   8     QT_LIBS = \
   9         libQt5Core.so.5 \
  10         libQt5Gui.so.5 \
  11         libQt5Widgets.so.5 \
  12         libQt5Network.so.5 \
  13         libQt5OpenGL.so.5 \
  14         libQt5Sql.so.5 \
  15         libQt5Svg.so.5 \
  16         libQt5Test.so.5 \
  17         libQt5Xml.so.5 \
  18         libQt5XmlPatterns.so.5 \
  19         libQt5Script.so.5 \
  20         libQt5Concurrent.so.5 \
  21         libQt5PrintSupport.so.5 \
  22         libQt5SerialPort.so.5 \
  23         libQt5Multimedia.so.5 \
  24         libQt5MultimediaWidgets.so.5 \
  25         libQt5Quick.so.5 \
  26         libQt5QuickWidgets.so.5 \
  27         libQt5Qml.so.5 \
  28         libQt5DBus.so.5 \
  29         libQt5QuickParticles.so.5 \
  30         libQt5XcbQpa.so.5 \
  31         libQt5X11Extras.so.5 \
  32         libicui18n.so.56 \
  33         libicuuc.so.56 \
  34         libicudata.so.56
  35
  36     contains(QT_ARCH, x86_64) {
  37         QT_LIBS += \
  38             libqgsttools_p.so.1
  39     }
  40
  41     for(lib, QT_LIBS) {
  42         addCopyFileTarget($${lib},$$[QT_INSTALL_LIBS],$${GCS_QT_LIBRARY_PATH})
  43     }
  44
  45     QT_PLUGINS = \
  46         iconengines/libqsvgicon.so \
  47         imageformats/libqgif.so \
  48         imageformats/libqico.so \
  49         imageformats/libqjpeg.so \
  50         imageformats/libqsvg.so \
  51         imageformats/libqtiff.so \
  52         platforms/libqxcb.so \
  53         xcbglintegrations/libqxcb-glx-integration.so \
  54         sqldrivers/libqsqlite.so
  55
  56     contains(QT_ARCH, x86_64) {
  57         QT_PLUGINS += \
  58             mediaservice/libgstaudiodecoder.so \
  59             mediaservice/libgstmediaplayer.so
  60     } else {
  61         QT_PLUGINS += \
  62             mediaservice/libqtmedia_audioengine.so
  63     }
  64 }
  65
  66 win32 {
  67     # set debug suffix if needed
  68     CONFIG(debug, debug|release):DS = "d"
  69
  70     # copy Qt DLLs
  71     QT_DLLS = \
  72         Qt5Core$${DS}.dll \
  73         Qt5Gui$${DS}.dll \
  74         Qt5Widgets$${DS}.dll \
  75         Qt5Network$${DS}.dll \
  76         Qt5OpenGL$${DS}.dll \
  77         Qt5Sql$${DS}.dll \
  78         Qt5Svg$${DS}.dll \
  79         Qt5Test$${DS}.dll \
  80         Qt5Xml$${DS}.dll \
  81         Qt5XmlPatterns$${DS}.dll \
  82         Qt5Script$${DS}.dll \
  83         Qt5Concurrent$${DS}.dll \
  84         Qt5PrintSupport$${DS}.dll \
  85         Qt5SerialPort$${DS}.dll \
  86         Qt5Multimedia$${DS}.dll \
  87         Qt5MultimediaWidgets$${DS}.dll \
  88         Qt5Quick$${DS}.dll \
  89         Qt5QuickWidgets$${DS}.dll \
  90         Qt5Qml$${DS}.dll
  91
  92     for(dll, QT_DLLS) {
  93         addCopyFileTarget($${dll},$$[QT_INSTALL_BINS],$${GCS_APP_PATH})
  94         addCopyDependenciesTarget($${dll},$$[QT_INSTALL_BINS],$${GCS_APP_PATH})
  95     }
  96
  97     # copy OpenSSL DLLs
  98     OPENSSL_DLLS = \
  99         ssleay32.dll \
 100         libeay32.dll
 101
 102     for(dll, OPENSSL_DLLS) {
 103         addCopyFileTarget($${dll},$$[QT_INSTALL_BINS],$${GCS_APP_PATH})
 104     }
 105
 106     QT_PLUGINS = \
 107         iconengines/qsvgicon$${DS}.dll \
 108         imageformats/qgif$${DS}.dll \
 109         imageformats/qico$${DS}.dll \
 110         imageformats/qjpeg$${DS}.dll \
 111         imageformats/qsvg$${DS}.dll \
 112         imageformats/qtiff$${DS}.dll \
 113         platforms/qwindows$${DS}.dll \
 114         mediaservice/dsengine$${DS}.dll \
 115         sqldrivers/qsqlite$${DS}.dll
 116 }
 117
 118 for(plugin, QT_PLUGINS) {
 119     addCopyFileTarget($${plugin},$$[QT_INSTALL_PLUGINS],$${GCS_QT_PLUGINS_PATH})
 120     win32:addCopyDependenciesTarget($${plugin},$$[QT_INSTALL_PLUGINS],$${GCS_APP_PATH})
 121 }
 122
 123 # Copy QtQuick2 complete directories
 124 # Some of these directories have a lot of files
 125 # Easier to copy everything
 126 QT_QUICK2_DIRS = \
 127     QtQuick/Controls \
 128     QtQuick/Dialogs \
 129     QtQuick/Layouts \
 130     QtQuick/LocalStorage \
 131     QtQuick/Particles.2 \
 132     QtQuick/PrivateWidgets \
 133     QtQuick/Window.2 \
 134     QtQuick/XmlListModel \
 135     QtQuick.2
 136
 137 for(dir, QT_QUICK2_DIRS) {
 138     addCopyDirTarget($${dir},$$[QT_INSTALL_QML],$${GCS_QT_QML_PATH})
 139 }