ground/uavobject-synthetics/uavobject-synthetics.pro

   1 #
   2 # Qmake project for UAVObjects generation.
   3 # Copyright (c) 2009-2013, The OpenPilot Team, http://www.openpilot.org
   4 #
   5
   6 TEMPLATE  = subdirs
   7
   8 # Some handy defines
   9 defineReplace(targetPath) {
  10    return($$replace(1, /, $$QMAKE_DIR_SEP))
  11 }
  12
  13 defineReplace(addNewline) {
  14     return($$escape_expand(\\n\\t))
  15 }
  16
  17 # QMAKESPEC should be defined by qmake but sometimes it is not
  18 isEmpty(QMAKESPEC) {
  19     win32:SPEC = win32-g++
  20     macx-g++:SPEC = macx-g++
  21     linux-g++:SPEC = linux-g++
  22     linux-g++-32:SPEC = linux-g++
  23     linux-g++-64:SPEC = linux-g++-64
  24 } else {
  25     SPEC = $$QMAKESPEC
  26 }
  27
  28 # Some platform-dependent options
  29 win32|unix {
  30     CONFIG(release, debug|release) {
  31         BUILD_CONFIG = release
  32     } else {
  33         BUILD_CONFIG = debug
  34     }
  35 }
  36
  37 win32 {
  38     # Windows sometimes remembers working directory changed from Makefile, sometimes not.
  39     # That's why pushd/popd is used here - to make sure that we know current directory.
  40
  41     uavobjects.commands += -$(MKDIR) $$targetPath(../uavobject-synthetics) $$addNewline()
  42     uavobjects.commands += pushd $$targetPath(../uavobject-synthetics) &&
  43     uavobjects.commands += $$targetPath(../uavobjgenerator/$${BUILD_CONFIG}/uavobjgenerator)
  44     uavobjects.commands +=   $$targetPath(../../shared/uavobjectdefinition)
  45     uavobjects.commands +=   $$targetPath(../..) &&
  46     uavobjects.commands += popd $$addNewline()
  47
  48     uavobjects.commands += -$(MKDIR) $$targetPath(../openpilotgcs) $$addNewline()
  49     uavobjects.commands += pushd $$targetPath(../openpilotgcs) &&
  50     uavobjects.commands += $(QMAKE) -spec $$SPEC CONFIG+=$${BUILD_CONFIG} -r
  51     uavobjects.commands +=   $$targetPath(../../ground/openpilotgcs/)openpilotgcs.pro &&
  52     uavobjects.commands += popd $$addNewline()
  53 }
  54
  55 !win32 {
  56     uavobjects.commands += $(MKDIR) -p ../uavobject-synthetics $$addNewline()
  57     uavobjects.commands += cd ../uavobject-synthetics &&
  58     uavobjects.commands += ../uavobjgenerator/uavobjgenerator
  59     uavobjects.commands +=   ../../shared/uavobjectdefinition ../.. &&
  60
  61     uavobjects.commands += $(MKDIR) -p ../openpilotgcs $$addNewline()
  62     uavobjects.commands += cd ../openpilotgcs &&
  63     uavobjects.commands += $(QMAKE) ../../ground/openpilotgcs/openpilotgcs.pro
  64     uavobjects.commands +=   -spec $$SPEC CONFIG+=$${BUILD_CONFIG} -r $$addNewline()
  65 }
  66
  67 uavobjects.target = FORCE
  68 QMAKE_EXTRA_TARGETS += uavobjects