ground/openpilotgcs/src/openpilotgcsplugin.pri

   1 include(../openpilotgcs.pri)
   2
   3 isEmpty(PROVIDER) {
   4     PROVIDER = OpenPilot
   5 }
   6
   7 DESTDIR = $$GCS_PLUGIN_PATH/$$PROVIDER
   8 LIBS += -L$$DESTDIR
   9 INCLUDEPATH += $$GCS_SOURCE_TREE/src/plugins
  10 DEPENDPATH += $$GCS_SOURCE_TREE/src/plugins
  11
  12 QT += widgets
  13
  14 # copy the plugin spec
  15 isEmpty(TARGET) {
  16     error("qtcreatorplugin.pri: You must provide a TARGET")
  17 }
  18
  19 PLUGINSPECS = $${_PRO_FILE_PWD_}/$${TARGET}.pluginspec
  20 copy2build.input = PLUGINSPECS
  21 copy2build.output = $$DESTDIR/${QMAKE_FUNC_FILE_IN_stripSrcDir}
  22 isEmpty(vcproj):copy2build.variable_out = PRE_TARGETDEPS
  23 copy2build.commands = $$QMAKE_COPY ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
  24 copy2build.name = COPY ${QMAKE_FILE_IN}
  25 copy2build.CONFIG += no_link
  26 QMAKE_EXTRA_COMPILERS += copy2build
  27
  28 TARGET = $$qtLibraryName($$TARGET)
  29
  30 macx {
  31         QMAKE_LFLAGS_SONAME = -Wl,-install_name,@executable_path/../Plugins/$${PROVIDER}/
  32 } else:linux-* {
  33     #do the rpath by hand since it's not possible to use ORIGIN in QMAKE_RPATHDIR
  34     QMAKE_RPATHDIR = \$\$ORIGIN
  35     QMAKE_RPATHDIR += \$\$ORIGIN/..
  36     QMAKE_RPATHDIR += \$\$ORIGIN/../..
  37     GCS_PLUGIN_RPATH = $$join(QMAKE_RPATHDIR, ":")
  38     QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,$${GCS_PLUGIN_RPATH}\'
  39     QMAKE_RPATHDIR =
  40 }
  41
  42
  43 contains(QT_CONFIG, reduce_exports):CONFIG += hGCS_symbols
  44
  45 CONFIG += plugin plugin_with_soname
  46
  47 !macx {
  48     target.path = /$$GCS_LIBRARY_BASENAME/openpilotgcs/plugins/$$PROVIDER
  49     pluginspec.files += $${TARGET}.pluginspec
  50     pluginspec.path = /$$GCS_LIBRARY_BASENAME/openpilotgcs/plugins/$$PROVIDER
  51     INSTALLS += target pluginspec
  52 }