ground/gcs/src/plugins/uploader/uploader.pro

   1 TEMPLATE = lib
   2 TARGET = Uploader
   3
   4 DEFINES += UPLOADER_LIBRARY
   5
   6 QT += svg serialport
   7
   8 include(uploader_dependencies.pri)
   9 include(../../libs/version_info/version_info.pri)
  10
  11 macx {
  12     QMAKE_CXXFLAGS  += -fpermissive
  13 }
  14
  15 !macx {
  16     QMAKE_CXXFLAGS += -Wno-enum-compare
  17 }
  18
  19 HEADERS += \
  20     uploadergadget.h \
  21     uploadergadgetconfiguration.h \
  22     uploadergadgetfactory.h \
  23     uploadergadgetoptionspage.h \
  24     uploadergadgetwidget.h \
  25     uploaderplugin.h \
  26     dfu.h \
  27     devicewidget.h \
  28     SSP/port.h \
  29     SSP/qssp.h \
  30     SSP/qsspt.h \
  31     SSP/common.h \
  32     runningdevicewidget.h \
  33     uploader_global.h \
  34     enums.h \
  35     rebootdialog.h
  36
  37 SOURCES += \
  38     uploadergadget.cpp \
  39     uploadergadgetconfiguration.cpp \
  40     uploadergadgetfactory.cpp \
  41     uploadergadgetoptionspage.cpp \
  42     uploadergadgetwidget.cpp \
  43     uploaderplugin.cpp \
  44     dfu.cpp \
  45     devicewidget.cpp \
  46     SSP/port.cpp \
  47     SSP/qssp.cpp \
  48     SSP/qsspt.cpp \
  49     runningdevicewidget.cpp \
  50     rebootdialog.cpp
  51
  52 OTHER_FILES += Uploader.pluginspec
  53
  54 FORMS += \
  55     uploader.ui \
  56     devicewidget.ui \
  57     runningdevicewidget.ui \
  58     rebootdialog.ui
  59
  60 RESOURCES += uploader.qrc
  61
  62 # TODO should use GCS_SYNTH_DIR... but that will break QtCreator
  63 exists( ../../../../../build/gcs-synthetics/fw_resource.qrc ) {
  64     RESOURCES += ../../../../../build/gcs-synthetics/fw_resource.qrc
  65 } else {
  66     message("fw_resource.qrc is not available, automatic firmware upgrades are disabled")
  67 }