flight/pios/stm32f4xx/link_STM32F4xx_RP_sections.ld

   1
   2 /* Section Definitions */
   3 SECTIONS
   4 {
   5         /*
   6          * Vectors, code and constant data.
   7          */
   8     .text :
   9     {
  10         PROVIDE (pios_isr_vector_table_base = .);
  11         KEEP(*(.cpu_vectors))   /* CPU exception vectors */
  12         KEEP(*(.io_vectors))    /* I/O interrupt vectors */
  13         *(.text .text.* .gnu.linkonce.t.*)
  14         *(.glue_7t) *(.glue_7)
  15         *(.rodata .rodata* .gnu.linkonce.r.*)
  16     } > FLASH
  17
  18     /*
  19      * Init section for UAVObjects.
  20      */
  21     .initcalluavobj.init :
  22     {
  23         . = ALIGN(4);
  24                 __uavobj_initcall_start = .;
  25         KEEP(*(.initcalluavobj.init))
  26                 . = ALIGN(4);
  27                 __uavobj_initcall_end   = .;
  28     } >FLASH
  29
  30     /*
  31      * Module init section section
  32      */
  33     .initcallmodule.init :
  34     {
  35         . = ALIGN(4);
  36                 __module_initcall_start = .;
  37         KEEP(*(.initcallmodule.init))
  38                 . = ALIGN(4);
  39                 __module_initcall_end   = .;
  40     } >FLASH
  41
  42         /*
  43          * C++ exception handling.
  44          */
  45     .ARM.extab :
  46     {
  47         *(.ARM.extab* .gnu.linkonce.armextab.*)
  48     } > FLASH
  49     .ARM.exidx :
  50     {
  51         __exidx_start = .;
  52         *(.ARM.exidx* .gnu.linkonce.armexidx.*)
  53         __exidx_end = .;
  54     } > FLASH
  55
  56         /*
  57          * Markers for the end of the 'text' section and the in-flash start of
  58          * non-constant data
  59          */
  60     . = ALIGN(4);
  61     _etext = .;
  62     _sidata = .;
  63
  64         /*
  65          * Board info structure, normally only generated by the bootloader but can
  66          * be read by the application.
  67          */
  68         PROVIDE(pios_board_info_blob = ORIGIN(BD_INFO));
  69     .boardinfo :
  70     {
  71                 . = ALIGN(4);
  72                 KEEP(*(.boardinfo))
  73                 . = ALIGN(ORIGIN(BD_INFO)+LENGTH(BD_INFO));
  74         } > BD_INFO
  75
  76     /*
  77          * Place the IRQ/bootstrap stack at the bottom of SRAM so that an overflow
  78          * results in a hard fault.
  79          */
  80         .istack (NOLOAD) :
  81         {
  82                 . = ALIGN(4);
  83         _irq_stack_end = . ;
  84         *(.irqstack)
  85         _irq_stack_top = . ;
  86         } > CCSRAM
  87
  88
  89         /*
  90          * Non-const initialised data.
  91          */
  92     .data : AT (_sidata)
  93     {
  94         . = ALIGN(4);
  95         _sdata = .;
  96         *(.data .data.*)
  97         . = ALIGN(4);
  98         _edata = . ;
  99     } > SRAM
 100
 101     /*
 102      * Uninitialised data (BSS + commons).
 103      */
 104     .bss (NOLOAD) :
 105     {
 106         _sbss = . ;
 107         *(.bss .bss.*)
 108         *(COMMON)
 109         _ebss = . ;
 110             PROVIDE ( _end = _ebss ) ;
 111     } > SRAM
 112
 113         /*
 114          * The heap consumes the remainder of the SRAM.
 115          */
 116     .heap (NOLOAD) :
 117     {
 118         . = ALIGN(4);
 119         _sheap = . ;
 120
 121         /*
 122          * This allows us to declare an object or objects up to the minimum acceptable
 123          * heap size and receive a linker error if the space available for the heap is
 124          * not sufficient.
 125          */
 126         *(.heap)
 127
 128         /* extend the heap up to the top of SRAM */
 129         . = ORIGIN(SRAM) + LENGTH(SRAM) - ABSOLUTE(_sheap);
 130         _eheap = .;
 131     } > SRAM
 132
 133         /*
 134          * 'Fast' memory goes in the CCM SRAM
 135          */
 136         .fast (NOLOAD) :
 137         {
 138                 _sfast = . ;
 139                 *(.fast)
 140                 _efast = . ;
 141         } > CCSRAM
 142
 143         .fastheap (NOLOAD) :
 144     {
 145         . = ALIGN(4);
 146         _sfastheap = . ;
 147
 148         /*
 149          * This allows us to declare an object or objects up to the minimum acceptable
 150          * heap size and receive a linker error if the space available for the heap is
 151          * not sufficient.
 152          */
 153         *(.fastheap)
 154
 155         /* extend the fastheap up to the top of CCSRAM */
 156         . = ORIGIN(CCSRAM) + LENGTH(CCSRAM) - ABSOLUTE(_sfastheap);
 157         _efastheap = .;
 158     } > CCSRAM
 159
 160     /* Stabs debugging sections.  */
 161     .stab          0 : { *(.stab) }
 162     .stabstr       0 : { *(.stabstr) }
 163     .stab.excl     0 : { *(.stab.excl) }
 164     .stab.exclstr  0 : { *(.stab.exclstr) }
 165     .stab.index    0 : { *(.stab.index) }
 166     .stab.indexstr 0 : { *(.stab.indexstr) }
 167     .comment       0 : { *(.comment) }
 168     /* DWARF debug sections.
 169        Symbols in the DWARF debugging sections are relative to the beginning
 170        of the section so we begin them at 0.  */
 171     /* DWARF 1 */
 172     .debug          0 : { *(.debug) }
 173     .line           0 : { *(.line) }
 174     /* GNU DWARF 1 extensions */
 175     .debug_srcinfo  0 : { *(.debug_srcinfo) }
 176     .debug_sfnames  0 : { *(.debug_sfnames) }
 177     /* DWARF 1.1 and DWARF 2 */
 178     .debug_aranges  0 : { *(.debug_aranges) }
 179     .debug_pubnames 0 : { *(.debug_pubnames) }
 180     /* DWARF 2 */
 181     .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
 182     .debug_abbrev   0 : { *(.debug_abbrev) }
 183     .debug_line     0 : { *(.debug_line) }
 184     .debug_frame    0 : { *(.debug_frame) }
 185     .debug_str      0 : { *(.debug_str) }
 186     .debug_loc      0 : { *(.debug_loc) }
 187     .debug_macinfo  0 : { *(.debug_macinfo) }
 188     /* SGI/MIPS DWARF 2 extensions */
 189     .debug_weaknames 0 : { *(.debug_weaknames) }
 190     .debug_funcnames 0 : { *(.debug_funcnames) }
 191     .debug_typenames 0 : { *(.debug_typenames) }
 192     .debug_varnames  0 : { *(.debug_varnames) }
 193 }