ground/openpilotgcs/copydata.pro

   1 include(openpilotgcs.pri)
   2
   3 TEMPLATE = aux
   4
   5 # Copy Qt runtime libraries into the build directory (to run or package)
   6 equals(copyqt, 1) {
   7     linux {
   8         QT_LIBS = libQt5Core.so.5 \
   9                   libQt5Gui.so.5 \
  10                   libQt5Widgets.so.5 \
  11                   libQt5Network.so.5 \
  12                   libQt5OpenGL.so.5 \
  13                   libQt5Sql.so.5 \
  14                   libQt5Svg.so.5 \
  15                   libQt5Test.so.5 \
  16                   libQt5Xml.so.5 \
  17                   libQt5Declarative.so.5 \
  18                   libQt5XmlPatterns.so.5 \
  19                   libQt5Script.so.5 \
  20                   libQt5Concurrent.so.5 \
  21                   libQt5PrintSupport.so.5 \
  22                   libQt5SerialPort.so.5 \
  23                   libQt5Multimedia.so.5 \
  24                   libQt5MultimediaWidgets.so.5 \
  25                   libQt5Quick.so.5 \
  26                   libQt5Qml.so.5 \
  27                   libQt5DBus.so.5 \
  28                   libQt5QuickParticles.so.5 \
  29                   libqgsttools_p.so.1 \
  30                   libicui18n.so.53 \
  31                   libicuuc.so.53 \
  32                   libicudata.so.53
  33         for(lib, QT_LIBS) {
  34             addCopyFileTarget($${lib},$$[QT_INSTALL_LIBS],$${GCS_QT_LIBRARY_PATH})
  35         }
  36
  37         QT_PLUGINS = iconengines/libqsvgicon.so \
  38                      imageformats/libqgif.so \
  39                      imageformats/libqico.so \
  40                      imageformats/libqjpeg.so \
  41                      imageformats/libqmng.so \
  42                      imageformats/libqsvg.so \
  43                      imageformats/libqtiff.so \
  44                      mediaservice/libgstaudiodecoder.so \
  45                      mediaservice/libgstmediaplayer.so \
  46                      platforms/libqxcb.so \
  47                      sqldrivers/libqsqlite.so
  48     }
  49
  50     win32 {
  51         # set debug suffix if needed
  52         CONFIG(debug, debug|release):DS = "d"
  53
  54         # copy Qt DLLs
  55         QT_DLLS = Qt5Core$${DS}.dll \
  56                   Qt5Gui$${DS}.dll \
  57                   Qt5Widgets$${DS}.dll \
  58                   Qt5Network$${DS}.dll \
  59                   Qt5OpenGL$${DS}.dll \
  60                   Qt5Sql$${DS}.dll \
  61                   Qt5Svg$${DS}.dll \
  62                   Qt5Test$${DS}.dll \
  63                   Qt5Xml$${DS}.dll \
  64                   Qt5Declarative$${DS}.dll \
  65                   Qt5XmlPatterns$${DS}.dll \
  66                   Qt5Script$${DS}.dll \
  67                   Qt5Concurrent$${DS}.dll \
  68                   Qt5PrintSupport$${DS}.dll \
  69                   Qt5SerialPort$${DS}.dll \
  70                   Qt5Multimedia$${DS}.dll \
  71                   Qt5MultimediaWidgets$${DS}.dll \
  72                   Qt5Quick$${DS}.dll \
  73                   Qt5Qml$${DS}.dll \
  74                   icuin53.dll \
  75                   icudt53.dll \
  76                   icuuc53.dll
  77         # it is more robust to take the following DLLs from Qt rather than from MinGW
  78         QT_DLLS += libgcc_s_dw2-1.dll \
  79                    libstdc++-6.dll \
  80                    libwinpthread-1.dll
  81         for(dll, QT_DLLS) {
  82             addCopyFileTarget($${dll},$$[QT_INSTALL_BINS],$${GCS_APP_PATH})
  83         }
  84
  85         # copy OpenSSL DLLs
  86         OPENSSL_DLLS = \
  87             ssleay32.dll \
  88             libeay32.dll
  89         for(dll, OPENSSL_DLLS) {
  90             addCopyFileTarget($${dll},$${OPENSSL_DIR},$${GCS_APP_PATH})
  91         }
  92
  93         # copy OpenGL DLL
  94         OPENGL_DLLS = \
  95             opengl32_32/opengl32.dll
  96         for(dll, OPENGL_DLLS) {
  97             addCopyFileTarget($${dll},$${MESAWIN_DIR},$${GCS_APP_PATH})
  98         }
  99
 100         QT_PLUGINS = iconengines/qsvgicon$${DS}.dll \
 101                      imageformats/qgif$${DS}.dll \
 102                      imageformats/qico$${DS}.dll \
 103                      imageformats/qjpeg$${DS}.dll \
 104                      imageformats/qmng$${DS}.dll \
 105                      imageformats/qsvg$${DS}.dll \
 106                      imageformats/qtiff$${DS}.dll \
 107                      platforms/qwindows$${DS}.dll \
 108                      mediaservice/dsengine$${DS}.dll \
 109                      sqldrivers/qsqlite$${DS}.dll
 110     }
 111
 112     for(plugin, QT_PLUGINS) {
 113         addCopyFileTarget($${plugin},$$[QT_INSTALL_PLUGINS],$${GCS_QT_PLUGINS_PATH})
 114     }
 115
 116     # Copy QtQuick2 complete directories
 117     # Some of these directories have a lot of files
 118     # Easier to copy everything
 119     QT_QUICK2_DIRS = QtQuick/Controls \
 120                      QtQuick/Dialogs \
 121                      QtQuick/Layouts \
 122                      QtQuick/LocalStorage \
 123                      QtQuick/Particles.2 \
 124                      QtQuick/PrivateWidgets \
 125                      QtQuick/Window.2 \
 126                      QtQuick/XmlListModel \
 127                      QtQuick.2
 128     for(dir, QT_QUICK2_DIRS) {
 129         addCopyDirTarget($${dir},$$[QT_INSTALL_QML],$${GCS_QT_QML_PATH})
 130     }
 131 }