ground/gcs/src/plugin.pri

   1 include(../gcs.pri)
   2
   3 isEmpty(PROVIDER):PROVIDER = "$$ORG_BIG_NAME"
   4
   5 DESTDIR = $$GCS_PLUGIN_PATH/$$PROVIDER
   6 LIBS += -L$$DESTDIR
   7 INCLUDEPATH += $$GCS_SOURCE_TREE/src/plugins
   8 DEPENDPATH += $$GCS_SOURCE_TREE/src/plugins
   9
  10 QT += widgets
  11
  12 # copy the plugin spec
  13 isEmpty(TARGET) {
  14     error("qtcreatorplugin.pri: You must provide a TARGET")
  15 }
  16
  17 PLUGINSPECS = $${_PRO_FILE_PWD_}/$${TARGET}.pluginspec
  18 copy2build.input = PLUGINSPECS
  19 copy2build.output = $$DESTDIR/${QMAKE_FUNC_FILE_IN_stripSrcDir}
  20 copy2build.variable_out = PRE_TARGETDEPS
  21 copy2build.commands = $$QMAKE_COPY ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
  22 copy2build.name = COPY ${QMAKE_FILE_IN}
  23 copy2build.CONFIG += no_link
  24 QMAKE_EXTRA_COMPILERS += copy2build
  25
  26 TARGET = $$qtLibraryName($$TARGET)
  27
  28 macx {
  29         QMAKE_LFLAGS_SONAME = -Wl,-install_name,@executable_path/../Plugins/$${PROVIDER}/
  30 } else:linux-* {
  31     QMAKE_RPATHDIR  = $$shell_quote(\$$ORIGIN)
  32     QMAKE_RPATHDIR += $$shell_quote(\$$ORIGIN/$$relative_path($$GCS_LIBRARY_PATH, $$DESTDIR))
  33     QMAKE_RPATHDIR += $$shell_quote(\$$ORIGIN/$$relative_path($$GCS_QT_LIBRARY_PATH, $$DESTDIR))
  34     include(rpath.pri)
  35 }
  36
  37
  38 contains(QT_CONFIG, reduce_exports):CONFIG += hGCS_symbols
  39
  40 CONFIG += plugin plugin_with_soname
  41
  42 !macx {
  43     target.path = /$$GCS_LIBRARY_BASENAME/gcs/plugins/$$PROVIDER
  44     pluginspec.files += $${TARGET}.pluginspec
  45     pluginspec.path = /$$GCS_LIBRARY_BASENAME/gcs/plugins/$$PROVIDER
  46     INSTALLS += target pluginspec
  47 }