ground/gcs/copydata.pro

   1 include(gcs.pri)
   2
   3 TEMPLATE = aux
   4
   5 # Copy Qt runtime libraries into the build directory (to run or package)
   6
   7 linux {
   8     QT_LIBS = \
   9         libQt5Core.so.5 \
  10         libQt5Gui.so.5 \
  11         libQt5Widgets.so.5 \
  12         libQt5Network.so.5 \
  13         libQt5OpenGL.so.5 \
  14         libQt5Sql.so.5 \
  15         libQt5Svg.so.5 \
  16         libQt5Test.so.5 \
  17         libQt5Xml.so.5 \
  18         libQt5XmlPatterns.so.5 \
  19         libQt5Script.so.5 \
  20         libQt5Concurrent.so.5 \
  21         libQt5PrintSupport.so.5 \
  22         libQt5SerialPort.so.5 \
  23         libQt5Multimedia.so.5 \
  24         libQt5MultimediaWidgets.so.5 \
  25         libQt5Quick.so.5 \
  26         libQt5QuickWidgets.so.5 \
  27         libQt5Qml.so.5 \
  28         libQt5DBus.so.5 \
  29         libQt5QuickParticles.so.5 \
  30         libQt5XcbQpa.so.5 \
  31         libQt5X11Extras.so.5 \
  32         libicui18n.so.56 \
  33         libicuuc.so.56 \
  34         libicudata.so.56
  35
  36     contains(QT_ARCH, x86_64) {
  37         QT_LIBS += \
  38             libqgsttools_p.so.1
  39     }
  40
  41     for(lib, QT_LIBS) {
  42         addCopyFileTarget($${lib},$$[QT_INSTALL_LIBS],$${GCS_QT_LIBRARY_PATH})
  43     }
  44
  45     QT_PLUGINS = \
  46         iconengines/libqsvgicon.so \
  47         imageformats/libqgif.so \
  48         imageformats/libqico.so \
  49         imageformats/libqjpeg.so \
  50         imageformats/libqsvg.so \
  51         imageformats/libqtiff.so \
  52         platforms/libqxcb.so \
  53         xcbglintegrations/libqxcb-glx-integration.so \
  54         sqldrivers/libqsqlite.so
  55
  56     contains(QT_ARCH, x86_64) {
  57         QT_PLUGINS += \
  58             mediaservice/libgstaudiodecoder.so \
  59             mediaservice/libgstmediaplayer.so
  60     } else {
  61         QT_PLUGINS += \
  62             mediaservice/libqtmedia_audioengine.so
  63     }
  64 }
  65
  66 win32 {
  67     # set debug suffix if needed
  68     CONFIG(debug, debug|release):DS = "d"
  69
  70     # copy Qt DLLs
  71     QT_DLLS = \
  72         Qt5Core$${DS}.dll \
  73         Qt5Gui$${DS}.dll \
  74         Qt5Widgets$${DS}.dll \
  75         Qt5Network$${DS}.dll \
  76         Qt5OpenGL$${DS}.dll \
  77         Qt5Sql$${DS}.dll \
  78         Qt5Svg$${DS}.dll \
  79         Qt5Test$${DS}.dll \
  80         Qt5Xml$${DS}.dll \
  81         Qt5XmlPatterns$${DS}.dll \
  82         Qt5Script$${DS}.dll \
  83         Qt5Concurrent$${DS}.dll \
  84         Qt5PrintSupport$${DS}.dll \
  85         Qt5SerialPort$${DS}.dll \
  86         Qt5Multimedia$${DS}.dll \
  87         Qt5MultimediaWidgets$${DS}.dll \
  88         Qt5Quick$${DS}.dll \
  89         Qt5QuickWidgets$${DS}.dll \
  90         Qt5Qml$${DS}.dll \
  91         libicuin56.dll \
  92         libicudt56.dll \
  93         libicuuc56.dll \
  94         libstdc++-6.dll \
  95         libwinpthread-1.dll \
  96         libpcre-1.dll \
  97         libpcre16-0.dll \
  98         zlib1.dll \
  99         libharfbuzz-0.dll \
 100         libgraphite2.dll \
 101         libfreetype-6.dll \
 102         libbz2-1.dll \
 103         libpng16-16.dll \
 104         libjpeg-8.dll \
 105         libglib-2.0-0.dll \
 106         libintl-8.dll \
 107         libiconv-2.dll
 108
 109     contains(QT_ARCH, i386) {
 110         QT_DLLS += \
 111             libgcc_s_dw2-1.dll
 112     } else {
 113         QT_DLLS += \
 114             libgcc_s_seh-1.dll
 115     }
 116
 117     for(dll, QT_DLLS) {
 118         addCopyFileTarget($${dll},$$[QT_INSTALL_BINS],$${GCS_APP_PATH})
 119     }
 120
 121     # copy OpenSSL DLLs
 122     OPENSSL_DLLS = \
 123         ssleay32.dll \
 124         libeay32.dll
 125
 126     for(dll, OPENSSL_DLLS) {
 127         addCopyFileTarget($${dll},$$[QT_INSTALL_BINS],$${GCS_APP_PATH})
 128     }
 129
 130     QT_PLUGINS = \
 131         iconengines/qsvgicon$${DS}.dll \
 132         imageformats/qgif$${DS}.dll \
 133         imageformats/qico$${DS}.dll \
 134         imageformats/qjpeg$${DS}.dll \
 135         imageformats/qsvg$${DS}.dll \
 136         imageformats/qtiff$${DS}.dll \
 137         platforms/qwindows$${DS}.dll \
 138         mediaservice/dsengine$${DS}.dll \
 139         sqldrivers/qsqlite$${DS}.dll
 140 }
 141
 142 for(plugin, QT_PLUGINS) {
 143     addCopyFileTarget($${plugin},$$[QT_INSTALL_PLUGINS],$${GCS_QT_PLUGINS_PATH})
 144 }
 145
 146 # Copy QtQuick2 complete directories
 147 # Some of these directories have a lot of files
 148 # Easier to copy everything
 149 QT_QUICK2_DIRS = \
 150     QtQuick/Controls \
 151     QtQuick/Dialogs \
 152     QtQuick/Layouts \
 153     QtQuick/LocalStorage \
 154     QtQuick/Particles.2 \
 155     QtQuick/PrivateWidgets \
 156     QtQuick/Window.2 \
 157     QtQuick/XmlListModel \
 158     QtQuick.2
 159
 160 for(dir, QT_QUICK2_DIRS) {
 161     addCopyDirTarget($${dir},$$[QT_INSTALL_QML],$${GCS_QT_QML_PATH})
 162 }