ground/gcs/src/app/app.pro

   1 include(../../gcs.pri)
   2 include(../shared/qtsingleapplication/qtsingleapplication.pri)
   3
   4 TEMPLATE = app
   5 TARGET = $$GCS_APP_TARGET
   6 macx {
   7     # .app is 3 levels above the executable
   8     DESTDIR = $$GCS_APP_PATH/../../..
   9 } else {
  10     DESTDIR = $$GCS_APP_PATH
  11 }
  12
  13 QT += xml widgets
  14
  15 SOURCES += main.cpp \
  16     gcssplashscreen.cpp
  17
  18 include(../libs/utils/utils.pri)
  19 include(../libs/version_info/version_info.pri)
  20
  21 LIBS *= -l$$qtLibraryName(ExtensionSystem) -l$$qtLibraryName(Aggregation)
  22
  23 DEFINES += PLUGIN_REL_PATH=$$shell_quote(\"$$relative_path($$GCS_PLUGIN_PATH, $$GCS_APP_PATH)\")
  24
  25 win32 {
  26     RC_FILE = gcs.rc
  27     target.path = /bin
  28     INSTALLS += target
  29 } else:macx {
  30     LIBS += -framework CoreFoundation
  31     ICON = gcs.icns
  32     QMAKE_INFO_PLIST = Info.plist
  33     FILETYPES.files = profile.icns prifile.icns
  34     FILETYPES.path = Contents/Resources
  35     QMAKE_BUNDLE_DATA += FILETYPES
  36     QMAKE_LFLAGS_SONAME = -Wl,-install_name,@executable_path/../Plugins/
  37 } else {
  38     target.path  = /bin
  39     INSTALLS    += target
  40     QMAKE_RPATHDIR  = $$shell_quote(\$$ORIGIN/$$relative_path($$GCS_LIBRARY_PATH, $$GCS_APP_PATH))
  41     QMAKE_RPATHDIR += $$shell_quote(\$$ORIGIN/$$relative_path($$GCS_QT_LIBRARY_PATH, $$GCS_APP_PATH))
  42     include(../rpath.pri)
  43
  44     equals(copyqt, 1) {
  45         RESOURCES += $$OUT_PWD/qtconf.qrc
  46
  47         # Copy qtconf.qrc to OUT_PWD because paths are relative
  48         # This needs to be done at qmake time because the Makefile depends on it
  49         system(cp $$PWD/qtconf.qrc.in $$OUT_PWD/qtconf.qrc)
  50         system(printf $$shell_quote([Paths]\nPrefix = $$relative_path($$GCS_QT_BASEPATH, $$GCS_APP_PATH)\n) > $$OUT_PWD/qt.conf)
  51     }
  52 }
  53
  54 OTHER_FILES += gcs.rc
  55
  56 RESOURCES += \
  57     appresources.qrc
  58
  59 HEADERS += \
  60     gcssplashscreen.h