ground/gcs/src/libs/gstreamer/copydata.pro

   1 win32:gstreamer {
   2
   3     GST_BIN_DIR = $$system(pkg-config --variable=exec_prefix gstreamer-1.0)/bin
   4     GST_PLUGINS_DIR = $$system(pkg-config --variable=pluginsdir gstreamer-1.0)
   5
   6     # gstreamer libraries
   7     GST_LIBS = \
   8         libgstreamer-1.0-0.dll
   9
  10     gstreamer_utilities:GST_LIBS += \
  11         gst-inspect-1.0.exe \
  12         gst-launch-1.0.exe
  13
  14     for(lib, GST_LIBS) {
  15         addCopyFileTarget($${lib},$${GST_BIN_DIR},$${GCS_APP_PATH})
  16         addCopyDependenciesTarget($${lib},$${GST_BIN_DIR},$${GCS_APP_PATH})
  17     }
  18
  19     # gstreamer core
  20     GST_PLUGINS = \
  21         libgstcoreelements.dll
  22
  23     # gst-plugins-base
  24     GST_PLUGINS += \
  25         libgstapp.dll \
  26         libgstaudiotestsrc.dll \
  27         libgstpango.dll \
  28         libgstplayback.dll \
  29         libgsttcp.dll \
  30         libgsttypefindfunctions.dll \
  31         libgstvideoconvert.dll \
  32         libgstvideorate.dll \
  33         libgstvideoscale.dll \
  34         libgstvideotestsrc.dll
  35
  36     # gst-plugins-good
  37     GST_PLUGINS += \
  38         libgstautodetect.dll \
  39         libgstavi.dll \
  40         libgstdeinterlace.dll \
  41         libgstdirectsound.dll \
  42         libgstimagefreeze.dll \
  43         libgstjpeg.dll \
  44         libgstrawparse.dll \
  45         libgstrtp.dll \
  46         libgstrtpmanager.dll \
  47         libgstrtsp.dll \
  48         libgstudp.dll \
  49         libgstvideomixer.dll
  50
  51     # gst-plugins-bad
  52     GST_PLUGINS += \
  53         libgstaudiovisualizers.dll \
  54         libgstautoconvert.dll \
  55         libgstcompositor.dll \
  56         libgstd3d.dll \
  57         libgstdebugutilsbad.dll \
  58         libgstdirectsoundsrc.dll \
  59         libgstopengl.dll \
  60         libgstinter.dll \
  61         libgstmpegpsdemux.dll \
  62         libgstmpegpsmux.dll \
  63         libgstmpegtsdemux.dll \
  64         libgstmpegtsmux.dll \
  65         libgstvideoparsersbad.dll \
  66         libgstwinks.dll \
  67         libgstwinscreencap.dll
  68
  69     # gst-plugins-ugly
  70     GST_PLUGINS += \
  71         libgstmpeg2dec.dll \
  72         libgstx264.dll
  73
  74     # gst-libav
  75     GST_PLUGINS += \
  76         libgstlibav.dll
  77
  78     for(lib, GST_PLUGINS) {
  79         addCopyFileTarget($${lib},$${GST_PLUGINS_DIR},$${GCS_LIBRARY_PATH}/gstreamer-1.0)
  80         addCopyDependenciesTarget($${lib},$${GST_PLUGINS_DIR},$${GCS_APP_PATH})
  81     }
  82
  83 }