ground/gcs/src/plugins/ophid/ophid.pro

   1 TEMPLATE = lib
   2 TARGET = opHID
   3
   4 QT += widgets
   5
   6 DEFINES += OPHID_LIBRARY
   7
   8 //DEFINES += OPHID_DEBUG_ON
   9
  10 include(../../plugin.pri)
  11 include(ophid_dependencies.pri)
  12
  13 HEADERS += \
  14     inc/ophid_global.h \
  15     inc/ophid_plugin.h \
  16     inc/ophid.h \
  17     inc/ophid_hidapi.h \
  18     inc/ophid_const.h \
  19     inc/ophid_usbmon.h \
  20     inc/ophid_usbsignal.h \
  21     hidapi/hidapi.h
  22
  23 SOURCES += \
  24     src/ophid_plugin.cpp \
  25     src/ophid.cpp \
  26     src/ophid_usbsignal.cpp \
  27     src/ophid_hidapi.cpp
  28
  29 FORMS +=
  30
  31 RESOURCES +=
  32
  33 OTHER_FILES += opHID.pluginspec
  34
  35 INCLUDEPATH += ./inc
  36
  37 # Platform Specific
  38
  39 win32 {
  40     SOURCES += \
  41         src/ophid_usbmon_win.cpp \
  42         hidapi/windows/hid.c
  43
  44     LIBS += -lhid -lsetupapi
  45 }
  46
  47 macx {
  48     SOURCES += \
  49         src/ophid_usbmon_mac.cpp \
  50         hidapi/mac/hid.c
  51
  52     LIBS += -framework CoreFoundation -framework IOKit
  53
  54     # hid.c has too many warnings about unused paramters.
  55     QMAKE_CXXFLAGS_WARN_ON += -Wno-unused-parameter
  56     QMAKE_CFLAGS_WARN_ON   += -Wno-unused-parameter
  57 }
  58
  59 linux {
  60     SOURCES += \
  61         src/ophid_usbmon_linux.cpp
  62
  63     LIBS += -ludev -lrt -lpthread
  64
  65     # hidapi library
  66     ## rawhid
  67     #SOURCES += hidapi/linux/hid.c
  68     ## libusb
  69     SOURCES += hidapi/libusb/hid.c
  70
  71     CONFIG += link_pkgconfig
  72     PKGCONFIG += libusb-1.0
  73
  74     !exists(/usr/include/libusb-1.0) {
  75         error(Install libusb-1.0-0-dev using your package manager.)
  76     }
  77 }