ground/gcs/src/plugins/uavobjects/uavobjgenerator.pri

   1 UAVOBJ_INIT_CPP = uavobjectsinit.cpp
   2 UAVOBJ_INIT_CPP_TEMPLATE = $${UAVOBJ_INIT_CPP}.template
   3
   4 uavobjgenerator.input = UAVOBJS
   5 uavobjgenerator.commands = $$shell_path($${UAVOBJGENERATOR}) -gcs $${UAVOBJ_XML_DIR} $${UAVOBJ_ROOT_DIR} ${QMAKE_FILE_BASE}
   6 silent:uavobjgenerator.commands = @echo uavobjgenerator -gcs && $${uavobjgenerator.commands}
   7 uavobjgenerator_header.depends = $${UAVOBJ_INIT_CPP_TEMPLATE}
   8 uavobjgenerator.output = $${UAVOBJ_INIT_CPP}
   9 uavobjgenerator.variable_out = SOURCES
  10 uavobjgenerator.CONFIG += combine
  11
  12 QMAKE_EXTRA_COMPILERS += uavobjgenerator
  13
  14 uavobjgenerator_header.input = UAVOBJS
  15 # We don't want any commands here because uavobjgenerator also creates .cpp, but if command is empty no rules are created
  16 uavobjgenerator_header.commands = $$escape_expand(\\n)
  17 uavobjgenerator_header.depends = $${UAVOBJ_INIT_CPP}
  18 uavobjgenerator_header.output = ${QMAKE_FILE_BASE}.h # Actually generated by uavobjgenerator for this depends
  19 uavobjgenerator_header.variable_out = UAVOBJS_HEADERS
  20
  21 QMAKE_EXTRA_COMPILERS += uavobjgenerator_header
  22
  23 uavobjgenerator_source.input = UAVOBJS
  24 # We don't want any commands here because uavobjgenerator also creates .cpp, but if command is empty no rules are created
  25 uavobjgenerator_source.commands = $$escape_expand(\\n)
  26 uavobjgenerator_source.depends = $${UAVOBJ_INIT_CPP}
  27 uavobjgenerator_source.output = ${QMAKE_FILE_BASE}.cpp # Actually generated by uavobjgenerator for this depends
  28 uavobjgenerator_source.variable_out = SOURCES
  29
  30 QMAKE_EXTRA_COMPILERS += uavobjgenerator_source
  31
  32 # Do our own moc without moc_verify because the files aren't generated when verified
  33 load(moc)
  34 uavobjgenerator_moc.commands = $$moc_header.commands
  35 uavobjgenerator_moc.output = $$moc_header.output
  36 uavobjgenerator_moc.input = UAVOBJS_HEADERS
  37 uavobjgenerator_moc.variable_out = GENERATED_SOURCES
  38
  39 QMAKE_EXTRA_COMPILERS += uavobjgenerator_moc